Теоретически сигналы в быстром тактовом домене всегда будут выполнять выборку сигналов, передаваемых из медленного тактового домена. Если тактовые сигналы асинхронны, могут возникать ошибки выборки, поэтому требуется синхронизация. Этот тип синхронизации относительно прост и обычно использует метод отводов задержки или метод задержанной выборки.
Метод отводов задержки
Наиболее распространённым методом синхронизации является метод двухступенчатой буферизации на триггерах, обычно известный как метод отводов задержки. Прежде чем асинхронный сигнал попадёт в другой тактовый домен, сигнал последовательно буферизуется дважды двумя ступенями триггеров, что эффективно снижает проблемы метастабильности, вызванные нарушениями временных ограничений. Схема приведена ниже.

В типовых проектах использования двух ступеней триггеров для буферизации достаточно для соблюдения временных требований проекта. Многочисленные эксперименты показывают, что трёхступенчатая буферизация на триггерах позволяет решить более 99% таких проблем асинхронной синхронизации.
Описание на Verilog двухступенчатого отвода задержки на триггерах и обнаружения переднего фронта выглядит следующим образом:
Пример
input clk1, // Асинхронный медленный тактовый сигнал
input sig1, // Асинхронный сигнал
input rstn, // Сигнал сброса
input clk2, // Тактовый сигнал целевого быстрого тактового домена
output sig2); // Сигнал, синхронизированный в быстром тактовом домене
reg [2:0] sig2_r ; // 3-ступенчатый буфер; первые две ступени для синхронизации, последние две ступени для обнаружения фронта
always @(posedge clk2 or negedge rstn) begin
if (!rstn) sig2_r <= 3'b0 ;
else sig2_r <= {sig2_r[1:0], sig1} ; // Буфер
end
assign sig2 = sig2_r[1] && !sig2_r[2] ; // Обнаружение переднего фронта
Метод задержанной выборки
Этот метод в основном предназначен для передачи многоразрядных данных.
Например, когда отношение частот двух асинхронных тактовых сигналов равно 5, можно сначала с помощью метода отводов задержки буферизовать сигнал разрешения данных через две ступени регистров, а затем выполнить выборку сигнала данных из медленного тактового домена в быстром тактовом домене.
Основная идея этого метода — обеспечить безопасную выборку сигнала в нужный момент без необходимости синхронизировать многоразрядные сигналы данных, что позволяет сэкономить часть аппаратных ресурсов.
Описание на Verilog задержанной выборки с использованием метода отводов выглядит следующим образом.
Пример
// Асинхронные данные поступают из модуля с рабочей частотой 20MHz
module delay_sample(
input rstn,
input clk1,
input [31:0] din,
input din_en,
input clk2,
output [31:0] dout,
output dout_en);
//синхронизация din_en
reg [2:0] din_en_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn) din_en_r <= 3'b0 ;
else din_en_r <= {din_en_r[1:0], din_en} ;
end
wire din_en_pos = din_en_r[1] && !din_en_r[2] ;
//синхронизация данных
reg [31:0] dout_r ;
reg dout_en_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn)
dout_r <= 'b0 ;
else if (din_en_pos)
dout_r <= din ;
end
//задержка dout_en
always @(posedge clk2 or negedge rstn) begin
if (!rstn) dout_en_r <= 1'b0 ;
else dout_en_r <= din_en_pos ;
end
assign dout = dout_r ;
assign dout_en = dout_en_r ;
endmodule
Временная диаграмма результатов этого метода показана ниже.
Очевидно, в тактовом домене clk2 выборка и буферизация данных в момент времени t2 намного безопаснее, чем в момент t1.

Однако, если в медленном тактовом домене нет сигнала разрешения данных din_en или сигнал разрешения данных всегда активен, метод обнаружения переднего фронта сигнала разрешения данных в быстром тактовом домене не сработает. Поскольку сигнал разрешения данных всегда активен, за исключением первых данных, быстрый тактовый домен не сможет обнаружить моменты передачи последующих данных.
Решение состоит в том, чтобы обнаруживать фронт сигнала медленного тактового сигнала в быстром тактовом домене.
Если разница частот между двумя тактовыми сигналами мала, может потребоваться буферизация данных с задержкой, чтобы гарантировать, что выборочные данные соответствуют текущему такту; если разница частот велика, время выборки данных можно получить с помощью подсчёта, без буферизации данных.
Описание на Verilog для обнаружения фронта медленного тактового сигнала с помощью метода подсчёта с задержанной выборкой выглядит следующим образом.
Пример
// Асинхронные данные поступают от модуля с рабочим тактовым сигналом 999KHz
module delay_cnt_sample(
input rstn,
input clk1,
input [31:0] din,
input din_en,
input clk2,
output [31:0] dout,
output dout_en);
// 4-каскадный буфер: 3 каскада для синхронизации отводов, 1 каскад для обнаружения фронта
reg [3:0] edge_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn) edge_r <= 3'b0 ;
else edge_r <= {edge_r[3:0], clk1} ;
end
wire edge_pos = edge_r[2] && !edge_r[3] ;
// Счётчик задержки: начинает считать, когда обнаружен передний фронт медленного тактового сигнала
reg [5:0] cnt ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn) cnt <= 6'h3f ;
else if (edge_pos && din_en)
cnt <= 6'h0 ;
else if (cnt != 6'h3f) cnt <= cnt + 1'b1 ;
end
// Синхронизация данных
reg [31:0] dout_r ;
reg dout_en_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn)
dout_r <= 'b0 ;
else if (din_en && cnt == 47) // Выборка приблизительно в середине периода медленного тактового сигнала
dout_r <= din ;
end
// Сигнал разрешения данных выводится с задержкой в один цикл относительно момента выборки данных
always @(posedge clk2 or negedge rstn) begin
if (!rstn) dout_en_r <= 1'b0 ;
else if (din_en && cnt==48)
dout_en_r <= 1'b1 ;
else dout_en_r <= 1'b0 ;
end
assign dout = dout_r ;
assign dout_en = dout_en_r ;
endmodule
Ниже показана диаграмма результата выборки синхронизации данных при большом различии частот.
Как видно из рисунка, момент выборки быстрого тактового сигнала находится примерно в центре периода медленного тактового сигнала, что очень безопасно.

Скачать исходный код для этой главы
Скачать