Ключевые слова: деление на чётное число, деление на нечётное число, деление на полуцелое число, дробное деление
При первом изучении Verilog многие модули состоят из счётчиков и делителей частоты, например ШИМ (PWM — широтно-импульсная модуляция), частотомеры и т. д. Логика деления часто реализуется через логику счёта. В этом разделе в основном приводится краткое обобщение деления на чётное число, деления на нечётное число, деления на полуцелое число и дробного деления.
Деление на чётное число
Соединив инвертирующий выход триггера обратно с его входом, можно построить простую схему деления на 2.
Каскадирование на этой основе позволяет построить схемы деления на 4 и на 8.
Реализация схемы показана на рисунке ниже. При описании на Verilog достаточно простой логики инвертирования.

Если коэффициент чётного деления слишком велик, необходимо циклически считать коэффициент деления N. Когда период счёта достигает среднего значения N/2 коэффициента деления, тактовый сигнал переключается, что обеспечивает коэффициент заполнения 50 % для разделённого тактового сигнала. Поскольку деление чётное, счёт также можно выполнять циклически до среднего значения N/2.
Пример описания на Verilog для чётного деления выглядит следующим образом.
Пример
# (parameter DIV_CLK = 10 )
(
input rstn ,
input clk,
output clk_div2,
output clk_div4,
output clk_div10
);
//деление на 2
reg clk_div2_r ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
clk_div2_r <= 'b0 ;
end
else begin
clk_div2_r <= ~clk_div2_r ;
end
end
assign clk_div2 = clk_div2_r ;
//деление на 4
reg clk_div4_r ;
always @(posedge clk_div2 or negedge rstn) begin
if (!rstn) begin
clk_div4_r <= 'b0 ;
end
else begin
clk_div4_r <= ~clk_div4_r ;
end
end
assign clk_div4 = clk_div4_r ;
//счёт N/2
reg [3:0] cnt ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
cnt <= 'b0 ;
end
else if (cnt == (DIV_CLK/2)-1) begin
cnt <= 'b0 ;
end
else begin
cnt <= cnt + 1'b1 ;
end
end
//выходной тактовый сигнал
reg clk_div10_r ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
clk_div10_r <= 1'b0 ;
end
else if (cnt == (DIV_CLK/2)-1 ) begin
clk_div10_r <= ~clk_div10_r ;
end
end
assign clk_div10 = clk_div10_r ;
endmodule
В тестбенче достаточно подать тактовый сигнал стимулов и другие сигналы, поэтому здесь они не перечисляются.
Результаты моделирования следующие.

Нечётное деление
Если для нечётного деления не требуется 50% коэффициент заполнения, его можно выполнить так же, как и чётное деление. То есть счётчик циклически считает коэффициент деления N, а затем на основе значения счёта выбирается определённый коэффициент заполнения для выходного разделённого тактового сигнала.
Если высокий и низкий уровни выходного тактового сигнала при нечётном делении различаются всего на один цикл, можно использовать свойство исходного тактового сигнала работать по обоим фронтам в сочетании с «операцией И» или «операцией ИЛИ», чтобы довести коэффициент заполнения разделённого тактового сигнала до 50%.
Операция ИЛИ для регулировки коэффициента заполнения
Временная диаграмма формирования тактового сигнала с делением на 3 и коэффициентом заполнения 50% с помощью «операции ИЛИ» показана ниже.
Используйте нарастающий фронт исходного тактового сигнала для формирования тактового сигнала с делением на 3, у которого высокий уровень составляет 1 цикл, а низкий — 2 цикла.
Используйте падающий фронт исходного тактового сигнала для формирования тактового сигнала с делением на 3, у которого высокий уровень составляет 1 цикл, а низкий — 2 цикла.
Эти два тактовых сигнала с делением на 3 должны формироваться при одном и том же значении счётчика, но на разных фронтах, с разностью фаз в половину такта. Затем, выполнив «операцию ИЛИ» над этими двумя сигналами, можно получить тактовый сигнал с делением на 3 и коэффициентом заполнения 50%.

Аналогично, для деления на 9 необходимо сформировать тактовые сигналы с делением на 9 с 4 циклами высокого уровня и 5 циклами низкого уровня как по нарастающему, так и по падающему фронту, а затем выполнить «операцию ИЛИ» над этими двумя сигналами. Описание на Verilog выглядит следующим образом.
Пример
#(parameter DIV_CLK = 9)
(
input rstn ,
input clk,
output clk_div9
);
//счётчик
reg [3:0] cnt ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
cnt <= 'b0 ;
end
else if (cnt == DIV_CLK-1) begin
cnt <= 'b0 ;
end
else begin
cnt <= cnt + 1'b1 ;
end
end
//генерация деления на 9 по переднему фронту
reg clkp_div9_r ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
clkp_div9_r <= 1'b0 ;
end
else if (cnt == (DIV_CLK>>1)-1 ) begin //считать 4-8 низким уровнем
clkp_div9_r <= 0 ;
end
else if (cnt == DIV_CLK-1) begin //считать 0-3 высоким уровнем
clkp_div9_r <= 1 ;
end
end
//генерация деления на 9 по заднему фронту
reg clkn_div9_r ;
always @(negedge clk or negedge rstn) begin
if (!rstn) begin
clkn_div9_r <= 1'b0 ;
end
else if (cnt == (DIV_CLK>>1)-1 ) begin
clkn_div9_r <= 0 ;
end
else if (cnt == DIV_CLK-1) begin
clkn_div9_r <= 1 ;
end
end
//операция ИЛИ, обычно с использованием библиотеки базовых логических ячеек
// or (clk_div9, clkp_div9_r, clkn_div9_r) ;
assign clk_div9 = clkp_div9_r | clkn_div9_r ;
endmodule
Результаты моделирования следующие.

Операция AND для регулировки коэффициента заполнения
Временная диаграмма генерации тактового сигнала с делением на 3 и коэффициентом заполнения 50% с использованием "операции AND" показана ниже.
Используйте передний фронт исходного тактового сигнала для генерации тактового сигнала с делением на 3 с высоким уровнем в течение 2 циклов и низким уровнем в течение 1 цикла.
Используйте задний фронт исходного тактового сигнала для генерации тактового сигнала с делением на 3 с высоким уровнем в течение 2 циклов и низким уровнем в течение 1 цикла.
Два тактовых сигнала с делением на 3 должны быть сгенерированы при одном и том же значении счётчика, но по разным фронтам, с разностью фаз в половину тактового цикла. Затем, выполнив "операцию AND" над этими двумя сигналами, можно получить тактовый сигнал с делением на 3 и коэффициентом заполнения 50%.

Аналогично, для деления на 9 необходимо сгенерировать тактовые сигналы с делением на 9 с 5 циклами высокого уровня и 4 циклами низкого уровня как по переднему, так и по заднему фронтам, а затем выполнить "операцию AND" над этими двумя сигналами. Описание на Verilog выглядит следующим образом.
Пример
#( parameter DIV_CLK = 9 )
(
input rstn ,
input clk,
output clk_div9
);
//счётчик
reg [3:0] cnt ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
cnt <= 'b0 ;
end
else if (cnt == DIV_CLK-1) begin
cnt <= 'b0 ;
end
else begin
cnt <= cnt + 1'b1 ;
end
end
//генерация деления на 9 по переднему фронту
reg clkp_div9_r ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
clkp_div9_r <= 1'b0 ;
end
else if (cnt == (DIV_CLK>>1) ) begin //считать 5-8 низким уровнем
clkp_div9_r <= 0 ;
end
else if (cnt == DIV_CLK-1) begin //считать 0-4 высоким уровнем
clkp_div9_r <= 1 ;
end
end
//генерация деления на 9 по заднему фронту
reg clkn_div9_r ;
always @(negedge clk or negedge rstn) begin
if (!rstn) begin
clkn_div9_r <= 1'b0 ;
end
else if (cnt == (DIV_CLK>>1) ) begin
clkn_div9_r <= 0 ;
end
else if (cnt == DIV_CLK-1) begin
clkn_div9_r <= 1 ;
end
end
//операция AND, обычно с использованием библиотеки базовых логических ячеек
//and (clk_div9, clkp_div9_r, clkn_div9_r) ;
assign clk_div9 = clkp_div9_r & clkn_div9_r ;
endmodule
Результаты моделирования следующие.

Деление с полуцелым коэффициентом
Используя логику по обоим фронтам тактового сигнала, можно выполнять деление с полуцелым коэффициентом. Однако, как бы его ни настраивали, коэффициент заполнения при делении с полуцелым коэффициентом не может быть 50%. Существует много методов деления с полуцелым коэффициентом; здесь представлен только один метод, аналогичный настройке коэффициента заполнения для деления на нечётное число.
- (1) Например, при выполнении деления на 3.5 счётчик циклически считает до 7, формируя два разделённых тактовых сигнала, состоящих соответственно из 4 и 3 циклов исходного тактового сигнала. С точки зрения того, что 2 разделённых тактовых сигнала формируются из 7 исходных тактовых сигналов, процесс выполняет операцию деления на 3.5, но каждый разделённый тактовый сигнал не является строго результатом деления на 3.5.
- (2) Затем скорректируйте разделённые тактовые сигналы с неравномерными периодами. В одном цикле счёта сформируйте два разделённых тактовых сигнала, состоящих соответственно из 4 и 3 циклов исходного тактового сигнала, по спадающему фронту исходного тактового сигнала. По сравнению с двумя тактовыми сигналами с неравномерными периодами, сформированными в первый раз, фаза двух тактовых сигналов, сформированных на этот раз, соответственно задержана на половину периода исходного тактового сигнала и опережена на половину периода исходного тактового сигнала.
- (3) Выполнив операцию "ИЛИ" над двумя сформированными тактовыми сигналами, можно получить тактовый сигнал с делением на 3.5 и равномерным периодом. Временная диаграмма разделённого тактового сигнала показана ниже.

Описание на Verilog тактового сигнала с делением на 3.5 выглядит следующим образом.
Пример
input rstn ,
input clk,
output clk_div3p5
);
//счётчик
parameter MUL2_DIV_CLK = 7 ;
reg [3:0] cnt ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
cnt <= 'b0 ;
end
else if (cnt == MUL2_DIV_CLK-1) begin //счёт до 2-кратного коэффициента деления
cnt <= 'b0 ;
end
else begin
cnt <= cnt + 1'b1 ;
end
end
reg clk_ave_r ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
clk_ave_r <= 1'b0 ;
end
//первый цикл: 4 такта исходного clk
else if (cnt == 0) begin
clk_ave_r <= 1 ;
end
//2-й цикл: 3 такта исходного clk
else if (cnt == (MUL2_DIV_CLK/2)+1) begin
clk_ave_r <= 1 ;
end
else begin
clk_ave_r <= 0 ;
end
end
//корректировка
reg clk_adjust_r ;
always @(negedge clk or negedge rstn) begin
if (!rstn) begin
clk_adjust_r <= 1'b0 ;
end
//этот тактовый сигнал предназначен только для настройки постоянного коэффициента заполнения
else if (cnt == 1) begin
clk_adjust_r <= 1 ;
end
//этот тактовый сигнал предназначен только для настройки постоянного точного коэффициента деления
else if (cnt == (MUL2_DIV_CLK/2)+1 ) begin
clk_adjust_r <= 1 ;
end
else begin
clk_adjust_r <= 0 ;
end
end
assign clk_div3p5 = clk_adjust_r | clk_ave_r ;
endmodule
Результаты моделирования следующие.

Дробное деление
Основной принцип
Нерегулярное дробное деление не может сделать каждый такт поделённого тактового сигнала точным дробным кратным такту исходного тактового сигнала, а также не может сделать коэффициент заполнения поделённого тактового сигнала равным 50%, потому что Verilog не может выполнять дробный подсчёт тактов. Подобно концепции «средней частоты», введённой на первом этапе полуцелого деления, дробное деление также реализуется на основе переменного деления и методов многократного усреднения.
Например, для деления на 7.6 достаточно обеспечить, чтобы время 76 исходных тактовых циклов равнялось времени 10 циклов поделённой синхронизации. В этом случае необходимо выполнить 6 операций деления на 8 и 4 операции деления на 7 в течение 76 исходных тактовых циклов. В качестве другого примера, для деления на 5.76 необходимо выполнить 76 операций деления на 6 и 24 операции деления на 5 в течение 576 исходных тактовых циклов.
Процесс вычисления этих параметров деления объясняется ниже.
Когда выполняется деление на 7, это можно понимать как выполнение 10 операций деления на 7 в течение 70 исходных тактовых циклов. Если те же 10 делений всё ещё выполняются в течение 76 исходных тактовых циклов, это эквивалентно распределению дополнительных 6 исходных тактовых циклов по 70 исходным тактовым циклам, тем самым завершая операцию деления на 7.6. В процессе деления 6 поделённых тактовых сигналов должны быть получены делением на 8, тогда как остальные 4 поделённых тактовых сигнала сохранят исходное состояние деления на 7.
Во многих источниках приводится система из двух линейных уравнений для вычисления этих параметров деления, как показано ниже. Принцип тот же, что и в приведённом выше анализе, и рекомендуется освоить описанный выше процесс вычисления.
7N + 8M = 76 N + M = 10
Здесь 7 — целочисленный коэффициент деления, N — число раз, когда выполняется целочисленное деление; 8 — коэффициент деления, полученный добавлением единицы к целочисленному коэффициенту деления, а M — число раз, когда выполняется это деление.
Принцип усреднения
На примере деления на 7.6 порядок реализации деления на 7 и деления на 8 обычно имеет следующие 4 случая:
- (1) Сначала выполнить деление на 7 4 раза, затем выполнить деление на 8 6 раз;
- (2) Сначала выполнить деление на 8 6 раз, затем выполнить деление на 7 4 раза;
- (3) Равномерно вставить 4 операции деления на 7 в 6 операций деления на 8;
- (4) Равномерно вставить 6 операций деления на 8 в 4 операции деления на 7.
Первые два метода приводят к неравномерным тактовым частотам и большому фазовому дрожанию, поэтому последние два метода усреднённой вставки обычно используются для дробного деления.
Усреднённую вставку можно реализовать путём накопления разности коэффициентов деления. Процесс реализации деления на 7.6 выглядит следующим образом:
- (1) Первая разность коэффициентов деления равна 76-10*7 = 6 < 10, поэтому первое деление — деление на 7.
- (2) Второй результат накопленной разности равен 6+6=12 > 10, поэтому во втором делении используется деление на 8, а разность корректируется до 12-10=2.
- (3) Третий результат накопленной разности равен 2+6=8 < 10, поэтому в третьем делении используется деление на 7.
- (4) Четвёртый результат накопленной разности равен 8+6=14 > 10, поэтому в четвёртом делении используется деление на 8, а разность корректируется до 14-10=4.
По аналогии завершите процесс равномерной вставки шести операций деления на 8 в четыре операции деления на 7.
В следующей таблице показан процесс деления частоты методом усреднённой вставки.
| Коэффициент деления | Накопление разности | Коррекция разности | Цикл деления |
|---|---|---|---|
| 1 | 6 | 6 | 7 |
| 2 | 6+6=12 | 2 | 8 |
| 3 | 2+6=8 | 8 | 7 |
| 4 | 8+6=14 | 4 | 8 |
| 5 | 4+6=10 | 0 | 8 |
| 6 | 6 | 6 | 7 |
| 7 | 6+6=12 | 2 | 8 |
| 8 | 2+6=8 | 8 | 7 |
| 9 | 8+6=14 | 4 | 8 |
| 10 | 4+6=10 | 0 | 8 |
Моделирование проекта
Описание на Verilog, основанное на вышеуказанном методе реализации дробного деления частоты, выглядит следующим образом.
Пример
#(
parameter SOURCE_NUM = 76 , //циклов в исходном тактовом сигнале
parameter DEST_NUM = 10 //циклов в целевом тактовом сигнале
)
(
input rstn ,
input clk,
output clk_frac
);
//параметр деления на 7, параметр деления на 8, разность счётчиков
parameter SOURCE_DIV = SOURCE_NUM/DEST_NUM ;
parameter DEST_DIV = SOURCE_DIV + 1;
parameter DIFF_ACC = SOURCE_NUM - SOURCE_DIV*DEST_NUM ;
reg [3:0] cnt_end_r ; //переменный цикл деления
reg [3:0] main_cnt ; //основной счётчик
reg clk_frac_r ; //выход тактового сигнала, длительность высокого уровня 1 такт
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
main_cnt <= 'b0 ;
clk_frac_r <= 1'b0 ;
end
else if (main_cnt == cnt_end_r) begin
main_cnt <= 'b0 ;
clk_frac_r <= 1'b1 ;
end
else begin
main_cnt <= main_cnt + 1'b1 ;
clk_frac_r <= 1'b0 ;
end
end
//выходной тактовый сигнал
assign clk_frac = clk_frac_r ;
//управление разрешением накопителя разностей
wire diff_cnt_en = main_cnt == cnt_end_r ;
//логика накопителя разностей
reg [4:0] diff_cnt_r ;
wire [4:0] diff_cnt = diff_cnt_r >= DEST_NUM ?
diff_cnt_r -10 + DIFF_ACC :
diff_cnt_r + DIFF_ACC ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
diff_cnt_r <= 0 ;
end
else if (diff_cnt_en) begin
diff_cnt_r <= diff_cnt ;
end
end
//логика управления переменной цикла деления
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
cnt_end_r <= SOURCE_DIV-1 ;
end
//при переполнении аккумулятора разности изменить цикл деления
else if (diff_cnt >= 10) begin
cnt_end_r <= DEST_DIV-1 ;
end
else begin
cnt_end_r <= SOURCE_DIV-1 ;
end
end
endmodule
Результаты моделирования следующие.

Итоги по делению
Четное деление частоты позволяет получить деление тактовой частоты с коэффициентом заполнения 50% без использования логики по обоим фронтам тактового сигнала, что делает его наиболее идеальным условием деления частоты.
Для нечетного деления частоты, если требуется разделенный тактовый сигнал с коэффициентом заполнения 50%, необходимо использовать логику по обоим фронтам тактового сигнала. Если коэффициент заполнения не требуется, метод реализации аналогичен четному делению частоты.
Деление частоты с полуцелым коэффициентом — это особый вид дробного деления частоты, и его можно реализовать с помощью логики по обоим фронтам. При объединении двух тактовых сигналов с двойным фронтом в итоговый выходной тактовый сигнал с помощью некоторой логики не рекомендуется использовать логику выбора. Это связано с тем, что легко возникают глитчи, а схема также вносит дополнительную неопределённость. Например, следующее описание не рекомендуется.
: clk_adjust_r ;
Основная идея дробного деления частоты состоит в том, что средняя частота выходного тактового сигнала за некоторый промежуток времени удовлетворяет требованию деления. Однако, учитывая фазовое дрожание, также необходимо усреднять логику деления там, где изменяется коэффициент деления.
Загрузка исходного кода для этой главы
Скачать