Управление моделированием: $finish, $stop

Системная задачаФормат вызоваОписание задачи
Выход из моделирования$finish( type ) ;Завершить моделирование. Параметр type определяет, выводить ли информацию при выходе из моделирования.
type=0: Выход сразу без вывода информации
type=1: Вывод времени моделирования и информации о строке расположения оператора
type=2: Вывести время моделирования, местоположение, память и использование процессорного времени
Приостановить моделирование$stop( type ) ;Приостановить моделирование. Формат использования такой же, как у $finish.

И $finish, и $stop выполняют функцию остановки моделирования, но они всё же различаются.

$finish завершает текущее моделирование. $stop приостанавливает текущее моделирование. После приостановки моделирование можно продолжить с помощью инструмента моделирования Verilog или командной строки, но после завершения моделирования его нельзя продолжить ни при каких обстоятельствах. $stop аналогичен функции отладки по точкам останова в языке C.

Следующее моделирование иллюстрирует информацию, выводимую в соответствии с параметром type.

Пример

   initial begin
      forever begin
         #100;
         if ($time >= 10000)  $finish(0) ;
         //if ($time >= 10000) $finish(1) ;
         //if ($time >= 10000) $finish(2) ;
      end
   end

$finish(0), при выходе из моделирования информация не выводится.

$finish(1), при выходе из моделирования выводит время моделирования и информацию о строке, где находится $finish, как показано ниже.

Точность времени module test — ns, но точность времени симулятора — ps, поэтому выводимая информация о времени отличается в 1000 раз.

$finish(2), когда моделирование завершается, он не только выводит время моделирования и информацию о строке, но также выводит время использования ПК и объём используемой памяти, как показано ниже.

Формат времени: $printtimescale, $timeformat

Системная задачаФормат вызова и описание 
Вывод времени
Единица измерения и точность
$printtimescale( hierarchy ) ; 
 Эта системная задача выводит информацию о масштабе времени в следующем формате:
Масштаб времени для ( hierarchy ) равен 1 ( unit ) / 1 ( precision )
hierarchy — это уровень доступа модуля, его можно опустить. В этом случае выводится информация о масштабе времени текущего модуля.
 
Установка времени
Единица измерения и точность
$timeformat(unit_num, precision_num, suffix_string, min_field_width) 
 unit_num задаёт единицу времени, по умолчанию — `timescale
precision_num задаёт количество значащих десятичных цифр в единице времени, по умолчанию — 0
suffix_string, задает информацию о суффиксе времени, например "ns", по умолчанию пусто
min_field_width, задает количество символов, занимаемых информацией о времени, по умолчанию 20
 

Когда задачи отображения (такие как $display, $monitor и т. д.) и задачи записи в файл (такие как $display и т. д.) используют формат "%t" для вывода данных, $timeformat может задавать формат вывода информации о единице времени.

В $timeformat unit_num использует знаковое число для указания единицы времени. Соответствие показано в следующей таблице:

unit_numЕдиница времениunit_numЕдиница времени
01 s-810 ns
-1100 ms-91 ns
-210 ms-10100 ps
-31 ms-1110 ps
-4100 us-121 ps
-510 us-13100 fs
-61 us-1410 fs
-7100 ns-151 fs

Используйте следующий код для выполнения простой симуляции 2 системных задач масштаба времени.

Пример

   //изменить масштаб времени
   initial begin
      # 10 ;
      //точность ps, 5 значащих цифр в дробной части, суффикс единицы отображается как "my-ps", занимает 15 позиций символов
      $timeformat(-12, 5, " my-ps", 15) ;
   end
   initial begin
      # 5 ;
      $printtimescale() ;
      $display("Время до перенастройки: %t", $time);
      # 10 ;
      $printtimescale() ;
      $display("Время после перенастройки: %t", $time);
   end

Ниже показан журнал моделирования.

По рисунку можно сравнить формат отображения времени до и после настройки $timeformat.

Кроме того, в этом процессе масштаб времени остаётся неизменным; $timeformat изменяет только формат отображения времени.

Время моделирования: $time, $stime, $realtime

Вызов системной задачиОписание
$timeВозвращает 64-битное целочисленное значение времени
$stimeВозвращает 32-битное целочисленное значение времени
$realtimeВозвращает вещественное значение времени, которое может быть числом с плавающей запятой

Код моделирования выглядит следующим образом:

Пример

   initial begin
      #10;
      $display("$time output1: %t", $time);
      $display("$stime output1: %t", $stime);
      $display("$realtime output1: %t", $realtime);
      #3.2;
      $display("$time output2: %t", $time);
      $display("$stime output2: %t", $stime);
      $display("$realtime output2: %t", $realtime);
      #5.6;
      $display("$time output2: %t", $time);
      $display("$stime output2: %t", $stime);
      $display("$realtime output2: %t", $realtime);
   end

Ниже показан журнал моделирования.

Поскольку время моделирования короткое, разницы между $time и $stime нет.

Однако $realtime точно считывает время моделирования в соответствии с текущей точностью времени, тогда как $time и $stime округляют текущее время в соответствии с точностью времени.

Передача аргументов командной строки: $test$plusargs, $value$plusargs

Verilog также предоставляет интерактивные задачи $test$plusargs и $value$plusargs. Во время моделирования параметры можно передавать через аргументы командной строки, что обеспечивает большое удобство для отладки моделирования.

Системная задачаФормат вызоваОписание задачи
Передача строкового аргумента$test$plusargs( str ) ;Во время моделирования, если строковые данные, переданные через командную строку, совпадают со str, возвращаемое значение равно 1, иначе — 0.
Передача числового аргумента$value$plusargs( str, var ) ;Во время моделирования, если строковые данные, переданные через командную строку, совпадают со str, возвращаемое значение равно 1, иначе — 0.
Тип переменной var, передаваемой в модуль, должен быть указан внутри str. За форматом обращайтесь к задаче отображения $display.

При использовании $test$plusargs( str ) просто добавьте "+str " в командную строку моделирования.

При использовании $value$plusargs( str, var ) тип значения при передаче параметра должен быть указан внутри str. При передаче параметров в командной строке значение не требует указания основания системы счисления; просто сохраняйте значение в соответствующей системе счисления. Формат параметров командной строки должен соответствовать формату, объявленному в str в $value$plusargs.

Следующее моделирование иллюстрирует это:

Пример

   initial begin
      if ($test$plusargs("DISPLAY_CTRL")) begin
          $display("Отобразить информацию о моделировании!!!");
      end
   end
   reg  [1:0]   display_sel ;
   initial begin
      if ($value$plusargs("INFO_SEL=%b", display_sel)) begin
          $display("Передача параметра выполнена успешно!!!");
      end
      else begin
         display_sel = 2'b0 ;
      end
   end
   initial begin
      #1 ;
      if (display_sel == 2'b01)
          $display("Вы выбрали Пример!!!");
      else if (display_sel == 2'b10)
          $display("Вы выбрали Verilog!!!");
      else if (display_sel == 2'b11)
          $display("Вы выбрали меня!!!");
      else
          $display("Что вы на самом деле хотите???");
   end

Добавьте в командную строку моделирования: +DISPLAY_CTRL +INFO_SEL=01

Журнал моделирования выглядит следующим образом. Из этого видно, что и строковый параметр, и двоичный параметр переданы правильно.

Скачать исходный код для этой главы

Скачать