Пример элемента И-НЕ

В комбинационном логическом UDP таблица состояний задаёт различные комбинации входных сигналов и соответствующие значения выходных сигналов. Любая неуказанная комбинация выдаёт x.

Простой UDP элемента И-НЕ можно выразить следующим образом:

primitive nand_my(out, a, b);
   output       out ;
   input        a, b ;

   table
    //a b : out ;
      0         0       :       1 ;
      0         1       :       1 ;
      1         0       :       1 ;
      1         1       :       0 ;
   endtable
endprimitive

Как объяснялось в предыдущем разделе, список портов и раздел объявлений можно изменить на:

primitive nand_my(
  output       out,
  input        a, b);
  ......
endprimitive

Элементы таблицы состояний

Формат синтаксиса для каждой строки в таблице состояний, представляющей комбинационную логику, следующий:

<input1>  <input2>  ...  <inputN>  :  <output> ;
  • 1. Порядок входных сигналов в таблице состояний должен соответствовать порядку в списке портов UDP.
  • 2. Вход и выход используют двоеточие:для их разделения.
  • 3. Каждая строка таблицы состояний заканчивается точкой с запятой;для завершения.
  • 4. Все входные комбинации, которые могут дать определённое значение выхода, должны быть перечислены в таблице состояний, иначе будет выведено значение x.

Например, в приведённом выше UDP nand_my, если a=0, b=x, то выход out = x, потому что эта комбинация не найдена в таблице. Поэтому при написании UDP необходимо полностью учитывать все входные комбинации.

Таблицу состояний UDP nand_my можно изменить на:

   table
    //a b : out ;
      0         0       :       1 ;
      0         1       :       1 ;
      1         0       :       1 ;
      1         1       :       0 ;

      0         x       :       1 ;
      x         0       :       1 ;
   endtable

Безразличные термы

В UDP nand_my, когда либо a, либо b равно 0, выход равен 1.

Входные сигналы, которые не влияют на результат выхода, являются безразличными термами; их можно обозначить вопросительным знаком "?". Запись "?" в таблице состояний автоматически раскрывается в 0, 1 или x.

Следовательно, таблицу состояний UDP nand_my можно изменить на:

   table
    //a b : out ;
      0         ?       :       1 ;
      ?         0       :       1 ;
      1         1       :       0 ;

      // Следующая комбинация выдаст x, поэтому её также можно опустить. В Verilog по умолчанию выводится x.
      1         x       :       x ;
      x         1       :       x ;
   endtable

Инстанцирование UDP

Формат вызова UDP точно такой же, как у встроенных примитивов вентильного уровня.

Используйте приведённый выше UDP nand_my, чтобы завершить в разделе"1.3 Gate Delay"моделирование D-триггера.

После удаления информации о задержке модель D-триггера выглядит следующим образом.

Примеры

module D_TRI(
            input       D, CP,
            output      Q, QR);

   //part1, НЕ-вентиль
   wire         CPN, DN ;
   not          (CPN, CP);
   not          (DN, D);

   //part2, ведущий триггер
   wire         G3O, G4O ;
   nand_my      (G3O, D, CP);
   nand_my      (G4O, DN, CP);
   wire         G1O, G2O ;
   nand_my      (G1O, G3O, G2O);
   nand_my      (G2O, G4O, G1O);

   //part3, ведомый триггер
   wire         G7O, G8O ;
   nand_my      (G7O, G1O, CPN);
   nand_my      (G8O, G2O, CPN);
   wire         G5O, G6O ;
   nand_my      (G5O, G7O, G6O);
   nand_my      (G6O, G8O, G5O);

   assign       Q = G5O ;
   assign       QR = G6O ;

endmodule

Тестовый стенд остаётся неизменным, а результаты моделирования выглядят следующим образом.

Как видно из рисунка, триггер захватывает входной сигнал D по заднему фронту тактового сигнала CP и передаёт его на Q/QR, которые остаются неизменными в течение одного тактового цикла.

Реализованный с помощью UDP элемент NAND работает корректно.

Загрузка исходного кода для этой главы

Скачать