Когда сигналы передаются из быстрого тактового домена в медленный, необходимо выполнять синхронизацию в соответствии с характеристиками сигнала. Для однобитных сигналов их обычно можно разделить на сигналы уровня и импульсные сигналы.
Синхронизация сигналов уровня
В синхронном проектировании логики сигнал уровня — это сигнал, который остается неизменным в течение длительного времени. Время, в течение которого он остается неизменным, определяется относительно медленного тактового сигнала. Пока быстрый тактовый сигнал остается высоким или низким достаточно долго, чтобы быть захваченным медленным тактовым сигналом при соблюдении временных ограничений, сигнал можно считать сигналом уровня.
Поскольку сигналы уровня можно безопасно захватывать, сигналы уровня, передаваемые из быстрого тактового домена в медленный, также синхронизируются методом задержки и регистровой буферизации.
Синхронизация импульсных сигналов
В синхронном проектировании логики импульсный сигнал — это сигнал, у которого длительность активного уровня, формируемого в быстром тактовом домене, меньше периода медленного тактового сигнала. Если медленный тактовый домен непосредственно захватывает такой узкий импульсный сигнал, он может быть пропущен.
Если ширины импульсов таких сигналов одинаковы, а отношение частот двух тактовых сигналов известно, для синхронизации можно использовать метод «расширения ширины импульса в быстром тактовом домене + задержки и регистровой буферизации в медленном тактовом домене».
Если узкие импульсные сигналы иногда также проявляют свойства сигналов уровня, то есть иногда длительность активного уровня сигнала превышает период медленного тактового сигнала и может быть зафиксирована медленным тактовым сигналом, то выполнять расширение импульса для таких сигналов, очевидно, невыгодно. В этом случае синхронизацию можно выполнить методом «передачи с квитированием».
Если предположить, что период высокого уровня импульсного сигнала является периодом действительного сигнала, основной принцип следующий.
- (1) Быстрый тактовый домен обнаруживает импульсный сигнал и при обнаружении высокого уровня выдает сигнал высокого уровня pulse_fast_r. Вместо этого, когда быстрый тактовый домен выдает сигнал высокого уровня, не спешите переводить сигнал в низкий уровень; сначала удерживайте выходной сигнал в высоком состоянии.
- (2) Медленный тактовый домен выполняет задержку и выборку с регистровой конвейеризацией сигнала pulse_fast_r из быстрого тактового домена. Поскольку в это время импульсный сигнал удерживается быстрым тактовым доменом на высоком уровне, задержка и регистровая конвейеризация обязательно захватят сигнал.
- (3) После того как медленный тактовый домен подтверждает, что он выполнил выборку сигнала высокого уровня pulse_fast2s_r, он передает его обратно в быстрый тактовый домен.
- (4) Быстрый тактовый домен выполняет задержку и выборку с регистровой конвейеризацией сигнала обратной связи pulse_fast2s_r. Если обнаружен высокий уровень сигнала обратной связи, это доказывает, что медленный тактовый домен получил действительный сигнал высокого уровня. Если собственная логика быстрого тактового домена в это время больше не требует, чтобы импульсный сигнал был высокого уровня, просто переведите импульсный сигнал в быстром тактовом домене в низкий уровень.
Суть этого метода заключается в расширении ширины импульса узких импульсных сигналов посредством взаимного квитирования.
Модель на Verilog для обработки синхронизации с использованием сигналов квитирования описывается следующим образом.
Пример
//Асинхронные данные поступают из модуля с рабочей тактовой частотой 100MHz
module pulse_syn_fast2s
#( parameter PULSE_INIT = 1'b0
)
(
input rstn,
input clk_fast,
input pulse_fast,
input clk_slow,
output pulse_slow);
wire clear_n ;
reg pulse_fast_r ;
/**************** быстрый clk ***************/
//(1) Когда домен быстрого тактового сигнала обнаруживает импульсный сигнал, он не спешит перевести импульсный сигнал в низкий уровень
always@(posedge clk_fast or negedge rstn) begin
if (!rstn)
pulse_fast_r <= PULSE_INIT ;
else if (!clear_n)
pulse_fast_r <= 1'b0 ;
else if (pulse_fast)
pulse_fast_r <= 1'b1 ;
end
reg [1:0] pulse_fast2s_r ;
/************ медленный тактовый сигнал *************/
//(2) Медленный тактовый домен выполняет задержку и регистровую конвейерную выборку сигнала
always@(posedge clk_slow or negedge rstn) begin
if (!rstn)
pulse_fast2s_r <= 3'b0 ;
else
pulse_fast2s_r <= {pulse_fast2s_r[0], pulse_fast_r} ;
end
assign pulse_slow = pulse_fast2s_r[1] ;
reg [1:0] pulse_slow2f_r ;
/********* обратная связь от медленного тактового сигнала к быстрому тактовому сигналу *******/
//(3) Выполнить задержку и регистровую конвейерную выборку сигнала обратной связи
always@(posedge clk_fast or negedge rstn) begin
if (!rstn)
pulse_slow2f_r <= 1'b0 ;
else
pulse_slow2f_r <= {pulse_slow2f_r[0], pulse_slow} ;
end
//Управление понижением импульсного сигнала быстрой тактовой области
assign clear_n = ~(!pulse_fast && pulse_slow2f_r[1]) ;
endmodule
Тестовый стенд описывается следующим образом.
Пример
module test ;
reg clk_100mhz, clk_25mhz ;
reg rstn ;
initial begin
clk_100mhz = 0 ;
clk_25mhz = 0 ;
rstn = 0 ;
#11 rstn = 1 ;
end
always #(10/2) clk_100mhz = ~clk_100mhz ;
always #(45/2) clk_25mhz = ~clk_25mhz ;
reg [7:0] cnt ;
reg pulse_sig ;
always @(posedge clk_100mhz or negedge rstn) begin
if (!rstn) begin
cnt <= 'b0 ;
end
else begin
cnt <= cnt + 1'b1 ;
end
end
//Секция генерации узкого импульса
always @(posedge clk_100mhz or negedge rstn) begin
if (!rstn) begin
pulse_sig <= 1'b0 ;
end
else if (cnt == 5 ||
cnt == 40 || cnt == 42 ||
cnt >= 75 && cnt <= 81 || cnt == 85 || cnt == 87 )
begin
pulse_sig <= 1'b1 ;
end
else begin
pulse_sig <= 1'b0 ;
end
end
pulse_syn_fast2s u_fast2s_pulse(
.rstn (rstn),
.clk_fast (clk_100mhz),
.pulse_fast (pulse_sig),
.clk_slow (clk_25mhz),
.pulse_slow ());
initial begin
forever begin
#100;
if ($time >= 10000) $finish ;
end
end
endmodule // test
Результаты моделирования приведены ниже, и из них можно увидеть следующее:
- (1) Одиночный узкий импульсный сигнал в быстром тактовом домене захватывается медленным тактовым доменом, но синхронизированный сигнал имеет большую задержку и большую ширину импульса. Задержка сигнала вызвана задержкой, регистровой конвейеризацией и сбросом обратной связи и неизбежна. Проблему чрезмерной ширины импульса можно решить, выполнив обнаружение фронта с помощью задержки и регистровой конвейеризации.
- (2) Ширина импульса синхронизированного сигнала двух соседних узких импульсных сигналов не отличается от ширины импульса синхронизированного сигнала одиночного узкого импульса. То есть схема синхронизации пропускает обнаружение второго узкого импульса. Это также особенность передачи с квитированием (handshake) при решении проблем синхронизации. Когда импульсный сигнал в быстром тактовом домене изменяется слишком быстро, этот метод не может различить соседние импульсы.
- (3) Когда несколько широких и узких импульсных сигналов находятся близко друг к другу, хотя этот метод синхронизации не может различить несколько импульсных сигналов, ширина импульса синхронизированного сигнала может быть относительно больше.

Синхронизация многоразрядных данных
При синхронизации многоразрядных данных, если каждый бит данных можно рассматривать как уровневый сигнал, то есть каждый бит данных может оставаться неизменным в течение относительно длительного периода, чтобы его можно было захватить медленным тактовым сигналом, можно задействовать часть ресурсов триггеров для выполнения простой синхронизации многоразрядных данных с задержкой и регистровой конвейеризацией.
Однако если данные изменяются слишком быстро, метод выборки с задержкой и регистровой конвейеризацией больше нельзя использовать. Потому что в этом случае каждый бит данных уже не является уровневым сигналом, а моменты изменения также неравномерны. Выборка асинхронным тактовым сигналом может захватить неверные данные, вызванные разными задержками путей.
Распространённый метод решения таких асинхронных проблем — использовать асинхронный FIFO (первым пришёл — первым вышел). Подробности см. в следующем разделе:"4.4 Проектирование FIFO"。
Скачать исходный код для этой главы
Скачать