Ключевые слова: задержка вентиля, D-триггер
Типы задержек вентилей
Схемы на уровне вентилей, представленные в предыдущих двух разделах, не имеют задержки; реальные схемы на уровне вентилей все имеют задержку.
Verilog позволяет пользователям задавать задержки логических элементов для определения задержки распространения от входов к выходным сигналам.
Существует в основном три типа задержек логических элементов.
Задержка нарастания
Когда вход логического элемента изменяется, время перехода, необходимое для изменения выхода логического элемента из 0, x, z в 1, называется задержкой нарастания.

Задержка спада
Когда вход логического элемента изменяется, время перехода, необходимое для изменения выхода логического элемента из 1, x, z в 0, называется задержкой спада.

Задержка отключения
Задержка отключения — это время перехода, необходимое для изменения выхода логического элемента из 0, 1, x в высокоимпедансное состояние z.

Время перехода, необходимое для изменения выхода логического элемента из 0, 1, z в x, явно не определено, но необходимое время можно определить по другим типам задержек; оно является наименьшим из трех вышеуказанных значений задержки.
Задержки логических элементов можно задавать при инстанцировании примитива логического элемента. Формат определения следующий:
gate_type [delay] [instance_name] (signal_list) ;
Здесь число задержек может быть 0, 1, 2 или 3.
В следующей таблице показаны значения задержек для разного числа спецификаций задержки.
| Тип задержки | Без задержки | 1 задержка (d) | 2 задержки (d1, d2) | 3 задержки (d1, d2, d3) |
|---|---|---|---|---|
| Нарастание | 0 | d | d1 | d1 |
| Спад | 0 | d | d2 | d2 |
| Выключение | 0 | d | min(d1, d2) | d3 |
| to_x | 0 | d | min(d1, d2) | min(d1, d2, d3) |
Если значение задержки не указано, задержка по умолчанию равна 0.
Если пользователь указывает 1 значение задержки, то все типы значений задержки равны этому значению.
Если пользователь указывает 2 значения задержки, они представляют собой задержку нарастания и задержку спада соответственно, а задержки выключения и "to_x" обе равны меньшему из этих 2 значений задержки.
Если пользователь указывает 3 значения задержки, они представляют собой задержку нарастания, задержку спада и задержку выключения соответственно, а задержка "to_x" является наименьшей из этих 3 значений задержки.
Создание экземпляра примитива вентильного уровня со значениями задержки выглядит следующим образом:
Пример
and #(1) (OUT1, IN1, IN2) ;
//задержка нарастания = 2.1, задержка спада = 2, задержка выключения = 2
or #(2.1, 2) (OUT2, IN1, IN2) ;
//задержка нарастания = 2, задержка спада = 1, задержка выключения = 1.3
bufif0 #(2, 1, 1.3) (OUT3, IN1, CTRL) ;
Следует отметить, что многовходовые вентили (такие как элементы AND) и многовыходовые вентили (такие как элементы NOT) могут задавать не более 2 задержек, потому что выход не будет z.
Вентили с тремя состояниями и однонаправленные ключи (MOS-транзисторы, CMOS-транзисторы и т.д.) могут задавать 3 задержки.
Вентили pull-up и pull-down не имеют никакой задержки, поскольку они представляют аппаратный атрибут; состояние pull-up/pull-down не изменяется, и выходного значения нет.
Двунаправленные ключи (tran) не имеют задержки при передаче сигналов, и задание задержек не допускается.
Двунаправленные ключи с управляющими выводами (tranif1, tranif0) имеют задержку включения или выключения при переключении. Для таких двунаправленных ключей можно задать 0, 1 или 2 задержки, например:
Пример
tranif0 #(1) (inout1, inout2, CTRL);
//задержка включения = 1, задержка выключения = 1.2
tranif1 #(1, 1.2) (inout3, inout4, CTRL);
Минимальные/типичные/максимальные задержки
Из-за различий в технологических процессах производства интегральных схем задержка устройств в реальных схемах всегда колеблется в определённом диапазоне. В Verilog пользователи могут не только указать 3 типа задержек логических элементов, но и задать минимальное, типичное и максимальное значения для каждого типа. На этапе компиляции или моделирования можно выбрать одно из этих значений задержки, что обеспечивает поддержку более реалистичного моделирования.
- Минимальное значение: минимальная задержка, которой обладает логический примитив.
- Типичное значение: типичная задержка, которой обладает логический примитив.
- Максимальное значение: максимальная задержка, которой обладает логический примитив.
Следующий пример инстанцирования иллюстрирует использование минимальной, типичной и максимальной задержек.
Пример
and #(1:2:3) (OUT1, IN1, IN2) ;
//задержка нарастания: мин. 1, типичная 2, макс. 3
//задержка спада: мин. 3, типичная 4, макс. 5
//задержка выключения: мин. min(1,3), типичная min(2,4), макс. min(3,5)
or #(1:2:3, 3:4:5) (OUT2, IN1, IN2) ;
//задержка нарастания: мин. 1, типичная 2, макс. 3
//задержка спада: мин. 3, типичная 4, макс. 5
//задержка выключения: мин. 2, типичная 3, макс. 4
bufif0 #(1:2:3, 3:4:5, 2:3:4) (OUT3, IN1, CTRL) ;
D-триггер
Далее мы проектируем D-триггер с точки зрения моделирования на уровне логических элементов.
SR-триггер
Структурная схема SR-триггера и таблица истинности выглядят следующим образом.
- 1. Когда S имеет низкий уровень, выход Q элемента G1 имеет высокий уровень и подаётся обратно на вход G2. Если R в это время имеет высокий уровень, выход Q' элемента G2 имеет низкий уровень.
- 2. Когда R имеет низкий уровень, а S — высокий, анализ аналогичен.
- 3. Когда и S, и R имеют высокий уровень, если Q = 1 (Q' = 0), то после подачи Q обратно на вход G2 выход Q' остаётся 0; после подачи Q' обратно на вход G1 выход Q остаётся 1, что показывает устойчивое состояние. Если Q = 0 (Q' = 1), анализ аналогичен, и Q и Q' остаются неизменными. То есть, когда и S, и R имеют высокий уровень, схема выполняет функцию хранения.
- 4. Если и S, и R имеют низкий уровень, то выходы Q и Q' оба имеют высокий уровень, и они больше не являются взаимодополняющими. Поэтому этот случай запрещён.


SR-защёлка
Добавление двух логических элементов И-НЕ перед базовым SR-триггером образует SR-защёлку с входом разрешения.
SR-защёлка и её таблица истинности выглядят следующим образом.
- Когда EN=0, G3 и G4 отключены, и SR-защёлка сохраняет своё выходное состояние неизменным.
- Когда EN=1, он работает точно так же, как базовый SR-триггер.


D-защелка
Входы базового SR-триггера не могут одновременно быть равны 0, а входы SR-защелки с входом разрешения не могут одновременно быть равны 1; в противном случае возникает противоречие некомплементарности между выходами Q и Q'.
Чтобы устранить это запрещенное состояние, в SR-защелку с входом разрешения добавляется инвертирующий модуль, гарантирующий, что 2 входа всегда логически противоположны, таким образом формируя D-защелку.
Ее структурная схема и таблица истинности выглядят следующим образом.
- 1. Когда EN=1, состояние выхода изменяется вместе с состоянием входа.
- 2. Когда EN=0, состояние выхода остается неизменным.


D-защелка управляется уровнем.
Если входной сигнал D переключается несколько раз в течение активного периода EN=1, выход Q также будет переключаться несколько раз. Это снижает помехоустойчивость схемы и не является надежной схемой для практических требований.
Чтобы повысить надежность триггера и улучшить помехоустойчивость схемы, был изобретен D-триггер, который фиксирует сигнал в определенный момент времени.
D-триггер
Каскадное соединение двух D-защелок с инвертированным тактовым сигналом образует простой D-триггер, также известный как флип-флоп.
Ее структурная схема и таблица истинности выглядят следующим образом.
D-защелка первого каскада также называется ведущей защелкой, которая фиксирует сигнал, когда CP имеет низкий уровень. D-защелка второго каскада также называется ведомой защелкой; ее тактовый сигнал противоположен тактовому сигналу ведущей защелки, и она фиксирует сигнал, когда CP имеет высокий уровень.


- 1. Когда CP=1, выход ведущей защёлки Qm следует за изменениями входного сигнала D, тогда как ведомая защёлка находится в состоянии хранения, и её выход Qs остаётся неизменным.
- 2. Когда CP изменяется с высокого уровня на низкий, ведущая защёлка фиксирует текущее состояние D, передаёт его на выход Qm и сохраняет его неизменным. Выход ведомой защёлки Qs следует за изменениями Qm. В это время ведущая защёлка в зафиксированном состоянии удерживает Qm неизменным, поэтому после того как выход Qs D-триггера получает новое значение Qm, он также остаётся неизменным.
Итак, выход Qs D-триггера фиксирует сигнал на D только по спадающему фронту тактового сигнала CP; в остальное время выходной сигнал выполняет функцию хранения.
Развёртывание двухкаскадной D-защёлки в структуру на уровне вентилей показано на следующем рисунке.

Мы выполняем моделирование D-триггера на уровне вентилей и добавляем задержки логических элементов. Модель на Verilog выглядит следующим образом:
Пример
input D, CP,
output Q, QR);
parameter RISE_TIME = 0.11 ;
parameter FALL_TIME = 0.07 ;
//part1, НЕ-вентиль
wire CPN, DN ;
not #(RISE_TIME, FALL_TIME) (CPN, CP);
not #(RISE_TIME, FALL_TIME) (DN, D);
//part2, ведущий триггер
wire G3O, G4O ;
nand #(RISE_TIME, FALL_TIME) (G3O, D, CP);
nand #(RISE_TIME, FALL_TIME) (G4O, DN, CP);
wire #(RISE_TIME, FALL_TIME) G1O, G2O ;
nand #(RISE_TIME, FALL_TIME) (G1O, G3O, G2O);
nand #(RISE_TIME, FALL_TIME) (G2O, G4O, G1O);
//part3, ведомый триггер
wire G7O, G8O ;
nand #(RISE_TIME, FALL_TIME) (G7O, G1O, CPN);
nand #(RISE_TIME, FALL_TIME) (G8O, G2O, CPN);
wire G5O, G6O ;
nand #(RISE_TIME, FALL_TIME) (G5O, G7O, G6O);
nand #(RISE_TIME, FALL_TIME) (G6O, G8O, G5O);
assign Q = G5O ;
assign QR = G6O ;
endmodule
Тестовый стенд написан следующим образом:
Пример
module test ;
reg D, CP = 0 ;
wire Q, QR ;
always #5 CP = ~CP ;
initial begin
D = 0 ;
#12 D = 1 ;
#10 D = 0 ;
#14 D = 1 ;
#3 D = 0 ;
#18 D = 0 ;
end
D_TRI u_d_trigger(
.D (D),
.CP (CP),
.Q (Q),
.QR (QR));
initial begin
forever begin
#100;
//$display("---gyc---%d", $time);
if ($time >= 1000) begin
$finish ;
end
end
end
endmodule // test
Результаты моделирования следующие.
Как видно из рисунка, оба сигнала Q/QR захватывают сигнал D по заднему фронту тактового сигнала CP, остаются неизменными в течение одного цикла, и выход имеет задержку.

Увеличьте масштаб в момент cap3 и проследите задержку, как показано на рисунке ниже.
- Задержка нарастания от CP до CPN составляет 110ps;
- Задержка спада от CPN до G8O составляет 70ps;
- Задержка нарастания от G8O до G6O составляет 110ps;
- Задержка спада от G6O до Q составляет 70ps;
- Итоговое значение — 360ps, что соответствует настроенной задержке вентиля.

Скачать исходный код для этой главы
Скачать