Ключевые слова: источник тактового сигнала, перекос тактового сигнала, джиттер тактового сигнала, время перехода тактового сигнала, задержка тактового сигнала, дерево тактовых сигналов, двухфронтовый тактовый сигнал

Почти любое сколько-нибудь сложное цифровое устройство неотделимо от тактовых сигналов. Тактовые сигналы также являются основой всей последовательностной логики. Ранее при рассмотрении времени установки и времени удержания также было затронуто понятие перекоса тактового сигнала. Ниже мы обобщим знания о тактовых сигналах, чтобы лучше выполнять цифровое проектирование.

Источник тактового сигнала

В зависимости от расположения источника тактового сигнала в модуле цифрового проектирования источники тактового сигнала можно разделить на внешние и внутренние.

Внешний источник тактового сигнала:

Схема RC/LC-генератора: в ней используются цепи положительной или отрицательной обратной связи для формирования периодически изменяющихся тактовых сигналов. Такой источник тактового сигнала имеет простую схему и широкий диапазон частот, но рабочая частота низкая, а стабильность невысокая.

Пассивный/активный кварцевый генератор: в нем используется пьезоэлектрический эффект кварцевых кристаллов (механическое давление и электрические сигналы могут преобразовываться друг в друга) для генерации резонансных сигналов. Такой источник тактового сигнала обладает высокой точностью по частоте, хорошей стабильностью, низким уровнем шума и малым температурным дрейфом. В активных генераторах часто также предусмотрены управление напряжением или термокомпенсация, что придает тактовому сигналу хорошие фазовые и частотные характеристики. Однако схемная реализация относительно сложна, частотный диапазон узок, а частота практически нерегулируема.

При отладке конкретных схем часто используются источники тактового сигнала, формируемые некоторыми специально построенными схемами (например, триггерами Шмитта), или оборудование генераторов сигналов.

Внутренний источник тактового сигнала:

Система фазовой автоподстройки частоты (PLL):

Она использует внешний опорный сигнал для управления частотой и фазой колебательного сигнала внутри петли, обеспечивая автоматическое слежение частоты выходного сигнала за частотой входного сигнала, и через цепь обратной связи умножает сигнал до более высокой фиксированной частоты.

Обычные кварцевые генераторы по технологическим и стоимостным причинам не могут достигать очень высоких частот. Использование схемы PLL позволяет получить стабильный высокочастотный тактовый сигнал. Интеграция PLL внутрь модуля проектирования может обеспечить хорошие характеристики задержки и стабильности для цифровых схем.

Деление тактовой частоты:Некоторые модули работают на частоте ниже частоты системного тактового сигнала. В этом случае системный тактовый сигнал необходимо разделить, чтобы получить тактовый сигнал более низкой частоты.

Подсчёт и вывод тактовых сигналов в блоке always — распространённый метод для делителей частоты. Логику реализации произвольных коэффициентов деления см. в следующем разделе, "5.3 Деление тактовой частоты".

Переключение тактовых сигналов:Рабочая частота системы или некоторых модулей иногда изменяется при определённых условиях, например, требуется снижение частоты в режиме низкого энергопотребления, а для повышения вычислительной способности — повышение частоты. В таких случаях система часто имеет несколько источников тактового сигнала для переключения тактовых сигналов при необходимости.

Если логика переключения тактовых сигналов не оптимизирована, во время переходного периода переключения вероятно появление помех в виде глитчей/игольчатых импульсов, что негативно влияет на схему. Безопасную логику переключения см. в следующей главе: "5.4 Переключение тактовых сигналов".

В цифровых системах часто применяется схема с входом от внешнего кварцевого генератора и внутренним умножением частоты в PLL. Затем в соответствии с требованиями проекта выполняется деление тактовой частоты или переключение тактовых сигналов.

Характеристики тактового сигнала

При моделировании все синхронные тактовые сигналы идеальны: переходы тактового сигнала мгновенны, фронты тактового сигнала между модулями выровнены, без задержки и без джиттера. В реальных схемах тактовые сигналы имеют задержку при передаче и переключении. Идеальный цифровой проект должен также учитывать эти неидеальные характеристики тактового сигнала, иначе это может вызвать нарушения временных требований в проекте.

Ниже приведено краткое описание некоторых характеристик тактового сигнала.

Перекос тактового сигнала

Из-за задержки в межсоединениях, когда тактовый сигнал достигает портов триггеров, нельзя гарантировать, что фронты тактового сигнала на разных портах триггеров выровнены, то есть фазы тактового сигнала на разных портах триггеров различаются. Эту разницу называют перекосом тактового сигнала. Схематическое изображение выглядит следующим образом:

В общем случае перекос тактового сигнала не имеет прямой связи с частотой тактового сигнала; он связан с такими факторами, как длина трассировки, емкость нагрузки и количество нагрузок.

Джиттер тактового сигнала

Относительно идеального фронта тактового сигнала смещение в реальном тактовом сигнале, которое не накапливается со временем и иногда опережает, а иногда отстает, называется джиттером тактового сигнала. Джиттер тактового сигнала можно количественно описать частотой джиттера и амплитудой джиттера. В цифровом проектировании джиттер тактового сигнала всегда описывается во временных терминах. Схема показана ниже.

Джиттер тактового сигнала можно разделить на случайный джиттер и детерминированный джиттер.

Случайный джиттер возникает из-за теплового шума, полупроводникового техпроцесса и т. д.

Детерминированный джиттер возникает из-за импульсных источников питания, электромагнитных помех или других нерациональных размещений и трассировки и т. д.

В инструменте синтеза Design Compiler перекос и джиттер тактового сигнала единообразно представляются значением uncertainty.

Время перехода

Когда тактовый сигнал переходит с нарастающего фронта на спадающий или со спадающего фронта на нарастающий, изменение уровня не является мгновенным «строго вертикальным» и не требующим времени; вместо этого оно имеет «линейно-нарастающий» характер и требует времени перехода для завершения изменения уровня. Это время перехода называется временем перехода тактового сигнала. Схема показана ниже.

Величина времени перехода зависит от техпроцесса библиотеки элементов, емкостной нагрузки и т. д.

Задержка тактового сигнала

Время задержки тактового сигнала от источника тактового сигнала (например, кварцевого генератора, PLL или выхода делителя частоты) до порта триггера называется задержкой тактового сигнала. Задержка тактового сигнала включает задержку источника и задержку сети, как показано на рисунке ниже.

Задержка источника — это время распространения тактового сигнала от фактического источника тактового сигнала до точки определения тактового сигнала проектного модуля. На рисунке выше она показана как 3ns.

Задержка сети — это время распространения от точки определения тактового сигнала проектного модуля до тактового входа триггера внутри модуля. Путь распространения может проходить через буфер. На рисунке выше она показана как 1ns.

Задержка источника — это задержка, общая для всех триггеров в проектируемом модуле, поэтому она не влияет на перекос тактовых сигналов.

Тактовое дерево

В цифровом проектировании каждый модуль должен использовать синхронные тактовые схемы. В синхронной схеме триггеры, управляемые одним и тем же тактовым сигналом, совместно образуют тактовый домен. В идеальной схеме тактовый сигнал приходил бы на тактовые входы всех триггеров в одном тактовом домене одновременно. Однако на практике из-за различных задержек эту характеристику тактового сигнала без задержки трудно достичь. Более того, движущая способность тактового сигнала ограничена, что затрудняет независимое обеспечение эффективного разветвления для тактового домена, содержащего много триггеров. Чтобы решить проблемы задержки тактового сигнала и движущей способности, нужна система тактового дерева для управления тактовым сигналом, обеспечивающая хорошие временные характеристики и движущую способность.

Тактовое дерево — это сетевая структура, построенная путем балансировки множества буферных ячеек. Обычно оно строится от единственной точки источника тактового сигнала через каскады буферных ячеек. Фактическая структура тактового дерева с добавленными тактовыми буферами (оранжевые треугольные модули на рисунке) показана ниже.

Синий символ нарастающего фронта обозначает время перехода тактового сигнала. Красная сплошная линия обозначает задержку тактового сигнала, включая задержку сети и задержку источника. Зеленая пунктирная линия обозначает неопределенность тактового сигнала, включая перекос тактового сигнала и дрожание тактового сигнала.

Дерево тактовых сигналов используется не для сокращения времени прихода тактового сигнала к каждому триггеру, а для уменьшения разницы во времени между приходами к триггерам. Обычно проектировщики бэкенда завершают проектирование дерева тактовых сигналов, вставляя буферы тактового сигнала. Проектировщикам фронтенда обычно необходимо обеспечить корректность схемы тактирования и функциональности цифровой логики.

Другие классификации тактовых сигналов:

Синхронные и асинхронные тактовые сигналы

"4.1 Синхронные и асинхронные"содержит подробное объяснение. Когда тактовые сигналы имеют один и тот же источник и удовлетворяют соотношению целочисленной кратности, их обычно можно считать синхронными. Определение синхронных тактовых сигналов в цифровом проектировании довольно широкое. Логика в пределах одного тактового домена не требует обработки синхронизации.

Далее рассмотрим понятие синхронного тактового сигнала с точки зрения синхронных схем.

Синхронная схема — это схема, состоящая из последовательностных и комбинационных логических схем. Её особенность в том, что тактовые входы всех триггеров соединены вместе и подключены к входу системного тактового сигнала. Состояние схемы может измениться только при поступлении тактового импульса. Изменённое состояние сохраняется до прихода следующего тактового импульса. В течение этого периода, независимо от того, изменяется ли внешний вход x, каждое состояние в таблице состояний устойчиво.

Стробируемый тактовый сигнал

Основной принцип стробируемого тактового сигнала: когда сигнал разрешения активен, тактовый сигнал включён. Когда сигнал разрешения неактивен, тактовый сигнал выключен.

Поскольку стробируемый тактовый сигнал может в нужные моменты отключать рабочий тактовый сигнал, стробируемые тактовые сигналы широко используются в проектировании с низким энергопотреблением. Простейшая логика реализации стробируемого тактового сигнала — напрямую выполнить логическое И сигнала разрешения с тактовым сигналом, но это небезопасно и подвержено глитчам. Подробное введение в стробируемые тактовые сигналы см. в "6.4 Проектирование с низким энергопотреблением на уровне RTL (часть 2)".

Двухфронтовый тактовый сигнал

Некоторые модули могут выполнять передачу данных как по переднему, так и по заднему фронту тактового сигнала, достигая удвоенной скорости передачи данных.

DDR (Double Data Rate) SDRAM — типичный пример использования передачи данных по обоим фронтам.

Типичная схема передачи данных DDR показана ниже.

Далее выполняется простая симуляция поведения передачи данных по обоим фронтам.

Основная идея дизайна — использовать оба фронта тактового сигнала для чтения данных, а затем использовать сигнал выбора кристалла, противоположный тактовому сигналу, для выбора и вывода данных, тем самым завершая передачу данных по обоим фронтам тактового сигнала.

Описание кода на Verilog приведено ниже.

Пример

module double_rate(
    input               rstn ,
    input               clk,
    input               csn,

    input [7:0]         din,
    input               din_en,
    output [7:0]        dout,
    output              dout_en);

   //захват по posedge
   reg [7:0]            datap_r ;
   reg                  datap_en_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         datap_r        <= 'b0 ;
         datap_en_r     <= 1'b0 ;
      end
      else if (din_en) begin
         datap_r        <= din ;
         datap_en_r     <= 1'b1 ;
      end
      else begin
         datap_en_r     <= 1'b0 ;
      end
   end

   //захват по отрицательному фронту
   reg [7:0]            datan_r ;
   reg                  datan_en_r ;
   always @(negedge clk or negedge rstn) begin
      if (!rstn) begin
         datan_r        <= 'b0 ;
         datan_en_r     <= 1'b0 ;
      end
      else if (din_en) begin
         datan_r        <= din ;
         datan_en_r     <= 1'b1 ;
      end
      else begin
         datan_en_r     <= 1'b0 ;
      end
   end

   assign dout = !csn ? datap_r : datan_r ;
   assign dout_en = datan_en_r | datap_en_r ;
endmodule

Описание тестбенча следующее: тактовая частота модуля передачи данных по двум фронтам составляет 100MHz, но скорость входных данных — 200MHz.

Пример

`timescale 1ns/1ps

module test ;
   reg          clk_100mhz, clk_200mhz ;
   reg          rstn ;
   reg          csn ;
   reg [7:0]    din ;
   reg          din_en ;
   wire [7:0]   dout ;
   wire         dout_en ;

   always #(2.5)    clk_200mhz  = ~clk_200mhz ;
   always @(posedge clk_200mhz)
                    clk_100mhz  = ~clk_100mhz ;

   initial begin
      clk_100mhz  = 0 ;
      clk_200mhz  = 0 ;
      rstn        = 0 ;
      din         = 0 ;
      din_en      = 0 ;
      csn         = 0 ;
      //начать работу
      #11 rstn    = 1 ;
      @(negedge clk_100mhz) ;
      din_en      = 1 ;
      #0.2 ;
      csn         = 1 ; // Когда csn=1, выводить данные, выбранные по спадающему фронту.
      //сгенерировать csn
      forever begin
         @(posedge clk_100mhz) ;
         #0.2 ;         //Добавить небольшую задержку для обеспечения правильного захвата данных
         csn = 0 ;      //Когда csn=0, выводить данные, выбранные по нарастающему фронту
         @(negedge clk_100mhz) ;
         #0.2 ;
         csn = 1 ;      //Когда csn=1, выводить данные, выбранные по спадающему фронту
      end
   end

   always @(negedge clk_200mhz) begin
      din <= {$random()} % 8'hFF ;  //Сгенерировать случайные данные для передачи
   end

   double_rate u_double_rate(
     .rstn      (rstn),
     .clk       (clk_100mhz),
     .csn       (csn),
     .din       (din),
     .din_en    (din_en),
     .dout      (dout),
     .dout_en   (dout_en));

   initial begin
      forever begin
         #100;
         if ($time >= 10000)  $finish ;
      end
   end

endmodule // test

Результаты моделирования для первых нескольких данных приведены ниже.

Как видно из рисунка, передача данных происходит нормально, а скорость в два раза превышает тактовую частоту.

Это лишь простое моделирование передачи данных по обоим фронтам тактового сигнала, а не моделирование принципа работы DDR. Принцип работы DDR с удвоенной скоростью передачи данных гораздо сложнее, чем это моделирование.

Однако в целом не рекомендуется использовать логику с двумя фронтами тактового сигнала, главным образом по следующим причинам.

В блоке always нельзя использовать в списке чувствительности одновременно и нарастающий, и спадающий фронты, а одну и ту же переменную нельзя присваивать в двух блоках always. Например, следующее описание неверно. Хотя компиляция RTL может не выдать ошибку, это нельзя синтезировать в реальную схему. Это приводит к трудностям при обмене сигналами.

   always @(posedge clk or negedge clk) begin

Скорость передачи данных в два раза превышает частоту тактирования данных. Если для RTL-моделирования используется логика по нарастающему и спадающему фронтам, также требуется сигнал выбора кристалла (chip-select), переключающийся с той же частотой, что и тактовый сигнал; если сигнал chip-select не используется, внутрь модуля следует ввести тактовый сигнал из того же источника с удвоенной частотой тактирования данных, чтобы данные выбирались нормально.

При использовании логики с двумя фронтами тактового сигнала необходимо задать корректные ограничения как для нарастающего, так и для спадающего фронта. Ограничения тактового сигнала становятся сложными, требования к размещению и трассировке — более строгими, а сложность отладки возрастает.

Проектирование с использованием двух фронтов тактового сигнала требует высокого качества тактового сигнала, и при проектировании дерева тактового сигнала необходимо учитывать множество факторов.

Загрузка исходного кода для этой главы

Скачать