Ключевые слова: распределённая задержка, сосредоточенная задержка, задержка пути

Большинство предыдущих моделирований были предназначены для проверки правильности функционирования цифровых схем, где передача сигналов была идеальной и не имела задержки. Однако реальные логические компоненты и пути передачи между ними имеют задержки. Поэтому необходимо проверять, удовлетворяет ли задержка в проекте временным ограничениям реальной схемы. Для проверки временных характеристик можно использовать временное моделирование, то есть во время моделирования к компонентам или путям добавляется информация о задержках, соответствующая реальным условиям, и выполняются соответствующие расчёты, чтобы определить, удовлетворяются ли временные требования.

Статический временной анализ (STA) также является методом проверки временных характеристик. Он не проверяет, корректна ли логическая функция; он только вычисляет и анализирует временные характеристики в проекте, чтобы определить, есть ли проекты, нарушающие временные ограничения. STA работает быстро и позволяет быстро локализовать проблемы, но игнорирует некоторые асинхронные проблемы.

Поэтому "STA + временное моделирование" — это относительно полный и безопасный метод проверки временных характеристик. В этом руководстве даётся лишь краткое введение во временное моделирование, а STA пока не рассматривается.

В основном существует 3 типа моделей задержки:Распределённая задержка, сосредоточенная задержка и задержка пути.

Распределённая задержка

Распределённая задержка требует определения задержек для каждого независимого компонента в схеме; разные пути имеют разные задержки, как показано на рисунке ниже.

Модель распределённой задержки на Verilog в основном совпадает с методом создания экземпляров логических элементов и указания значений задержки.

Пример

module and4(
   output       out,
   input        a, b, c, d);

   wire         an1, an2 ;
   and #1       (an1, a, b);
   and #2       (an2, c, d);
   and #1.5     (out, an1, an2);
endmodule

Операторы непрерывного присваивания (assign) также могут использоваться для задания распределённой задержки.

Пример

module and4(
   output       out,
   input        a, b, c, d);

   wire         an1, an2 ;
   assign #1    an1 = a & b ;
   assign #2    an2 = c & d ;
   assign #1.5  out = an1 & an2 ;
endmodule

Сосредоточенная задержка

Сосредоточенная задержка концентрирует накопленные задержки всех путей в последнем логическом элементе.

Задержка до последнего логического элемента различается для разных путей; в этом случае максимальная задержка берётся в качестве задержки последнего логического элемента.

Преобразование приведённой выше схемы распределённой задержки в схему сосредоточенной задержки выглядит следующим образом.

Verilog-модель сосредоточенной задержки выглядит следующим образом.

Пример

module and4(
   output       out,
   input        a, b, c, d);

   wire         an1, an2 ;
   and          (an1, a, b);
   and          (an2, c, d);
   and #3.5     (out, an1, an2); //установить максимальную задержку на последнем логическом элементе
endmodule

Задержка пути

Задержка пути задаёт времена задержки для всех путей от каждого входного вывода к каждому выходному выводу.

Схема задержки пути выглядит следующим образом.

Модель задержки пути должна быть определена с использованием ключевого слова specify.

Verilog-модель задержки пути выглядит следующим образом; конкретный метод определения будет подробно представлен в следующем разделе.

Пример

module and4(
   output       out,
   input        a, b, c, d);

   указать
      (a => out) = 2.5 ;
      (b => out) = 2.5 ;
      (c => out) = 3.5 ;
      (d => out) = 3.5 ;
   endspecify

   wire         an1, an2 ;
   and          (an1, a, b);
   and          (an2, c, d);
   and          (out, an1, an2);
endmodule

Сравнение моделей задержек

  • Распределённая задержка: распределённая задержка распределяет время задержки по каждому логическому элементу, но по-прежнему не может описать различия в задержке на разных выводах внутри базового элемента. Когда масштаб проектирования становится большим, структура усложняется.
  • Сосредоточенная задержка: этот метод имеет простую модель и подходит для схем малого масштаба, но не может описать задержки разных путей от входа до выхода.
  • Задержка пути: она задаёт задержки между выводами, и информация о задержке является относительно полной. Хотя информации больше, её проще реализовать для крупномасштабных схем. Поскольку разработчикам не нужно заботиться о внутренней логике реализации модуля, им нужно знать только задержку от входных до выходных выводов. Даже если внутренняя логика модуля изменится, спецификация задержки пути может остаться неизменной.

Поэтому информация о задержках в большинстве библиотек логических элементов приводится в форме задержки пути. Многие интегральные модули также могут напрямую получать задержки пути из своих технических описаний, что очень удобно.

Скачать исходный код главы

Скачать