Ключевые слова: синхронный сброс, асинхронный сброс

Чтобы гарантировать, что система имеет четкое и стабильное начальное состояние после включения питания или может восстановиться до нормального начального состояния, когда рабочее состояние системы нарушено, в проектировании цифровых систем необходим модуль схемы сброса. Ненормальные схемы сброса могут вызвать функциональные нарушения всей системы, поэтому в определенной степени важность схемы сброса не меньше важности схемы тактирования.

Схемы сброса можно разделить на синхронный сброс и асинхронный сброс.

Синхронный сброс

Синхронный сброс означает, что сигнал сброса действует, когда приходит активный фронт тактового сигнала. Без тактового сигнала, как бы ни изменялся сигнал сброса, схема не выполнит операцию сброса.

Типичное описание кода синхронного сброса выглядит следующим образом:

Пример

module sync_reset(
    input       rstn,  // сигнал синхронного сброса
    input       clk,   // тактовый сигнал
    input       din,   // входные данные
    output reg  dout   // выходные данные
    );
   
    always @(posedge clk) begin   // сигнал сброса не должен добавляться в список чувствительности
        if(!rstn)  dout <= 1'b0 ; // сигнал rstn синхронен с тактовым сигналом clk
        else       dout <= din ;
    end
   
endmodule

Этот описательный код часто синтезируется в следующую схему:

Преимущества синхронного сброса: сигналы синхронны, можно фильтровать глитчи в сигнале сброса и облегчать временной анализ.

Недостатки синхронного сброса: большинство ячеек триггеров не имеют вывода синхронного сброса, поэтому использование синхронного сброса требует дополнительных логических ресурсов. Кроме того, длительность сигнала сброса должна быть больше одного тактового цикла, иначе сигнал сброса может быть пропущен.

Асинхронный сброс

Асинхронный сброс означает, что независимо от прихода тактового сигнала, пока сигнал сброса активен, схема будет выполнять операцию сброса.

Типичное описание кода асинхронного сброса выглядит следующим образом:

Пример

module async_reset(
    input       rstn,  // асинхронный сигнал сброса
    input       clk,   // тактовый сигнал
    input       din,   // входные данные
    output reg  dout   // выходные данные
    );
   
    // сигнал сброса должен быть добавлен в список чувствительности
    always @(posedge clk or negedge rstn) begin
        if(!rstn)  dout <= 1'b0 ; // сигнал rstn асинхронен по отношению к тактовому сигналу clk
        else       dout <= din ;
    end
   
endmodule

Этот код часто синтезируется в следующую схему:

Преимущества асинхронного сброса: большинство ячеек триггеров имеют асинхронный вход сброса, что не занимает дополнительных логических ресурсов. Более того, сигнал асинхронного сброса используется напрямую без обработки, что делает проект относительно простым, а распознавание сигнала — быстрым и удобным.

Недостатки асинхронного сброса: между сигналом сброса и тактовым сигналом нет определённой временной связи, поэтому асинхронный сброс может легко вызывать нарушения временных параметров снятия и восстановления. Кроме того, асинхронный сброс легко подвержен влиянию глитчей, что приводит к неожиданным операциям сброса.

Асинхронный сброс, синхронное снятие

Учитывая такие факторы, как проектирование и ресурсы, в проектировании цифровых систем обычно используется асинхронный сброс.

Чтобы устранить недостатки асинхронного сброса, схемы сброса часто используют метод проектирования «асинхронный сброс, синхронное снятие». То есть, когда приходит сигнал сброса, он не синхронизируется тактовым сигналом; когда сигнал сброса снимается, его необходимо синхронизировать с тактовым сигналом.

Типичное описание кода асинхронного сброса с синхронным снятием выглядит следующим образом:

Пример

module areset_srelease(
    input       rstn,  // асинхронный сигнал сброса
    input       clk,   // тактовый сигнал
    input       din,   // входные данные
    output reg  dout   // выходные данные
    );
     
    reg   rstn_r1, rstn_r2;
    always @ (posedge clk or negedge rstn) begin
        if (!rstn) begin
            rstn_r1 <= 1'b0;     // асинхронный сброс
            rstn_r2 <= 1'b0;  
        end
        else begin
            rstn_r1 <= 1'b1;     // синхронное снятие
            rstn_r2 <= rstn_r1;  // синхронизировать с помощью задержки (перетактования); временную разницу можно задержать еще на несколько тактов
        end
    end
     
    // Использовать rstn_r2 в качестве синхронного сброса; сигнал сброса можно добавить в список чувствительности
    always @ (posedge clk or negedge rstn_r2) begin
        if (!rstn_r2) dout <= 1'b0; // синхронный сброс
        else          dout <= din;
    end

endmodule

Это описание кода часто синтезируется в следующую схему:

Следует отметить, что схемы сброса потребляют больше аппаратной логики и ресурсов площади, увеличивая сложность проектирования системы. Триггеры без вывода сброса также обладают относительно более высокой производительностью. Поэтому в некоторых цифровых проектах, где начальные значения не влияют на логическую корректность — например, в некоторых частях обработки данных в трактах данных или в некоторых регистрах высокоскоростных конвейеров — рассмотрение удаления сброса может позволить достичь оптимальной производительности.

Для удобного и быстрого моделирования других функций логики без сброса, сбросы во всех цифровых проектах этого руководства вводятся как асинхронные сбросы из тестбенча, без учёта вопросов синхронизации схемы сброса. При реальном проектировании цифровых систем схему сброса необходимо проектировать отдельно, тщательно и осмотрительно.