Verilog предоставляет множество системных задач, которые могут работать с файлами. К часто используемым системным задачам в основном относятся:

  • Открытие/закрытие файла: $fopen, $fclose, $ferror
  • Запись в файл: $fdisplay, $fwrite, $fstrobe, $fmonitor
  • Запись строки: $sformat, $swrite
  • Чтение из файла: $fgetc, $fgets, $fscanf, $fread
  • Позиционирование в файле: $fseek, $ftell, $feof, $frewind
  • Загрузка памяти: $readmemh, $readmemb

При использовании задач файловых операций (особенно обращая внимание на $sforamt, $gets, $sscanf и т. д.) для работы с файлами необходимо определить, какую системную задачу использовать, исходя из характера файла и содержимого переменных, и обеспечить согласованность параметров и типов переменных чтения/записи с содержимым файла. Не путайте строковые типы с типами с несколькими основаниями.

Открытие/закрытие файла

Системная задачаФормат вызоваОписание задачи
Открытие файлаfd = $fopen("fname", mode) ;fname — имя открываемого файла
fd — возвращаемый 32-битный дескриптор файла
--- При правильном открытии fd не равен нулю
--- При возникновении ошибки во время открытия fd равен нулю
mode используется для указания режима открытия файла
Закрытие файла$fclose(fd) ;Закрыть соответствующий файл, описываемый fd
Ошибка файлаerr = $ferror(fd, str) ;Когда файл открывается нормально:
--- и err, и str равны нулю,
Когда при открытии файла возникает ошибка:
--- err возвращает ненулевое значение, указывающее на ошибку
--- str возвращает ненулевое значение, содержащее тип ошибки
--- Официальная рекомендация состоит в том, что длина str составляет 640 bits

Пример кода выглядит следующим образом:

Пример

  //открыть/закрыть файл
   integer fd1, fd2 ;
   integer err1, err2 ;
   reg [320:0] str1, str2 ; //Переменная для типа ошибки также может быть поддерживаемым строковым типом
   initial begin
      //существующий файл
      fd1 = $fopen("./DATA_RD.HEX", "r");    //Открыть существующий файл
      err1 = $ferror(fd1, str1);
      $display("Дескриптор File1: %h.", fd1 );//Ненулевое значение
      $display("Номер ошибки Error1: %h.", err1 );  //0
      $display("Информация об ошибке Error2: %s.", str1 );    //0
      $fclose(fd1);
      //несуществующий файл
      fd2 = $fopen("../../FILE_NOEXIST.HEX", "r");//Открываемый файл не существует
      err2 = $ferror(fd2, str2);
      $display("Дескриптор File2: %h.", fd2 ); //0
      $display("Номер ошибки Error2: %h.", err2 );   //Ненулевое значение
      $display("Информация об ошибке Error2: %s.", str2 );     //Ненулевое значение
      $fclose(fd2);
   end

Типы режимов открытия файлов и их описания приведены ниже:

rОткрыть текстовый файл только для чтения, разрешено только чтение данных.
wОткрыть текстовый файл только для записи, разрешена только запись данных. Если файл существует, исходное содержимое файла будет удалено. Если файл не существует, создайте новый файл.
aОткрыть текстовый файл в режиме добавления и записывать данные в конец файла. Если файл не существует, создайте новый файл.
rbОткрыть двоичный файл только для чтения, разрешено только чтение данных.
wbОткрыть или создать двоичный файл только для записи, разрешена только запись данных.
abОткрыть двоичный файл в режиме добавления и записывать данные в конец файла.
r+Открыть текстовый файл для чтения и записи, разрешены и чтение, и запись.
w+Открыть или создать текстовый файл для чтения и записи, разрешены как чтение, так и запись. Если файл существует, исходное содержимое файла будет удалено. Если файл не существует, создайте новый файл.
a+Открыть текстовый файл для чтения и записи, разрешая и чтение, и запись. Если файл не существует, создать новый файл. Чтение начинается с начала файла, запись выполняется только в режиме добавления.
rb+Открыть двоичный файл для чтения и записи, аналогично "r+".
wb+Открыть или создать двоичный файл для чтения и записи, аналогично "w+".
ab+Открыть двоичный файл для чтения и записи, аналогично "a+".

Запись в файл

Системные задачи для записи файлов в основном включают: $fdisplay, $fwrite, $fstrobe, $fmonitor, а также соответствующие им системные задачи со встроенными форматами, такие как $fdisplayb, $fdisplayh, $fdisplayo и т. д.

Формат вызоваОписание задачи
$fdisplay(fd, arguments) ;Записать в файл последовательно или условно, с автоматическим переводом строки.
$fwrite(fd, arguments) ;Записать в файл последовательно или условно, без автоматического перевода строки.
$fstrobe(fd, arguments) ;Запись в файл со стробированием после выполнения оператора.
$fmonitor(fd, arguments) ;Записывать в файл при каждом изменении данных.

По сравнению со стандартными задачами вывода $display, $write, $strobe, $monitor, системные задачи записи в файл требуют дополнительного файлового дескриптора fd в формате использования, но все остальные условия печати и временные характеристики согласуются с соответствующими им задачами вывода.

Пример записи в файл с использованием режима добавления выглядит следующим образом:

Пример

  //(2) запись в файл
   integer fd ;
   integer err, str ;
   initial begin
      fd = $fopen("./DATA_RD.HEX", "a+");  //Открыть в режиме добавления в конце
      err = $ferror(fd, str);
      if (!err) begin
         $fdisplay(fd, "Новые данные 1: %h", fd) ;
         $fdisplay(fd, "Новые данные 2: %h", str) ;
         $fdisplay(fd, "Новые данные 3: %h", err) ;
         //$write(fd, "New data3: %h", err) ; //Вывести последнюю строку без символа новой строки
      end
      $fclose(fd);
   end

Откройте файл DATA_RD.HEX, и вы увидите, что в конец файла были добавлены 3 строки данных.

Запись строк

Verilog также предоставляет системные задачи $swrite и $sformat для записи данных в строки.

Формат вызоваОписание задачи
$swrite(reg, list_of_arguments) ;Записывает строки в переменную reg последовательно или условно.
len = $sformat(reg, format_str, arguments) ;Записывает строки в переменную reg в соответствии с форматом format_str.
Формат соответствует заданному в $display.
Не рекомендуется опускать второй параметр format_str.
Может возвращать длину строки len.

Второй параметр format у $sformat — строкового типа, и его обычно не рекомендуется опускать. Этот параметр задаёт тип входной переменной. При указании типа можно также включать другую строковую информацию. О типах и использовании см. функцию отображения $display. Этот параметр также может быть регистрового типа, но хранимые данные должны быть обычными строковыми данными.

Пример кода для записи строк выглядит следующим образом:

Пример

   //(3) запись строки
   reg [299:0] str_swrite, str_sformat;
   reg [63:0] str_buf ;
   integer    len, age ;
   initial begin
      #20 ;
      str_buf   = "example!" ;
      age       = 9 ;

      //$swrite записывает строку, содержащую переменные, в указанном формате
      $swrite(str_swrite, "%s age is %d", str_buf, age) ;
      $display("%s", str_swrite);
      //$swrite напрямую записывает строку без переменных
      $swrite(str_swrite, "years ", "old.") ;
      $display("%s", str_swrite);
      //$swrite записывает строку, содержащую переменные, без заданного формата, не рекомендуется
      $swrite(str_swrite, age) ;
      $display("$swrite тест ошибки: %d", str_swrite);

      $display();
     //$sformat записывает строку, содержащую переменные, в заданном формате
      $sformat(str_sformat, "Я выучил за %s", str_buf) ;
      $display("%s", str_sformat);
      //$sformat напрямую записывает строку без переменных и получает длину строки
      len = $sformat(str_sformat, "в течение 4 лет!") ;
      $display("%s", str_sformat);
      $display("$sformat длина: %d", len);
      //$sformat напрямую записывает несколько строк без переменных за один раз, не рекомендуется
      $sformat(str_sformat, "в течение", "4", "лет!") ;
      $display("$sformat тест ошибки: %s", str_sformat);
   end

Игнорируя пробелы в выводимой информации, отладочный вывод выглядит так:

Из этого видно, что $sformat и $swrite можно использовать одинаковым образом. Например, $sformat может записать строку в указанном формате или записать строку без переменных только один раз. В этом случае $sformat эквивалентно отсутствию указания типа переменной во втором параметре, поэтому третий параметр следует опустить.

$swrite также может записывать несколько строк без переменных за один раз, тогда как $sformat не допускает такого вызова.

Также рекомендуется указывать тип переменной при использовании $swrite для записи строк, содержащих переменные; в противном случае результат может быть непредсказуемым.

Чтение файлов

Системная задачаФормат вызова и описание 
Чтение файла посимвольноc = $fgetc( fd ) ; 
 Выводит данные fd в переменную c в символьном формате; c должна иметь ширину не менее 8 бит.
При возникновении ошибки чтения c равно EOF(-1); можно использовать $ferror для проверки типа ошибки.
 
Запись символа в буферcode = $ungetc(c, fd ) ; 
 Записывает символ c в буфер файла fd.
Значение c возвращается при следующем вызове $fgetc; содержимое самого файла fd не изменяется.
При обычной записи в буфер возвращаемый код равен 0; при возникновении ошибки возвращаемый код равен EOF.
 
Чтение файла построчноcode = $fgets(str, fd) 
 Считывать символы непрерывно до тех пор, пока переменная str не будет заполнена, или строка не будет прочитана полностью, или не будет достигнут конец файла.
При обычном чтении возвращаемый код равен количеству прочитанных строк (раз); при возникновении ошибки code равен 0.
 
Чтение файла по форматуcode = $fscanf(fd, format, args) ; 
 Считывать данные из файла fd в переменную args в соответствии с форматом format.
Для format обратитесь к описанию формата $display.
Условие остановки для одного чтения — пробел или новая строка.
При возникновении ошибки чтения возвращаемый код равен 0.
 
Чтение строки по форматуcode = $sscanf(str, format, args) ; 
 Считать переменную str строкового типа в переменную args в соответствии с форматом format.
в переменную data_get, содержимое в data_get будет некорректным.
 
Чтение файла в двоичном режиме.code = $fread(store, fd, start, count) ; 
 Считать данные из файла fd в массив или регистровую переменную store в формате двоичного потока данных.
start — начальный адрес файла, а count — длина чтения.
Если start/count не указаны, все данные будут помещены в переменную store.
Если store имеет регистровый тип, параметры start/count недействительны. Чтение прекращается после того, как переменная store будет один раз заполнена данными.
 
В качестве примера используется файл DATA_RD.HEX из симуляции "запись в файл" как эталонный файл для чтения. Содержимое файла следующее.
c0dec0de
5555aaaa
12345678
aaaa5555
New data1: 80000003
New data2: 00000000
New data3: 00000000

Примеры вызовов $fgetc и $ungetc

Пример

   //(4.1) чтение символа
   целое число      i ;
   reg [31:0]   char_buf ;
   initial begin
      #30 ;
      fd = $fopen("DATA_RD.HEX", "r");
      $write("Прочитанный символ: ");
      err = $ferror(fd, str);
      if (!err) begin
         for (i=0; i<13; i++) begin
            char_buf[7:0] = $fgetc(fd) ;  //Чтение по одному символу
            $write("%c", char_buf[7:0]) ; //Печатать отдельные символы по одному без перевода строки
         end
         $write(".\n") ;
      end

      $ungetc("1", fd) ;            //Записать в буфер файла 3 раза подряд
      $ungetc("2", fd) ;
      $ungetc("3", fd) ;
      char_buf[7:0]   = $fgetc(fd) ;  //прочитать 3
      char_buf[15:8]  = $fgetc(fd) ;  //прочитать 2
      char_buf[23:16] = $fgetc(fd) ;  //прочитать 1, конец буфера чтения
      char_buf[31:24] = $fgetc(fd) ;  //прочитать символ
      $display("Символ, прочитанный после $ungetc: %s", char_buf);
      $fclose(fd);
   end

Результаты моделирования следующие.

Как видно из рисунка, 13 символов, прочитанных с помощью $fgetc, корректны, и среди прочитанных символов есть символы перевода строки.

После того как $ungetc записывает символьные данные в файловый буфер, с помощью $fgetc можно затем прочитать символьные данные в файловом буфере. Чтение/запись следует принципу «первым пришёл — последним вышел» (FILO, First in Last out), что эквивалентно помещению в стек. Когда символьные данные "123" записываются первыми, считанные данные — "321".

После того как файловый буфер полностью прочитан, при повторном чтении символьных данных считанные данные по-прежнему следуют позиции последнего чтения файла, то есть символу "a" в "a123" в логе.

В течение этого процесса содержимое файла DATA_RD.HEX никогда не менялось.

Пример вызова $fgets

Пример

   //(4.2) чтение строки
   integer      code ;
   reg [99:0]   line_buf [9:0] ;
   initial begin
      #31 ;
      fd = $fopen("DATA_RD.HEX", "r");
      err = $ferror(fd, str);
      if (!err) begin
         for (i=0; i<6; i++) begin  //Чтение построчно в строковом формате
            code = $fgets(line_buf[i], fd) ;  //Содержит "\n" в конце, поэтому будут напечатаны 2 строки
            $display("Получить данные строки%d: %s", i, line_buf[i]) ;
         end
      end
      //Отображение в шестнадцатеричном виде покажет соответствующие символы ASCII-кода
      $display("Показать шестнадцатеричные данные строки%d: %h", 2, line_buf[2]) ;
      $display("Показать шестнадцатеричные данные строки%d: %h", 4, line_buf[4]) ;
      $fclose(fd) ;
   end

Результаты моделирования следующие.

Первые 4 строки данных считываются и отображаются как строковый тип, результаты нормальны.

При чтении 5-й строки файла из-за ограничения ширины переменной line_buf в 100 бит содержимое файла "New data1: 80000003 " нужно прочитать за 2 отдельные операции.

Поскольку каждая строка заканчивается символом новой строки "\n", при использовании функции $display будет напечатана дополнительная пустая строка.

При чтении как строкового типа и отображении данных в шестнадцатеричном виде соответствующее содержимое данных файла не может быть отображено наглядно. Например, во второй строке отображается не "12345678,", а соответствующий ей ASCII-код. Поэтому задача $fgets читает в соответствии со строковым типом; на это нужно обратить внимание.

Примеры вызовов $fscanf и $sscanf

Пример

   //(4.3) $fscanf/$sscanf
   reg [31:0]   data_buf [9:0] ;
   reg [63:0]   string_buf [9:0] ;
   reg [31:0]   data_get ;
   reg [63:0]   data_test ;
   initial begin
      #32 ;
      fd = $fopen("DATA_RD.HEX", "r");
      err = $ferror(fd, str);
      if (!err) begin
         for (i=0; i<4; i++) begin
            //Прочитать и отобразить первые 4 строки данных в шестнадцатеричном виде
            код = $fscanf(fd, "%h", data_buf[i]);
            $display("$fscanf прочитанные данные%d: %h", i, data_buf[i]) ;
         end
         for (i=4; i<6; i++) begin
            //Прочитать и отобразить последние 2 строки данных как строковый тип
            код = $fscanf(fd, "%s", string_buf[i]);
            $display("$fscanf прочитанные данные%d: %s", i, string_buf[i]) ;
         end
      end

      //(1) $sscanf: исходная переменная data_test является строковым типом
      data_test = "fedcba98" ;
      код = $sscanf(data_test, "%h", data_get);
      $display("$sscanf чтение data0: %h", data_get) ;
      //(2) $sscanf: сначала преобразовать исходную переменную data_test в строковую переменную
      code = $sformat(data_test, "%h", data_buf[2]);
      код = $sscanf(data_test, "%h", data_get);
      //Прямой ввод шестнадцатеричной переменной не рекомендуется
      //code = $sscanf(data_buf[2], "%h", data_get);
      $display("$sscanf чтение data0: %h", data_get) ;
      $fclose(fd) ;
   end

Результаты моделирования следующие.

Использование $fscanf для чтения и отображения первых 4 строк файла в шестнадцатеричном виде и последних 2 строк как строкового типа, все результаты нормальны.

При использовании $sscanf для чтения содержимого регистра-источника и последующего перемещения его в регистр-приёмник содержимое в регистре-источнике должно быть данными строкового типа.

Например, при использовании $sscanf для перемещения шестнадцатеричных данных data_buf

Если $sscanf используется напрямую для перемещения данных data_buf в шестнадцатеричном формате

Просто секретный совет: регистры можно напрямую присваивать друг другу!!!

Пример вызова $fread

Пример

   //(4.4) $fread
   reg [71:0]   bin_buf [3:0] ; //В каждой строке 8 элементов данных типа word и 1 символ новой строки
   reg [143:0]  bin_reg ;
   initial begin
      #40 ;
      fd = $fopen("DATA_RD.HEX", "r");
      err = $ferror(fd, str);
      if (!err) begin
         код = $fread(bin_buf, fd, 0, 4); //Чтение типа массив, прочитать 4 раза
         $display("$fread read data %h", bin_buf[0]) ;//Отображение в шестнадцатеричном формате
         $display("$fread read data %h", bin_buf[1]) ;
         $display("$fread read data %s", bin_buf[2]) ;//Отображение строки
         $display("$fread read data %s", bin_buf[3]) ;
      end

      fd = $fopen("DATA_RD.HEX", "r");
      код = $fread(bin_reg, fd); //Чтение одного регистра
      $display("$fread read data %h", bin_reg) ;
      $fclose(fd) ;
   end

Результаты моделирования следующие.

Когда $fread читает файл в двоичном режиме, начальный адрес и длина чтения являются параметрами для задания переменных типа массив.

Если тип переменной, хранящей данные, — это reg-тип, не являющийся массивом, будет выполнено только одно чтение, пока переменная типа reg не заполнится полностью.

Позиционирование в файле

Системные задачиФормат вызоваОписание задачи
Получить позицию в файлеpos = $ftell( fd ) ;Возвращает смещение текущей позиции файла от начала файла; начальный адрес равен 0.
Смещение измеряется в байтах как в единице измерения (8 бит).
Используется вместе с $fseek.
Перемещениеcode = $fseek(fd, offset, type) ;Устанавливает позицию следующего ввода или вывода файла.
offset — устанавливаемое значение смещения.
type — тип операции смещения.
--- 0: Установить позицию на адрес смещения.
--- 1: Установить позицию в текущую позицию плюс смещение.
--- 2: Установить позицию в конец файла плюс смещение. Отрицательные числа часто используются для обозначения смещения назад от конца файла.
Перемещение без смещенияcode = $rewind( fd ) ;Эквивалентно $fseek( fd, 0, 0);
Определить конец файлаcode = $feof(fd) ;Определить, достигнут ли конец файла.
Возвращает 1, когда обнаружен конец файла; в противном случае возвращает 0.

Содержимое файла DATA_RD.HEX можно представить следующим образом.

Если в качестве терминатора используется символ новой строки "\n", размер файла равен: 4x9 + 3x20 = 96 байт.

Код тестирования позиционирования файла выглядит следующим образом:

Пример

   // позиция файла
   reg [31:0]   data4 ;      //Длина регистровой переменной — 4 байта
   reg [199:0]  str_long ;
   integer      pos ;
   initial begin
      #40 ;
      fd = $fopen("DATA_RD.HEX", "r");
      err = $ferror(fd, str);
      if (!err) begin
         //первое чтение
         code = $fscanf(fd, "%h", data4);//Начать чтение с позиции 0
         pos  = $ftell(fd);      //После чтения 8 байт позиция равна 8, координаты (0,8)
         $display("Позиция после чтения: %d", pos) ;
         $display("данные 1-го чтения: %h", data4) ;

         //тип = 0
         code = $fseek(fd, 4, 0) ; //Начать чтение с позиции 4, координаты (0,4)
         code = $fscanf(fd, "%h", data4); //Остановиться, когда прочитан символ новой строки
         pos  = $ftell(fd);      //После чтения 4 байт позиция равна 8, координаты (0,8)
         $display("тип 0: текущая позиция: %d", pos) ;
         $display("тип 0: прочитанные данные: %h", data4) ;
         //type = 1
         code = $fseek(fd, 4, 1) ; //Начать чтение с позиции 4+9=12, по координатам (1,3)
         code = $fscanf(fd, "%h", data4); //Остановиться, когда прочитан символ новой строки
         pos  = $ftell(fd);      //После чтения 5 байт позиция равна 17, координаты (1,8)
         $display("тип 1: текущая позиция: %d", pos) ;
         $display("тип 1: прочитанные данные: %h", data4) ;
         //type = 2
         code = $fseek(fd, -(96-31), 2) ; //Начать чтение с позиции 31, координаты (3,4)
         code = $fscanf(fd, "%h", data4);
         pos  = $ftell(fd);      //После чтения 4 байт позиция равна 35, координаты (3,8)
         $display("тип 2: текущая позиция: %d", pos) ;
         $display("тип 2: прочитанные данные: %h", data4) ;

         //перемотка для чтения
         code   = $rewind(fd) ;//Сбросить позицию указателя файла на начало файла
         pos    = $ftell(fd);  //На данный момент позиция равна 0
         $display("Позиция после $rewind: %d", pos) ;
         //прочитать всё содержимое файла
         while (!$feof(fd)) begin
            code   = $fgets(str_long, fd);
            $write("Прочитано: %s", str_long) ;
         end
         $fclose(fd) ;
      end
   end

Результаты моделирования следующие.

Как видно из рисунка, в конце журнала выводится дополнительная строка данных. Это связано с тем, что в конце файла DATA_RD.TXT всё ещё есть пустая строка (результат операции перевода строки). Системная задача $feof не считает эту пустую строку концом файла, поэтому возвращаемое значение по-прежнему равно 0. Однако в этой строке фактически нет данных, поэтому прочитанные данные неконтролируемы.

Чтобы устранить влияние символа перевода строки в последней строке данных файла, последнюю системную задачу записи в файл $fdisplay в примере "запись в файл" можно заменить на $write.

Остальная часть журнала вместе с комментариями к коду показывает, что моделирование выполнено правильно, поэтому здесь не даётся единого объяснения.

Загрузка памяти

Системные задачиФормат вызова и описание 
Загрузить шестнадцатеричный файл$readmemh("fname", mem, start_addr, finish_addr) 
 fname — имя файла данных.
mem — переменная типа массива/памяти.
start_addr и finish_addr — это начальный адрес и конечный адрес соответственно.
start_addr и finish_addr можно опустить. В этом случае условием остановки загрузки данных является полное заполнение переменной памяти mem или полное чтение файла.
Содержимое файла должно содержать только пробельные символы (или символы новой строки/пробела), двоичные или шестнадцатеричные данные.
Комментарии обозначаются "//". Рекомендуется использовать символы новой строки для разделения данных.
 
Загрузить двоичный файл$readmemb("fname", mem, start_addr, finish_addr) 
 Формат использования такой же, как у $readmemb. 

Содержимое файла DATA_WITHNOTE.HEX следующее. Загрузите содержимое этого файла в переменную памяти.

Пример кода выглядит следующим образом:

Пример

   //6 загрузить память
   reg [31:0]   mem_load [3:0] ;
   initial begin
      #50 ;
      $readmemh("./DATA_WITHNOTE.HEX", mem_load);
      $display("Чтение памяти 1: %h", mem_load[0]) ;
      $display("Чтение памяти 2: %h", mem_load[1]) ;
      $display("Чтение памяти 3: %h", mem_load[2]) ;
      $display("Чтение памяти 4: %h", mem_load[3]) ;
   end

Результаты моделирования следующие:

Скачать исходный код для этой главы

Скачать