Theoretisch werden Signale im schnellen Taktbereich immer Signale abtasten, die aus dem langsamen Taktbereich übertragen werden. Wenn die Takte asynchron sind, können Abtastfehler auftreten, daher ist eine Synchronisation erforderlich. Diese Art der Synchronisation ist relativ einfach und verwendet im Allgemeinen die Delay-Tapping-Methode oder die verzögerte Abtastmethode.
Delay-Tapping-Methode
Die gebräuchlichste Synchronisationsmethode ist die Zweistufen-Flipflop-Pufferungsmethode, allgemein bekannt als Delay-Tapping-Methode. Bevor ein asynchrones Signal in einen anderen Taktbereich eintritt, wird das Signal zweimal hintereinander durch zwei Flipflop-Stufen gepuffert, wodurch Metastabilitätsprobleme, die durch Timing-Verletzungen verursacht werden, wirksam reduziert werden. Das Schaltbild ist unten dargestellt.

In allgemeinen Designs reichen zwei Flipflop-Stufen zum Puffern aus, um die Timing-Anforderungen des Designs zu erfüllen. Eine große Anzahl von Experimenten zeigt, dass eine Pufferung mit drei Flipflop-Stufen mehr als 99% solcher asynchronen Timing-Probleme lösen kann.
Die Verilog-Beschreibung der Delay-Tapping-Funktion mit zwei Flipflop-Stufen und der Erkennung steigender Flanken lautet wie folgt:
Beispiel
input clk1, // Asynchroner langsamer Takt
input sig1, // Asynchrones Signal
input rstn, // Rücksetzsignal
input clk2, // Takt des schnellen Ziel-Taktbereichs
output sig2); // Signal im schnellen Taktbereich synchronisiert
reg [2:0] sig2_r ; // 3-stufiger Puffer; die ersten beiden Stufen zur Synchronisation, die letzten beiden Stufen zur Flankenerkennung
always @(posedge clk2 or negedge rstn) begin
if (!rstn) sig2_r <= 3'b0 ;
else sig2_r <= {sig2_r[1:0], sig1} ; // Puffer
end
assign sig2 = sig2_r[1] && !sig2_r[2] ; // Erkennung der steigenden Flanke
Verfahren der verzögerten Abtastung
Dieses Verfahren zielt hauptsächlich auf die Mehrbit-Datenübertragung ab.
Wenn beispielsweise das Frequenzverhältnis zweier asynchroner Takte 5 beträgt, können Sie zunächst mit dem Verzögerungsabgriffverfahren das Datenfreigabesignal über zwei Registerstufen puffern und dann das Datensignal aus dem langsamen Taktbereich im schnellen Taktbereich abtasten.
Die Grundidee dieses Verfahrens besteht darin, sicherzustellen, dass das Signal im richtigen Moment sicher abgetastet wird, ohne Mehrbit-Datensignale synchronisieren zu müssen, wodurch einige Hardware-Ressourcen eingespart werden.
Die Verilog-Beschreibung der verzögerten Abtastung unter Verwendung des Abgriffverfahrens lautet wie folgt.
Beispiel
// Asynchrone Daten stammen aus einem Modul mit einem Arbeitstakt von 20MHz
module delay_sample(
input rstn,
input clk1,
input [31:0] din,
input din_en,
input clk2,
output [31:0] dout,
output dout_en);
//din_en synchronisieren
reg [2:0] din_en_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn) din_en_r <= 3'b0 ;
else din_en_r <= {din_en_r[1:0], din_en} ;
end
wire din_en_pos = din_en_r[1] && !din_en_r[2] ;
//Daten synchronisieren
reg [31:0] dout_r ;
reg dout_en_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn)
dout_r <= 'b0 ;
else if (din_en_pos)
dout_r <= din ;
end
//Verzögerung von dout_en
always @(posedge clk2 or negedge rstn) begin
if (!rstn) dout_en_r <= 1'b0 ;
else dout_en_r <= din_en_pos ;
end
assign dout = dout_r ;
assign dout_en = dout_en_r ;
endmodule
Das Timing-Ergebnisdiagramm dieser Methode ist unten dargestellt.
Offensichtlich ist es in der clk2-Taktdomäne viel sicherer, Daten zum Zeitpunkt t2 abzutasten und zu puffern als zum Zeitpunkt t1.

Wenn jedoch die langsame Taktdomäne kein Datenfreigabesignal din_en hat oder das Datenfreigabesignal immer aktiv ist, wird die Methode, die steigende Flanke des Datenfreigabesignals in der schnellen Taktdomäne zu erkennen, fehlschlagen. Da das Datenfreigabesignal immer aktiv ist, wird die schnelle Taktdomäne außer beim ersten Datenwort nicht in der Lage sein, die Übertragungszeitpunkte der nachfolgenden Daten zu erkennen.
Die Lösung besteht darin, die Flanke des langsamen Taktsignals in der schnellen Taktdomäne zu erkennen.
Wenn der Frequenzunterschied zwischen den beiden Takten klein ist, kann es notwendig sein, die Daten verzögert zu puffern, um sicherzustellen, dass die abgetasteten Daten dem aktuellen Taktzyklus entsprechen; wenn der Frequenzunterschied groß ist, kann der Datenabtastzeitpunkt durch Zählen ermittelt werden, ohne die Daten zu puffern.
Die Verilog-Beschreibung zum Erkennen der langsamen Taktflanke unter Verwendung des Verfahrens der verzögerten Abtastung durch Zählen lautet wie folgt.
Beispiel
// Asynchrone Daten kommen von einem Modul mit einem 999KHz-Arbeitstakt
module delay_cnt_sample(
input rstn,
input clk1,
input [31:0] din,
input din_en,
input clk2,
output [31:0] dout,
output dout_en);
// 4-stufiger Puffer: 3 Stufen zur Abgriff-Synchronisierung, 1 Stufe zur Flankenerkennung
reg [3:0] edge_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn) edge_r <= 3'b0 ;
else edge_r <= {edge_r[3:0], clk1} ;
end
wire edge_pos = edge_r[2] && !edge_r[3] ;
// Verzögerungszähler: beginnt zu zählen, wenn die steigende Flanke des langsamen Takts erkannt wird
reg [5:0] cnt ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn) cnt <= 6'h3f ;
else if (edge_pos && din_en)
cnt <= 6'h0 ;
else if (cnt != 6'h3f) cnt <= cnt + 1'b1 ;
end
// Datensynchronisation
reg [31:0] dout_r ;
reg dout_en_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn)
dout_r <= 'b0 ;
else if (din_en && cnt == 47) // Ungefähr in der Mitte der Periode des langsamen Takts abtasten
dout_r <= din ;
end
// Das Datenfreigabesignal wird um einen Zyklus verzögert vom Datenabtastzeitpunkt ausgegeben
always @(posedge clk2 or negedge rstn) begin
if (!rstn) dout_en_r <= 1'b0 ;
else if (din_en && cnt==48)
dout_en_r <= 1'b1 ;
else dout_en_r <= 1'b0 ;
end
assign dout = dout_r ;
assign dout_en = dout_en_r ;
endmodule
Das Diagramm des Abtast-Ergebnisses der Datensynchronisation für eine große Frequenzdifferenz ist unten dargestellt.
Wie aus der Abbildung ersichtlich ist, liegt der Abtastzeitpunkt des schnellen Takts etwa in der Mitte der Periode des langsamen Takts, was sehr sicher ist.

Quellcode-Download für dieses Kapitel
Herunterladen