Стробирование тактового сигнала

Обычно тактовое дерево состоит из большого числа буферов и инверторов. Поскольку тактовый сигнал является сигналом с самой высокой частотой переключений в проекте, энергопотребление тактового дерева может достигать 30% от общего энергопотребления проекта. Добавление схемы стробирования тактового сигнала позволяет уменьшить переключательную активность тактового дерева и сэкономить мощность переключений. В то же время снижение переключательной активности тактовых выводов также уменьшает внутреннее энергопотребление регистров. Поэтому применение стробирования тактового сигнала позволяет эффективно снизить энергопотребление.

Принцип реализации

Проще говоря, логика, которая отключает тактовый сигнал, когда модуль или триггер не работает, не влияя на нормальное функционирование, может называться логикой стробирования тактового сигнала. В этом случае тактовый сигнал присутствует не всегда, поэтому его можно образно назвать «стробируемый тактовый сигнал».

Существует в основном три способа реализации стробирования тактового сигнала.

1. Использование логики И

Самый простой метод — напрямую выполнить операцию И между сигналом разрешения тактирования (стробирования) и тактовым сигналом.

Например, выполняя эту операцию над тактовым сигналом блока RAM, код выглядит следующим образом:

Пример

// использовать логику И
module  clkgate_basic
    (
        input           clk ,
        input           clken ,
        input           rstn ,
        input           wr_en ,
        input [3:0]     addr ,
        input [7:0]     data ,
        output [7:0]    q
     );

   //стробирование тактового сигнала
  wire                 clk_gate = clk & clken ;
   ram #(4, 8)
      u1_ram16x8
        (
         .CLK   (clk_gate),
         .A     (addr),
         .D     (data),
         .EN    (clken),
         .WR    (wr_en),
         .Q     (q));

endmodule

Модель RAM выглядит следующим образом:

Пример

module  ram
    #(  parameter       AW = 2 ,
        parameter       DW = 3 )
    (
        input                   CLK ,
        input [AW-1:0]          A ,
        input [DW-1:0]          D ,
        input                   EN ,
        input                   WR ,    //1 для записи и 0 для чтения
        output reg [DW-1:0]     Q
     );

   parameter            MASK = 3 ;

   reg [DW-1:0]         mem [0:(1<<AW)-1] ;
   always @(posedge CLK) begin
      if (EN && WR) begin
         mem[A]  <= D ;
      end
      else if (EN && !WR) begin
         Q       <= mem[A] ;
      end
   end

endmodule

Код тестового стенда выглядит следующим образом:

Пример

`timescale 1ns/1ns
module test ;
   //объявление сигналов
   reg          rstn ;
   reg          clk ;
   reg          clken ;
   reg          wr_en ;
   reg [3:0]    addr ;
   reg [7:0]    data ;
   wire [7:0]   q ;

   initial begin
      rstn      = 0 ;
      #7 rstn   = 0 ;
   end

   always begin
      #50 clk = 0 ;
      #50 clk = 1 ;
   end

   //логика данных
   initial begin
      clken     = 0 ;
      wr_en     = 0 ;
      addr      = 4'h3 ;
      data      = 8'h31 ;
      # 53 ;
      //(1) обычная запись и чтение
      clken     = 1 ;
      wr_en     = 1 ;
      repeat(9) begin
         @(negedge clk) ;
         data   = data + 1 ;
         addr   = addr + 1 ;
      end
      @(negedge clk) ;
      clken     = 0 ;
      wr_en     = 0 ;

      //чтение
      #211;
      addr      = 4'h3 ;
      clken     = 1 ;
      repeat(9) begin
         @(negedge clk) ;
         addr   = addr + 1 ;
      end
      @(negedge clk) ;
      //конец
      clken     = 0 ;
   end // initial begin

   clkgate_basic u_ram_clkgate
    (
        .clk    (clk),
        .clken  (clken),
        .rstn   (rstn),
        .wr_en  (wr_en),
        .addr   (addr),
        .data   (data),
        .q      (q)
     );

   //завершение моделирования
   always begin
      #100;
      if ($time >= 10000)  begin
         #1 ;
         $finish ;
      end
   end

endmodule

Захватите сигналы портов RAM; результаты тестирования приведены ниже.

Как показано на рисунке, во время интервала между операциями чтения и записи тактовый сигнал RAM имеет период, в течение которого он остаётся на уровне 0. Тактовый сигнал не переключается, когда RAM не работает, что на практике также значительно снижает энергопотребление.

Недостатки этого метода также очевидны. Из-за проблем с таймингом или джиттером после выполнения операции AND между сигналом разрешения тактирования и тактовым сигналом легко возникают глитчи, которые могут серьёзно повлиять на цифровые схемы.

В тестбенче выполните неидеальное моделирование сигнала разрешения тактирования, добавив следующий код моделирования:

Пример

      //(2) джиттер в конце чтения
      #985;
      addr      = 4'h3 ;
      clken     = 1 ;
      repeat(9) begin
         @(negedge clk) ;
         addr   = addr + 1 ;
      end
      @(negedge clk) ;
      clken     = 0 ;
      #20 clken = 1 ;
      #21 clken = 0 ;
      #31 clken = 1 ;
      #13 clken = 0 ;

Результаты моделирования чтения из ОЗУ следующие.

Из рисунка видно, что из-за асинхронности или джиттера сигнала clken в тактовом входе ОЗУ появились глитчи. Данные по адресу 0x3 пропущены (связано с временными характеристиками сигнала разрешения), а данные по адресу 0xC прочитаны дважды. Очевидно, что такая логика стробирования тактового сигнала очень опасна.

Чтобы решить такие проблемы, нужна структура на защёлке для устранения глитчей.

2. Использование защёлки

В главе учебного руководства по Verilog"6.5 Verilog: избегание защёлок"упоминается, что в цифровом проектировании следует избегать создания защёлок, но стробирование тактового сигнала является исключением. Поэтому при выполнении временного анализа не нужно беспокоиться о защёлках, создаваемых частью стробирования тактового сигнала.

Схема использования защёлки для устранения глитчей стробирования тактового сигнала показана ниже.

Сигнал разрешения тактирования защёлкивается по заднему фронту тактового сигнала и удерживается неизменным в течение одного такта. Затем защёлкнутый сигнал логически умножается (AND) на тактовый сигнал, что позволяет устранить глитчи в стробированном тактовом сигнале.

Перепишите часть логики стробирования тактового сигнала в примере моделирования, которая напрямую использует операцию AND, чтобы использовать логику на защёлках, со следующими изменениями:

Пример

   //(2) использование защёлки
   reg                  en_latch ;
   always @(*) begin
      if (!clk) begin
         en_latch       = clken ;
      end
   end
   wire clk_gate = clk & en_latch ;

Результаты моделирования следующие.

Хотя данные по адресу 0x3 по-прежнему пропускаются (это связано с временными параметрами сигнала разрешения), тактовый сигнал RAM теперь является обычным тактовым сигналом, и глитчи не появляются (сигнал CLK выделен жёлтым).

3. Использование библиотеки стандартных ячеек

Хотя использование защёлки позволяет решить проблему возникновения глитчей при тактовом стробировании, также требуется строгое соблюдение временных ограничений.

При проектировании на FPGA или ИС библиотека синтеза часто содержит встроенные ячейки стробирующей логики. Такие ячейки стробирующей логики прошли многократные итерации и верификацию, что делает их более удобными и безопасными в использовании.

Поэтому в общем случае в проектах тактового стробирования непосредственно создают экземпляры специализированных встроенных ячеек стробирующей логики. Способ создания экземпляров аналогичен способу для базовых ячеек, таких как элементы AND и буферы; просто создавайте их экземпляры напрямую.

Использование

Правильное использование логики тактового стробирования для управления тактовым сигналом схемы также может эффективно снижать энергопотребление.

1. Ручное стробирование

Добавьте сигнал разрешения тактирования, чтобы вручную управлять наличием рабочего тактового сигнала модуля.

Когда модуль работает, сигнал разрешения устанавливается в активное состояние и тактовый сигнал включается; когда модуль простаивает, сигнал разрешения снимается и тактовый сигнал отключается, что экономит энергию.

Проект моделирования из предыдущего раздела можно рассматривать как пример ручного стробирования. Во время чтения/записи RAM сигнал разрешения имеет высокий уровень, тактовый сигнал RAM включается, и RAM начинает работать; когда сигнал разрешения имеет низкий уровень, RAM не работает, и в это время входной тактовый сигнал отсутствует.

2. Автоматическое стробирование

Во время работы модуль может автоматически определять собственное рабочее состояние и выдавать сигнал занятости. Внешне этот индикаторный сигнал можно использовать для применения тактового стробирования к части внутренней логики модуля, тем самым уменьшая переключение тактового сигнала и обеспечивая автоматическое управление стробированием.

В отличие от ручного стробирования, эти модули имеют короткие состояния простоя во время работы. Автоматическое стробирование заключается в отключении неиспользуемых тактовых сигналов в течение этих коротких состояний простоя, а не в прямом отключении тактового сигнала всего модуля, как при ручном стробировании; иначе модуль больше не смог бы нормально работать.

Например, UART имеет состояние простоя после завершения одной передачи данных. В этот момент тактовые сигналы таких модулей, как логика FIFO и логика генерации скорости передачи, могут автоматически отключаться.

Например, в проекте, содержащем CPU, можно добавить логику для обнаружения состояния простоя шины и автоматического управления переключением тактового сигнала шины для снижения энергопотребления.

Из-за ограничений по объёму примеры моделирования здесь не приводятся.

3. Автоматическая вставка стробирования

Когда после завершения проектирования RTL выполняется логический синтез, компилятор также автоматически оптимизирует логику кода, что включает стробирование тактовых входов некоторых триггеров. Например, RTL-описание синхронного D-триггера с входом разрешения выглядит следующим образом:

Пример

   //(2) Триггер с входом разрешения
   always @(posedge CLK) begin
      if (EN) begin
         Q       = D ;
      end
   end

Осциллограмма моделирования RTL до синтеза показана ниже:

Осциллограмма моделирования после синтеза часто выглядит так, как показано ниже:

Из сравнения видно, что после синтеза сигнал EN больше не существует, а тактовый сигнал (вывод CP) не присутствует непрерывно после стробирования тактового сигнала. Это не только обеспечивает логическую корректность, но и уменьшает переключения тактового сигнала и снижает энергопотребление.

Загрузка исходного кода для этой главы

Скачать