Théoriquement, les signaux du domaine d'horloge rapide échantillonneront toujours les signaux transmis depuis le domaine d'horloge lent. Si les horloges sont asynchrones, des erreurs d'échantillonnage peuvent se produire, une synchronisation est donc nécessaire. Ce type de synchronisation est relativement simple et utilise généralement la méthode de prélèvement par délai ou la méthode d'échantillonnage retardé.

Méthode de prélèvement par délai

La méthode de synchronisation la plus courante est la méthode de mise en mémoire tampon par deux étages de bascules, communément appelée méthode de prélèvement par délai. Avant qu'un signal asynchrone n'entre dans un autre domaine d'horloge, le signal est mis en mémoire tampon deux fois consécutivement par deux étages de bascules, ce qui réduit efficacement les problèmes de métastabilité causés par les violations de temporisation. Le schéma du circuit est présenté ci-dessous.

Dans les conceptions générales, l'utilisation de deux étages de bascules pour la mise en mémoire tampon suffit à satisfaire les exigences de temporisation de conception. Un grand nombre d'expériences montrent qu'une mise en mémoire tampon à trois étages de bascules peut résoudre plus de 99% de ces problèmes de temporisation asynchrone.

La description Verilog du prélèvement par délai à deux étages de bascules et de la détection de front montant est la suivante :

Exemple

module delay_clap(
    input       clk1,  // Horloge lente asynchrone
    input       sig1,  // Signal asynchrone

    input       rstn,  // Signal de réinitialisation
    input       clk2,  // Horloge du domaine d'horloge rapide de destination
    output      sig2); // Signal synchronisé dans le domaine d'horloge rapide

   reg [2:0]    sig2_r ;   // Tampon à 3 étages ; les deux premiers étages servent à la synchronisation, les deux derniers à la détection de front
   always @(posedge clk2 or negedge rstn) begin
     if (!rstn) sig2_r  <= 3'b0 ;
     else       sig2_r  <= {sig2_r[1:0], sig1} ;  // Tampon
   end
   assign sig2 = sig2_r[1] && !sig2_r[2] ; // Détection de front montant

Méthode d'échantillonnage différé

Cette méthode vise principalement la transmission de données multi-bits.

Par exemple, lorsque le rapport de fréquence de deux horloges asynchrones est de 5, vous pouvez d'abord utiliser la méthode de prélèvement par retard pour mettre en tampon le signal de validation des données à travers deux étages de registres, puis échantillonner le signal de données du domaine d'horloge lent dans le domaine d'horloge rapide.

L'idée de base de cette méthode est de garantir que le signal est échantillonné en toute sécurité au bon moment, sans avoir besoin de synchroniser des signaux de données multi-bits, ce qui permet d'économiser certaines ressources matérielles.

La description Verilog de l'échantillonnage différé utilisant la méthode de prélèvement par retard est la suivante.

Exemple

// L'horloge de travail du module de synchronisation est de 100MHz
// Les données asynchrones proviennent d'un module dont l'horloge de travail est de 20MHz
module delay_sample(
    input               rstn,
    input               clk1,
    input [31:0]        din,
    input               din_en,

    input               clk2,
    output [31:0]       dout,
    output              dout_en);

   //synchronisation de din_en
   reg [2:0]    din_en_r ;
   always @(posedge clk2 or negedge rstn) begin
     if (!rstn) din_en_r  <= 3'b0 ;
     else       din_en_r  <= {din_en_r[1:0], din_en} ;
   end
   wire din_en_pos = din_en_r[1] && !din_en_r[2] ;

   //synchronisation des données
   reg [31:0]           dout_r ;
   reg                  dout_en_r ;
   always @(posedge clk2 or negedge rstn) begin
      if (!rstn)
        dout_r         <= 'b0 ;
      else if (din_en_pos)
        dout_r         <= din ;
   end
   //délai de dout_en
   always @(posedge clk2 or negedge rstn) begin
      if (!rstn)        dout_en_r      <= 1'b0 ;
      else              dout_en_r      <= din_en_pos ;
   end
   assign       dout    = dout_r ;
   assign       dout_en = dout_en_r ;

endmodule

Le diagramme des résultats temporels de cette méthode est présenté ci-dessous.

De toute évidence, dans le domaine d'horloge clk2, l'échantillonnage et la mise en mémoire tampon des données à l'instant t2 sont bien plus sûrs qu'à l'instant t1.

Cependant, si le domaine d'horloge lent n'a pas de signal de validation de données din_en, ou si le signal de validation de données est toujours actif, la méthode consistant à détecter le front montant du signal de validation de données dans le domaine d'horloge rapide échouera. Comme le signal de validation de données est toujours actif, à l'exception de la première donnée, le domaine d'horloge rapide ne pourra pas détecter les instants de transmission des données suivantes.

La solution consiste à détecter le front du signal d'horloge lent dans le domaine d'horloge rapide.

Si la différence de fréquence entre les deux horloges est faible, il peut être nécessaire de retarder la mise en mémoire tampon des données pour garantir que les données échantillonnées correspondent au battement d'horloge actuel ; si la différence de fréquence est grande, l'instant d'échantillonnage des données peut être obtenu par comptage, sans mise en mémoire tampon des données.

La description Verilog de la détection du front de l'horloge lente à l'aide de la méthode d'échantillonnage retardé par comptage est la suivante.

Exemple

// L'horloge de travail du module de synchronisation est de 100MHz
// Les données asynchrones proviennent d'un module dont l'horloge de fonctionnement est de 999KHz
module delay_cnt_sample(
    input               rstn,
    input               clk1,
    input [31:0]        din,
    input               din_en,

    input               clk2,
    output [31:0]       dout,
    output              dout_en);

   // Tampon à 4 étages : 3 étages pour la synchronisation des prélèvements, 1 étage pour la détection de front
   reg [3:0]    edge_r ;
   always @(posedge clk2 or negedge rstn) begin
     if (!rstn) edge_r  <= 3'b0 ;
     else       edge_r  <= {edge_r[3:0], clk1} ;
   end
   wire edge_pos = edge_r[2] && !edge_r[3] ;

   // Compteur de retard : commence à compter lorsque le front montant de l'horloge lente est détecté
   reg [5:0] cnt ;
   always @(posedge clk2 or negedge rstn) begin
      if (!rstn)                cnt <= 6'h3f ;
      else if (edge_pos && din_en)
                                cnt <= 6'h0 ;
      else if (cnt != 6'h3f)    cnt <= cnt + 1'b1 ;
   end

   // Synchronisation des données
   reg [31:0]           dout_r ;
   reg                  dout_en_r ;
   always @(posedge clk2 or negedge rstn) begin
      if (!rstn)
        dout_r         <= 'b0 ;
      else if (din_en && cnt == 47) // Échantillonner approximativement au milieu de la période de l'horloge lente
        dout_r         <= din ;
   end
   // Le signal de validation des données est émis avec un retard d'un cycle par rapport à l'instant d'échantillonnage des données
   always @(posedge clk2 or negedge rstn) begin
      if (!rstn)        dout_en_r      <= 1'b0 ;
      else if (din_en && cnt==48)
                        dout_en_r      <= 1'b1 ;
      else              dout_en_r      <= 1'b0 ;
   end
   assign       dout    = dout_r ;
   assign       dout_en = dout_en_r ;

endmodule

Le diagramme des résultats d'échantillonnage de synchronisation des données pour une différence de fréquence importante est présenté ci-dessous.

Comme on peut le voir sur la figure, le moment d'échantillonnage de l'horloge rapide se situe autour du centre de la période de l'horloge lente, ce qui est très sûr.

Téléchargement du code source pour ce chapitre

Téléchargement