理論上、高速クロックドメインの信号は低速クロックドメインから転送されてくる信号を常にサンプリングできますが、非同期が存在する場合、サンプリングデータが誤る可能性があるため、同期処理が必要です。この種の同期処理は比較的単純で、通常は遅延フリップフロップ法または遅延サンプリング法を使用します。
遅延フリップフロップ法
最も一般的な同期方法は2段フリップフロップバッファ法で、通称「遅延フリップフロップ法」と呼ばれます。非同期信号があるクロックドメインから別のクロックドメインに入る前に、その信号を2段のフリップフロップで連続して2回バッファリングすることで、タイミング要件を満たせないために生じるメタステーブル状態の問題を効果的に低減できます。回路概略図は以下のとおりです。

一般的な設計では、2段のフリップフロップによるバッファリングで設計タイミング要件を満たすことができます。多くの実験により、3段のフリップフロップバッファリングで、この種の非同期タイミング問題の99%以上を解決できることが示されています。
2段フリップフロップで遅延させ、信号の立ち上がりエッジを検出するVerilog記述は以下のとおりです。
例
input clk1, //非同期低速クロック
input sig1, //非同期信号
input rstn, //リセット信号
input clk2, //目的の高速クロックドメインのクロック
output sig2); //高速クロックドメイン同期後の信号
reg [2:0] sig2_r ; //3段バッファ、前の2段は同期用、後の2段はエッジ検出用
always @(posedge clk2 or negedge rstn) begin
if (!rstn) sig2_r <= 3'b0 ;
else sig2_r <= {sig2_r[1:0], sig1} ; //バッファ
end
assign sig2 = sig2_r[1] && !sig2_r[2] ; //立ち上がりエッジ検出
遅延サンプリング法
この方法は主に複数ビット幅のデータ転送を対象としています。
例えば、2つの非同期クロックの周波数比が5の場合、まず遅延フリップフロップ法を使用してデータイネーブル信号を2段フリップフロップでバッファリングし、その後、高速クロックドメインで低速クロックドメインのデータ信号をサンプリングすることができます。
この方法の基本思想は、信号が安全にサンプリングされるタイミングを保証し、複数ビット幅のデータ信号を同期させる必要がないため、一部のハードウェアリソースを節約できるというものです。
フリップフロップ遅延法を利用して遅延サンプリングを行うVerilog記述は以下のとおりです。
例
//非同期データは動作クロックが20MHzのモジュールからのもの
module delay_sample(
input rstn,
input clk1,
input [31:0] din,
input din_en,
input clk2,
output [31:0] dout,
output dout_en);
//sync din_en
reg [2:0] din_en_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn) din_en_r <= 3'b0 ;
else din_en_r <= {din_en_r[1:0], din_en} ;
end
wire din_en_pos = din_en_r[1] && !din_en_r[2] ;
//sync data
reg [31:0] dout_r ;
reg dout_en_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn)
dout_r <= 'b0 ;
else if (din_en_pos)
dout_r <= din ;
end
//dout_en delay
always @(posedge clk2 or negedge rstn) begin
if (!rstn) dout_en_r <= 1'b0 ;
else dout_en_r <= din_en_pos ;
end
assign dout = dout_r ;
assign dout_en = dout_en_r ;
endmodule
この方法のタイミング結果図は以下のとおりです。
明らかに、clk2クロックドメインでは、t2の時点でデータをサンプリングしてバッファリングする方が、t1の時点よりもはるかに安全です。

しかし、低速クロックドメインにデータイネーブル信号 din_en がない場合、またはデータイネーブル信号が常に有効な場合、高速クロックドメインでデータイネーブル信号の立ち上がりエッジを検出する方法は無効になります。データイネーブル信号が常に有効であるため、最初のデータを除いて、高速クロックドメインは後続データの転送タイミングを検出できません。
解決方法は、高速クロックドメインで低速クロック信号のエッジを検出することです。
2つのクロックの周波数差が小さい場合、サンプリングするデータが現在のクロックサイクルのデータであることを保証するために、データを遅延バッファリングする必要があるかもしれません。2つのクロックの周波数差が大きい場合、データのサンプリングタイミングはカウント方法によって取得できるため、データをバッファリングする必要はありません。
カウントによる遅延サンプリング方法を利用して低速クロックのエッジを検出するVerilog記述は以下のとおりです。
例
//非同期データは動作クロックが999KHzのモジュールからのもの
module delay_cnt_sample(
input rstn,
input clk1,
input [31:0] din,
input din_en,
input clk2,
output [31:0] dout,
output dout_en);
//4段バッファ:3段はフリップフロップ同期用、1段はエッジ検出用
reg [3:0] edge_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn) edge_r <= 3'b0 ;
else edge_r <= {edge_r[3:0], clk1} ;
end
wire edge_pos = edge_r[2] && !edge_r[3] ;
//遅延カウンタ。低速クロックの立ち上がりエッジを検出するとカウントを開始
reg [5:0] cnt ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn) cnt <= 6'h3f ;
else if (edge_pos && din_en)
cnt <= 6'h0 ;
else if (cnt != 6'h3f) cnt <= cnt + 1'b1 ;
end
//データ同期
reg [31:0] dout_r ;
reg dout_en_r ;
always @(posedge clk2 or negedge rstn) begin
if (!rstn)
dout_r <= 'b0 ;
else if (din_en && cnt == 47) //低速クロック周期のほぼ中間時点でサンプリング
dout_r <= din ;
end
//データイネーブル信号はデータサンプリング時点から1周期遅れて出力
always @(posedge clk2 or negedge rstn) begin
if (!rstn) dout_en_r <= 1'b0 ;
else if (din_en && cnt==48)
dout_en_r <= 1'b1 ;
else dout_en_r <= 1'b0 ;
end
assign dout = dout_r ;
assign dout_en = dout_en_r ;
endmodule
周波数差が大きい場合のデータ同期サンプリング結果図は以下のとおりです。
図からわかるように、高速クロックのサンプリング時点は低速クロック周期の中央付近にあり、この時点は非常に安全です。

本章のソースコードダウンロード
Download