Schlüsselwörter: geradzahlige Teilung, ungeradzahlige Teilung, halbzahlige Teilung, fraktionale Teilung

Beim ersten Erlernen von Verilog bestehen viele Module aus Zählern und Teilern, wie z. B. PWM-Pulsweitenmodulation, Frequenzzähler usw. Die Teilungslogik wird oft durch Zähllogik implementiert. Dieser Abschnitt bietet hauptsächlich eine kurze Zusammenfassung der geradzahligen Teilung, ungeradzahligen Teilung, halbzahligen Teilung und fraktionalen Teilung.

Geradzahlige Teilung

Durch Rückkopplung des invertierenden Ausgangs eines Flipflops auf seinen Eingang kann eine einfache Durch-2-Teiler-Schaltung aufgebaut werden.

Durch Kaskadierung auf dieser Basis lassen sich Durch-4- und Durch-8-Teiler-Schaltungen bilden.

Die Schaltungsimplementierung ist in der folgenden Abbildung dargestellt. Bei der Beschreibung in Verilog genügt eine einfache Invertierungslogik.

Wenn der gerade Teilerfaktor zu groß ist, ist es notwendig, den Teilerfaktor N zyklisch zu zählen. Wenn der Zählwert den Mittelwert N/2 des Teilerfaktors erreicht, wird der Takt umgeschaltet, was ein 50%-Tastverhältnis für den geteilten Takt gewährleistet. Da es sich um eine gerade Teilung handelt, kann auch zyklisch bis zum Mittelwert N/2 gezählt werden.

Ein Beispiel für eine Verilog-Beschreibung für die gerade Division ist wie folgt.

Beispiel

module even_divisor
  # (parameter DIV_CLK = 10 )
    (
    input               rstn ,
    input               clk,
    output              clk_div2,
    output              clk_div4,
    output              clk_div10
    );

   //durch 2 teilen
   reg                  clk_div2_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         clk_div2_r     <= 'b0 ;
      end
      else begin
         clk_div2_r     <= ~clk_div2_r ;
      end
   end
   assign       clk_div2 = clk_div2_r ;

   //Teilen durch 4
   reg                  clk_div4_r ;
   always @(posedge clk_div2 or negedge rstn) begin
      if (!rstn) begin
         clk_div4_r     <= 'b0 ;
      end
      else begin
         clk_div4_r     <= ~clk_div4_r ;
      end
   end
   assign clk_div4      = clk_div4_r ;

   //N/2 Zählwert
   reg [3:0]            cnt ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         cnt    <= 'b0 ;
      end
      else if (cnt == (DIV_CLK/2)-1) begin
         cnt    <= 'b0 ;
      end
      else begin
         cnt    <= cnt + 1'b1 ;
      end
   end

   //Ausgangstakt
   reg                  clk_div10_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         clk_div10_r <= 1'b0 ;
      end
      else if (cnt == (DIV_CLK/2)-1 ) begin
         clk_div10_r <= ~clk_div10_r ;
      end
   end
   assign clk_div10 = clk_div10_r ;
endmodule

In der Testbench müssen nur der Stimulus-Takt und andere Signale bereitgestellt werden, daher wird sie hier nicht aufgeführt.

Die Simulationsergebnisse sind wie folgt.

Ungerade Teilung

Wenn die ungerade Teilung keinen 50%-Tastgrad erfordert, kann sie auf dieselbe Weise wie die gerade Teilung durchgeführt werden. Das heißt, der Zähler zählt den Teilerfaktor N zyklisch, und dann wird basierend auf dem Zählwert ein bestimmter Tastgrad ausgewählt, um den geteilten Takt auszugeben.

Wenn sich die High- und Low-Pegel des Ausgangstakts der ungeraden Teilung nur um einen Zyklus unterscheiden, kann die Double-Edge-Eigenschaft des Quelltakts genutzt werden, kombiniert mit einer "UND-Verknüpfung" oder "ODER-Verknüpfung", um den Tastgrad des geteilten Takts auf 50% einzustellen.

ODER-Verknüpfung zum Einstellen des Tastgrads

Das Zeitdiagramm zur Erzeugung eines Takts mit Teiler 3 und einem Tastgrad von 50% unter Verwendung der "ODER-Verknüpfung" ist unten dargestellt.

Verwenden Sie die steigende Flanke des Quelltakts, um einen Takt mit Teiler 3 mit einem High-Pegel von 1 Zyklus und einem Low-Pegel von 2 Zyklen zu erzeugen.

Verwenden Sie die fallende Flanke des Quelltakts, um einen Takt mit Teiler 3 mit einem High-Pegel von 1 Zyklus und einem Low-Pegel von 2 Zyklen zu erzeugen.

Die beiden Takte mit Teiler 3 sollten beim gleichen Zählerwert, aber an unterschiedlichen Flanken erzeugt werden, mit einer Phasendifferenz von einem halben Taktzyklus. Durch eine "ODER-Verknüpfung" der beiden Takte kann dann ein Takt mit Teiler 3 und einem Tastgrad von 50% erhalten werden.

Ähnlich ist es für Teiler 9 erforderlich, Takte mit Teiler 9 mit 4 High-Pegel-Zyklen und 5 Low-Pegel-Zyklen sowohl an der steigenden als auch an der fallenden Flanke zu erzeugen und dann eine "ODER-Verknüpfung" der beiden Takte durchzuführen. Die Verilog-Beschreibung lautet wie folgt.

Beispiel

module odo_div_or
  #(parameter DIV_CLK = 9)
   (
    input               rstn ,
    input               clk,
    output              clk_div9
    );

   //Zähler
   reg [3:0]            cnt ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         cnt    <= 'b0 ;
      end
      else if (cnt == DIV_CLK-1) begin
         cnt    <= 'b0 ;
      end
      else begin
         cnt    <= cnt + 1'b1 ;
      end
   end

   //Division durch 9 bei steigender Flanke erzeugen
   reg                  clkp_div9_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         clkp_div9_r <= 1'b0 ;
      end
      else if (cnt == (DIV_CLK>>1)-1 ) begin //4-8 als Low-Pegel zählen
        clkp_div9_r <= 0 ;
      end
      else if (cnt == DIV_CLK-1) begin //0-3 als High-Pegel zählen
        clkp_div9_r <= 1 ;
      end
   end
 
   //Division durch 9 bei fallender Flanke erzeugen
   reg                  clkn_div9_r ;
   always @(negedge clk or negedge rstn) begin
      if (!rstn) begin
         clkn_div9_r <= 1'b0 ;
      end
      else if (cnt == (DIV_CLK>>1)-1 ) begin
        clkn_div9_r <= 0 ;
      end
      else if (cnt == DIV_CLK-1) begin
        clkn_div9_r <= 1 ;
      end
   end

   //ODER-Operation, normalerweise unter Verwendung einer Basis-Logikzellenbibliothek
   // oder (clk_div9, clkp_div9_r, clkn_div9_r) ;
   assign clk_div9 = clkp_div9_r | clkn_div9_r ;

endmodule

Die Simulationsergebnisse sind wie folgt.

UND-Operation zum Anpassen des Tastverhältnisses

Das Timing-Diagramm zur Erzeugung eines Divide-by-3-Takts mit einem Tastverhältnis von 50 % unter Verwendung der "UND-Operation" ist unten dargestellt.

Verwenden Sie die steigende Flanke des Quelltakts, um einen Divide-by-3-Takt mit einem High-Pegel von 2 Zyklen und einem Low-Pegel von 1 Zyklus zu erzeugen.

Verwenden Sie die fallende Flanke des Quelltakts, um einen Divide-by-3-Takt mit einem High-Pegel von 2 Zyklen und einem Low-Pegel von 1 Zyklus zu erzeugen.

Die beiden Divide-by-3-Takte sollten beim gleichen Zählerwert, aber an unterschiedlichen Flanken erzeugt werden, mit einer Phasendifferenz von einem halben Taktzyklus. Durch Ausführen einer "UND-Operation" an den beiden Takten kann dann ein Divide-by-3-Takt mit einem Tastverhältnis von 50 % erhalten werden.

Ähnlich ist es für Divide-by-9 erforderlich, sowohl an der steigenden als auch an der fallenden Flanke Divide-by-9-Takte mit 5 High-Pegel-Zyklen und 4 Low-Pegel-Zyklen zu erzeugen und dann eine "UND-Operation" an den beiden Takten durchzuführen. Die Verilog-Beschreibung lautet wie folgt.

Beispiel

module odo_div_and
   #( parameter DIV_CLK = 9 )
   (
    input               rstn ,
    input               clk,
    output              clk_div9
    );

   //Zähler
   reg [3:0]            cnt ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         cnt    <= 'b0 ;
      end
      else if (cnt == DIV_CLK-1) begin
         cnt    <= 'b0 ;
      end
      else begin
         cnt    <= cnt + 1'b1 ;
      end
   end

   //Division durch 9 bei steigender Flanke erzeugen
   reg                  clkp_div9_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         clkp_div9_r <= 1'b0 ;
      end
      else if (cnt == (DIV_CLK>>1) ) begin //5-8 als Low-Pegel zählen
        clkp_div9_r <= 0 ;
      end
      else if (cnt == DIV_CLK-1) begin //0-4 als High-Pegel zählen
        clkp_div9_r <= 1 ;
      end
   end

   //Division durch 9 bei fallender Flanke erzeugen
   reg                  clkn_div9_r ;
   always @(negedge clk or negedge rstn) begin
      if (!rstn) begin
         clkn_div9_r <= 1'b0 ;
      end
      else if (cnt == (DIV_CLK>>1) ) begin
        clkn_div9_r <= 0 ;
      end
      else if (cnt == DIV_CLK-1) begin
        clkn_div9_r <= 1 ;
      end
   end

   //UND-Operation, üblicherweise unter Verwendung einer Basis-Logikzellenbibliothek
   //and (clk_div9, clkp_div9_r, clkn_div9_r) ;
   assign clk_div9 = clkp_div9_r & clkn_div9_r ;

endmodule

Die Simulationsergebnisse sind wie folgt.

Halbzahlige Division

Durch die Verwendung der Doppelflankenlogik des Takts kann eine halbzahlige Division durchgeführt werden. Egal wie sie angepasst wird, kann das Tastverhältnis der halbzahligen Division jedoch nicht 50% betragen. Es gibt viele Methoden für die halbzahlige Division; hier wird nur eine Methode vorgestellt, die der Tastverhältnisanpassung für die ungerade Division ähnelt.

  • (1) Wenn beispielsweise eine Division durch 3.5 durchgeführt wird, zählt der Zähler zyklisch bis 7 und erzeugt zwei geteilte Takte, die jeweils aus 4 bzw. 3 Quelltaktzyklen bestehen. Aus der Sicht, dass aus 7 Quelltakten 2 geteilte Takte erzeugt werden, führt der Vorgang eine Division durch 3.5 aus, aber jeder geteilte Takt ist kein striktes Ergebnis einer Division durch 3.5.
  • (2) Als Nächstes werden die geteilten Takte mit ungleichmäßigen Perioden angepasst. In einem Zählzyklus werden an der fallenden Flanke des Quelltakts zwei geteilte Takte erzeugt, die jeweils aus 4 bzw. 3 Quelltaktzyklen bestehen. Im Vergleich zu den beiden beim ersten Mal erzeugten Takten mit ungleichmäßiger Periode ist die Phase der beiden diesmal erzeugten Takte jeweils um eine halbe Quelltaktperiode verzögert bzw. um eine halbe Quelltaktperiode vorverlegt.
  • (3) Durch Ausführen einer "ODER-Verknüpfung" mit den beiden erzeugten Takten kann ein Takt mit Division durch 3.5 und gleichmäßiger Periode erhalten werden. Das Wellenformdiagramm des geteilten Takts ist unten dargestellt.

Die Verilog-Beschreibung des Takts mit Division durch 3.5 lautet wie folgt.

Beispiel

module half_divisor(
    input               rstn ,
    input               clk,
    output              clk_div3p5
    );

   //Zähler
   parameter            MUL2_DIV_CLK = 7 ;
   reg [3:0]            cnt ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         cnt    <= 'b0 ;
      end
      else if (cnt == MUL2_DIV_CLK-1) begin //bis zum 2-fachen des Teilungsverhältnisses zählen
         cnt    <= 'b0 ;
      end
      else begin
         cnt    <= cnt + 1'b1 ;
      end
   end

   reg                  clk_ave_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         clk_ave_r <= 1'b0 ;
      end
      //erster Zyklus: 4 Quelltakt-Zyklen
      else if (cnt == 0) begin
         clk_ave_r <= 1 ;
      end
      //2. Zyklus: 3 Quelltakt-Zyklen
      else if (cnt == (MUL2_DIV_CLK/2)+1) begin
         clk_ave_r <= 1 ;
      end
      else begin
         clk_ave_r <= 0 ;
      end
   end

   //anpassen
   reg                  clk_adjust_r ;
   always @(negedge clk or negedge rstn) begin
      if (!rstn) begin
         clk_adjust_r <= 1'b0 ;
      end
      //Dieser Takt dient nur zur Anpassung eines konsistenten Tastverhältnisses
      else if (cnt == 1) begin
         clk_adjust_r <= 1 ;
      end
      //Dieser Takt dient nur zur Anpassung eines konsistenten, präzisen Teilungsverhältnisses
      else if (cnt == (MUL2_DIV_CLK/2)+1 ) begin
         clk_adjust_r <= 1 ;
      end
      else begin
         clk_adjust_r <= 0 ;
      end
   end

   assign clk_div3p5 = clk_adjust_r | clk_ave_r ;

endmodule

Die Simulationsergebnisse sind wie folgt.

Fraktionale Division

Grundprinzip

Unregelmäßige fraktionale Division kann nicht jeden geteilten Taktzyklus zu einem exakten fraktionalen Vielfachen des Quelltaktzyklus machen, noch kann sie das Tastverhältnis des geteilten Takts auf 50% bringen, weil Verilog keine fraktionale Zählung auf dem Takt durchführen kann. Ähnlich dem im ersten Teilungsschritt der Halbzahldivision eingeführten Konzept der "Durchschnittsfrequenz" wird auch die fraktionale Division auf Basis variabler Division und mehrfacher Mittelungsmethoden implementiert.

Zum Beispiel reicht es für die Division durch 7.6 aus, sicherzustellen, dass die Zeit von 76 Quelltaktzyklen gleich der Zeit von 10 geteilten Taktzyklen ist. In diesem Fall müssen innerhalb von 76 Quelltaktzyklen 6 Division-durch-8-Operationen und 4 Division-durch-7-Operationen ausgeführt werden. Ein weiteres Beispiel: Für die Division durch 5.76 müssen innerhalb von 576 Quelltaktzyklen 76 Division-durch-6-Operationen und 24 Division-durch-5-Operationen ausgeführt werden.

Der Berechnungsprozess dieser Divisionsparameter wird unten erläutert.

Wenn eine Division durch 7 ausgeführt wird, kann dies so verstanden werden, dass 10 Division-durch-7-Operationen innerhalb von 70 Quelltaktzyklen ausgeführt werden. Wenn weiterhin 10 Divisionen innerhalb von 76 Quelltaktzyklen ausgeführt werden, entspricht dies dem Verteilen der zusätzlichen 6 Quelltaktzyklen auf die 70 Quelltaktzyklen, wodurch die Division-durch-7.6-Operation abgeschlossen wird. Im Divisionsprozess müssen 6 geteilte Takte durch Division durch 8 erhalten werden, während die verbleibenden 4 geteilten Takte den ursprünglichen Division-durch-7-Zustand beibehalten.

An vielen Stellen wird ein System aus zwei linearen Gleichungen zur Berechnung dieser Divisionsparameter angegeben, wie unten gezeigt. Das Prinzip ist dasselbe wie in der obigen Analyse, und es wird empfohlen, den oben beschriebenen Berechnungsprozess zu beherrschen.

7N + 8M = 76
N  + M   = 10 

Hier ist 7 der ganzzahlige Divisionsfaktor, N ist die Anzahl, wie oft die ganzzahlige Division ausgeführt wird; 8 ist der Divisionsfaktor, der durch Addition von eins zum ganzzahligen Divisionsfaktor erhalten wird, und M ist die Anzahl, wie oft diese Division ausgeführt wird.

Mittelungsprinzip

Am Beispiel der Division durch 7.6 gibt es für die Ausführungsreihenfolge von Division durch 7 und Division durch 8 im Allgemeinen die folgenden 4 Fälle:

  • (1) Zuerst 4-mal Division durch 7 ausführen, dann 6-mal Division durch 8 ausführen;
  • (2) Zuerst 6-mal Division durch 8 ausführen, dann 4-mal Division durch 7 ausführen;
  • (3) Die 4 Division-durch-7-Operationen gleichmäßig in die 6 Division-durch-8-Operationen einfügen;
  • (4) Die 6 Division-durch-8-Operationen gleichmäßig in die 4 Division-durch-7-Operationen einfügen.

Die ersten beiden Verfahren führen zu ungleichmäßigen Taktfrequenzen und großem Phasenjitter, daher werden die beiden letztgenannten Durchschnittseinfügeverfahren im Allgemeinen für die fraktionale Teilung verwendet.

Die Durchschnittseinfügung kann durch Akkumulieren der Differenz der Teilungszahlen implementiert werden. Der Implementierungsprozess der Teilung durch 7.6 ist wie folgt:

  • (1) Die erste Differenz der Teilungszahl ist 76-10*7 = 6 < 10, daher ist die erste Division eine Teilung durch 7.
  • (2) Das zweite akkumulierte Differenzergebnis ist 6+6=12 > 10, daher verwendet die zweite Division die Teilung durch 8, und die Differenz wird auf 12-10=2 korrigiert.
  • (3) Das dritte akkumulierte Differenzergebnis ist 2+6=8 < 10, daher verwendet die dritte Division die Teilung durch 7.
  • (4) Das vierte akkumulierte Differenzergebnis ist 8+6=14 > 10, daher verwendet die vierte Division die Teilung durch 8, und die Differenz wird auf 14-10=4 korrigiert.

Vervollständigen Sie analog dazu den Prozess, sechs Teilungen durch 8 gleichmäßig in vier Teilungen durch 7 einzufügen.

Die folgende Tabelle zeigt den Frequenzteilungsprozess der Durchschnittseinfügemethode.

TeilungszahlDifferenzakkumulationDifferenzänderungTeilungszyklus
1667
26+6=1228
32+6=887
48+6=1448
54+6=1008
6667
76+6=1228
82+6=887
98+6=1448
104+6=1008

Design-Simulation

Die Verilog-Beschreibung basierend auf der oben genannten Implementierungsmethode zur fraktionalen Frequenzteilung lautet wie folgt.

Beispiel

module frac_divisor
  #(
   parameter            SOURCE_NUM = 76 , //Zyklen im Quelltakt
   parameter            DEST_NUM   = 10  //Zyklen im Zieltakt
   )
   (
    input               rstn ,
    input               clk,
    output              clk_frac
    );
 
   //Parameter für Division durch 7, Parameter für Division durch 8, Zähldifferenz
   parameter    SOURCE_DIV = SOURCE_NUM/DEST_NUM ;
   parameter    DEST_DIV   = SOURCE_DIV + 1;
   parameter    DIFF_ACC   = SOURCE_NUM - SOURCE_DIV*DEST_NUM ;


   reg [3:0]            cnt_end_r ;  //variabler Divisionszyklus
   reg [3:0]            main_cnt ;   //Hauptzähler
   reg                  clk_frac_r ; //Taktausgang mit einer Dauer von 1 Zyklus auf High-Pegel
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         main_cnt    <= 'b0 ;
         clk_frac_r  <= 1'b0 ;
      end
      else if (main_cnt == cnt_end_r) begin
         main_cnt    <= 'b0 ;
         clk_frac_r  <= 1'b1 ;
      end
      else begin
         main_cnt    <= main_cnt + 1'b1 ;
         clk_frac_r  <= 1'b0 ;
      end
   end
   //Ausgangstakt
   assign       clk_frac        = clk_frac_r ;
   //Freigabesteuerung des Differenzakkumulators
   wire         diff_cnt_en     = main_cnt == cnt_end_r ;

   //Differenzakkumulator-Logik
   reg [4:0]            diff_cnt_r ;
   wire [4:0]           diff_cnt = diff_cnt_r >= DEST_NUM ?
                                   diff_cnt_r -10 + DIFF_ACC :
                                   diff_cnt_r + DIFF_ACC ;                                
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         diff_cnt_r <= 0 ;
      end
      else if (diff_cnt_en) begin
         diff_cnt_r <= diff_cnt ;
      end
   end

   //Steuerlogik für die Divisionszyklusvariable
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         cnt_end_r      <= SOURCE_DIV-1 ;
      end
      //Wenn der Differenzakkumulator überläuft, den Divisionszyklus ändern
      else if (diff_cnt >= 10) begin
         cnt_end_r      <= DEST_DIV-1 ;
      end
      else begin
         cnt_end_r      <= SOURCE_DIV-1 ;
      end
   end

endmodule

Die Simulationsergebnisse sind wie folgt.

Zusammenfassung der Frequenzteilung

Geradzahlige Frequenzteilung kann eine Taktteilung mit 50%-Tastverhältnis erreichen, ohne die Doppelflankenlogik des Takts zu verwenden, was sie zur idealsten Voraussetzung für die Frequenzteilung macht.

Für ungeradzahlige Frequenzteilung muss, wenn ein geteilter Takt mit 50%-Tastverhältnis erforderlich ist, die Doppelflankenlogik des Takts verwendet werden. Wenn kein Tastverhältnis erforderlich ist, ist die Implementierungsmethode ähnlich wie bei der geradzahligen Frequenzteilung.

Halbzahlige Frequenzteilung ist eine spezielle Art der fraktionalen Frequenzteilung und kann mit Double-Edge-Logik entworfen werden. Wenn zwei Double-Edge-Taktsignale durch bestimmte Logik zu einem finalen Ausgangstakt kombiniert werden, wird empfohlen, keine Auswahllogik zu verwenden. Dies liegt daran, dass leicht Glitches auftreten und die Schaltung auch zusätzliche Unsicherheit einführt. Zum Beispiel wird die folgende Beschreibung nicht empfohlen.

assign clk_div3p5 = (cnt == 1 || cnt ==2) ? clk_ave_r
                                          : clk_adjust_r ;

Die Grundidee der fraktionalen Frequenzteilung besteht darin, dass die durchschnittliche Frequenz des Ausgangstakts über einen Zeitraum die Teilanforderung erfüllt. Unter Berücksichtigung von Phasenjitter ist es jedoch auch erforderlich, die Teilungslogik zu mitteln, bei der sich der Teilungskoeffizient ändert.

Quellcode-Download für dieses Kapitel

Herunterladen