Simulationssteuerung: $finish, $stop

SystemaufgabeAufrufformatAufgabenbeschreibung
Simulation beenden$finish( type ) ;Beendet die Simulation. Der Parameter type wählt aus, ob beim Beenden der Simulation Informationen ausgegeben werden.
type=0: Direkt beenden, ohne etwas auszugeben
type=1: Simulationszeit und Zeileninformationen der Position der Anweisung ausgeben
type=2: Gibt die Simulationszeit, den Ort, den Speicher und die CPU-Zeitnutzung aus
Simulation pausieren$stop( type ) ;Pausiert die Simulation. Das Verwendungsformat ist dasselbe wie bei $finish.

Sowohl $finish als auch $stop haben die Funktion, die Simulation anzuhalten, aber sie unterscheiden sich dennoch.

$finish beendet die aktuelle Simulation. $stop pausiert die aktuelle Simulation. Nachdem die Simulation pausiert wurde, kann sie über das Verilog-Simulationstool oder die Kommandozeile fortgesetzt werden, aber nachdem die Simulation beendet wurde, kann sie auf keinen Fall fortgesetzt werden. $stop ähnelt der Haltepunkt-Debugging-Funktion in der Sprache C.

Die folgende Simulation veranschaulicht die ausgegebenen Informationen, die dem type-Parameter entsprechen.

Beispiel

   initial begin
      forever begin
         #100;
         if ($time >= 10000)  $finish(0) ;
         //if ($time >= 10000) $finish(1) ;
         //if ($time >= 10000) $finish(2) ;
      end
   end

$finish(0), beim Beenden der Simulation werden keine Informationen ausgegeben.

$finish(1), beim Beenden der Simulation gibt es die Simulationszeit und die Zeileninformation aus, in der sich $finish befindet, wie unten gezeigt.

Die Zeitpräzision des Moduls test ist ns, aber die Zeitpräzision des Simulators ist ps, daher unterscheiden sich die ausgegebenen Zeitinformationen um den Faktor 1000.

$finish(2), wenn die Simulation beendet wird, gibt sie nicht nur die Simulationszeit und Zeileninformationen aus, sondern auch die PC-Nutzungszeit und Speichernutzung, wie unten gezeigt.

Zeitformat: $printtimescale, $timeformat

SystemaufgabeAufrufformat und Beschreibung 
Zeit ausgeben
Einheit und Präzision
$printtimescale( hierarchy ) ; 
 Diese Systemtask gibt die Timescale-Informationen im folgenden Format aus:
Zeitskala von ( hierarchy ) ist 1 ( Einheit ) / 1 ( Präzision )
hierarchy ist die Modulzugriffsebene und kann weggelassen werden. In diesem Fall gibt es die Timescale-Informationen des aktuellen Moduls aus.
 
Zeit setzen
Einheit und Präzision
$timeformat(unit_num, precision_num, suffix_string, min_field_width) 
 unit_num, setzt die Zeiteinheit, standardmäßig `timescale
precision_num, setzt die Anzahl der signifikanten Dezimalstellen in der Zeiteinheit, standardmäßig 0
suffix_string, legt die Zeit-Suffix-Information fest, wie z. B. "ns", Standardwert ist leer
min_field_width, legt die Anzahl der Zeichenstellen fest, die von der Zeitinformation belegt werden, Standardwert ist 20
 

Wenn Anzeigeaufgaben (wie $display, $monitor usw.) und Dateischreibaufgaben (wie $display usw.) das Format "%t" für die Datenausgabe verwenden, kann $timeformat das Ausgabeformat der Zeiteinheiteninformationen angeben.

In $timeformat verwendet unit_num eine vorzeichenbehaftete Zahl, um die Zeiteinheit anzugeben. Die entsprechende Zuordnung ist in der folgenden Tabelle dargestellt:

unit_numZeiteinheitunit_numZeiteinheit
01 s-810 ns
-1100 ms-91 ns
-210 ms-10100 ps
-31 ms-1110 ps
-4100 us-121 ps
-510 us-13100 fs
-61 us-1410 fs
-7100 ns-151 fs

Verwenden Sie den folgenden Code, um eine einfache Simulation der 2 Systemaufgaben der Zeitskala durchzuführen.

Beispiel

   //Zeitskala ändern
   initial begin
      # 10 ;
      //ps-Präzision, 5 signifikante Stellen im Dezimalteil, Einheitensuffix wird als "my-ps" angezeigt, belegt 15 Zeichenpositionen
      $timeformat(-12, 5, " my-ps", 15) ;
   end
   initial begin
      # 5 ;
      $printtimescale() ;
      $display("Zeit vor dem erneuten Setup: %t", $time);
      # 10 ;
      $printtimescale() ;
      $display("Zeit nach dem erneuten Setup: %t", $time);
   end

Das Simulationsprotokoll wird unten angezeigt.

Anhand der Abbildung kann das Anzeigeformat der Zeit vor und nach der Einstellung von $timeformat verglichen werden.

Darüber hinaus bleibt die Zeitskala während dieses Prozesses unverändert; $timeformat ändert nur das Anzeigeformat der Zeit.

Simulationszeit: $time, $stime, $realtime

Aufruf einer SystemaufgabeBeschreibung
$timeGibt einen 64-Bit-Ganzzahl-Zeitwert zurück
$stimeGibt einen 32-Bit-Ganzzahl-Zeitwert zurück
$realtimeGibt einen reellen Zeitwert zurück, der eine Gleitkommazahl sein kann

Der Simulationscode lautet wie folgt:

Beispiel

   initial begin
      #10;
      $display("$time output1: %t", $time);
      $display("$stime output1: %t", $stime);
      $display("$realtime output1: %t", $realtime);
      #3.2;
      $display("$time output2: %t", $time);
      $display("$stime output2: %t", $stime);
      $display("$realtime output2: %t", $realtime);
      #5.6;
      $display("$time output2: %t", $time);
      $display("$stime output2: %t", $stime);
      $display("$realtime output2: %t", $realtime);
   end

Das Simulationsprotokoll wird unten angezeigt.

Da die Simulationszeit kurz ist, gibt es keinen Unterschied zwischen $time und $stime.

Jedoch liest $realtime die Simulationszeit genau gemäß der aktuellen Zeitpräzision, während $time und $stime die aktuelle Zeit gemäß der Zeitpräzision runden.

Übergabe von Kommandozeilenargumenten: $test$plusargs, $value$plusargs

Verilog bietet außerdem die interaktiven Tasks $test$plusargs und $value$plusargs. Während der Simulation können Parameter über Kommandozeilenargumente übergeben werden, was die Simulationsfehlersuche erheblich erleichtert.

System-TaskAufrufformatAufgabenbeschreibung
Übergabe von String-Argumenten$test$plusargs( str ) ;Wenn die über die Kommandozeile übergebenen String-Daten während der Simulation mit str übereinstimmen, ist der Rückgabewert 1, andernfalls 0.
Übergabe numerischer Argumente$value$plusargs( str, var ) ;Wenn die über die Kommandozeile übergebenen String-Daten während der Simulation mit str übereinstimmen, ist der Rückgabewert 1, andernfalls 0.
Der Typ der an das Modul übergebenen Variablen var muss innerhalb von str angegeben werden. Für das Format siehe die Display-Task $display.

Bei Verwendung von $test$plusargs( str ) fügen Sie einfach "+str " zur Simulations-Kommandozeile hinzu.

Bei Verwendung von $value$plusargs( str, var ) muss der Typ des Werts beim Übergeben des Parameters innerhalb von str angegeben werden. Beim Übergeben von Parametern auf der Kommandozeile benötigt der Wert keine Radix-Angabe; behalten Sie den Wert einfach in der entsprechenden Basis bei. Das Format der Kommandozeilenparameter muss dem Format folgen, das von str in $value$plusargs deklariert wurde.

Die folgende Simulation veranschaulicht dies:

Beispiel

   initial begin
      if ($test$plusargs("DISPLAY_CTRL")) begin
          $display("Simulationsinformationen anzeigen!!!");
      end
   end
   reg  [1:0]   display_sel ;
   initial begin
      if ($value$plusargs("INFO_SEL=%b", display_sel)) begin
          $display("Parameterübertragung erfolgreich!!!");
      end
      else begin
         display_sel = 2'b0 ;
      end
   end
   initial begin
      #1 ;
      if (display_sel == 2'b01)
          $display("Sie haben Beispiel ausgewählt!!!");
      else if (display_sel == 2'b10)
          $display("Sie haben Verilog ausgewählt!!!");
      else if (display_sel == 2'b11)
          $display("Sie haben mich ausgewählt!!!");
      else
          $display("Was wollen Sie wirklich???");
   end

Fügen Sie zur Simulationskommandozeile hinzu: +DISPLAY_CTRL +INFO_SEL=01

Das Simulationsprotokoll lautet wie folgt. Daraus ist ersichtlich, dass sowohl der String-Parameter als auch der Binärparameter korrekt übergeben werden.

Quellcode-Download für dieses Kapitel

Herunterladen