Aufgrund verschiedener Einschränkungen durch Anwendungsszenarien müssen Chips während des Betriebs häufig zwischen verschiedenen Taktquellen für unterschiedliche Anwendungen umschalten. Beispielsweise erfordern Low-Power- und High-Performance-Modi jeweils niederfrequente und hochfrequente Takte. Die beiden Taktquellen können aus derselben Quelle stammen und synchron sein, oder sie können unabhängig voneinander sein. Die direkte Verwendung von Auswahllogik zur Taktumschaltung führt wahrscheinlich zu Glitches im geteilten Taktsignal, daher erfordert die Taktumschaltungslogik ebenfalls eine spezielle Behandlung.

Taktumschaltungsproblem

Das Schaltbild der direkten Verwendung von Auswahllogik zur Taktumschaltung ist unten dargestellt.

Wenn das Taktauswahlsignal sel_clk1 asynchron zu beiden Takten ist, ist der Zeitpunkt der Taktumschaltung beliebig. Wenn der Takt von clk1 auf clk2 umschaltet und der Umschaltzeitpunkt dann liegt, wenn der Ausgangspegel von clk1 hoch ist, führt eine sofortige Umschaltung des Takts zu diesem Zeitpunkt zu Glitches am Ausgangstakt. Das Wellenformdiagramm ist wie folgt:

Taktumschaltungsschema

Das Umschalten der Takte, wenn die beiden Pegel entgegengesetzt sind, erzeugt mit Sicherheit Glitches; wenn die Pegel gleich sind, ist selbst dann, wenn kein Glitch erzeugt wird, die Periode oder das Tastverhältnis des ersten Takts nach dem Umschalten nicht ideal. Daher sollte zur Vermeidung von Glitches die Taktumschaltung durchgeführt werden, wenn beide Takte auf Low-Pegel sind.

Eine typische Taktschaltschaltung ist unten dargestellt.

Diese Schaltung verwendet die fallende Flanke des Takts, um das Taktauswahlsignal sel_clk1 zu puffern. Gleichzeitig liefert ein Taktauswahlsignal eine Rückkopplungssteuerung für den anderen Takt, wodurch sichergestellt wird, dass zu jedem Zeitpunkt nur ein Takt aktiv ist. Schließlich kombiniert eine ODER-Operation die beiden Taktpfade, um den Taktschaltvorgang abzuschließen.

Das Wellenformdiagramm für die Verwendung der obigen Schaltung zum Abschluss der Taktumschaltung (clk1->clk2) ist unten dargestellt.

Wie aus der Abbildung ersichtlich ist, wird beim Umschalten von clk1 auf clk2 zuerst clk1 ausgeschaltet, dann clk2 eingeschaltet. Da das Taktauswahlsignal mit der fallenden Flanke des Takts synchronisiert wird, treten während des Umschaltvorgangs keine Glitches auf.

Das Wellenformdiagramm für das Umschalten von clk2 auf clk1 ist unten dargestellt.

In Anbetracht dessen, dass das Auswahlsignal ein asynchrones Signal sein kann, müssen vor dem Puffer-Flipflop des Taktauswahlsignals zwei Flipflop-Stufen zur Synchronisation hinzugefügt werden, um die Ausbreitung von Metastabilität zu verringern. Das Strukturdiagramm ist wie folgt. Diese Taktschaltschaltung ist universeller.

Taktumschaltungs-Design

Eine universelle und sichere Beschreibung der Taktumschaltlogik ist wie folgt.

Beispiel

module clk_switch(
    input               rstn ,
    input               clk1,
    input               clk2,
    input               sel_clk1 , // 1 clk1, 0 clk2
    output              clk_out
    );

   reg [2:0]            sel_clk1_r ;
   reg [1:0]            sel_clk1_neg_r ;
   reg [2:0]            sel_clk2_r ;
   reg [1:0]            sel_clk2_neg_r ;

   //3-Zyklus-Pufferung verwenden, um die AND-Operation zwischen dem anderen Taktsteuersignal und diesem Taktsteuersignal zu synchronisieren
   always @(posedge clk1 or negedge rstn) begin
      if (!rstn) begin
         sel_clk1_r     <= 3'b111 ; //Beachte den Standardwert
      end
      else begin
         //clk1 auswählen, und nicht clk2 auswählen
         sel_clk1_r     <= {sel_clk1_r[1:0], sel_clk1 & (!sel_clk2_neg_r[1])} ;
      end
   end

   //Bei der fallenden Flanke 2-Zyklus-Pufferung für das Taktauswahlsignal verwenden
   always @(negedge clk1 or negedge rstn) begin
      if (!rstn) begin
         sel_clk1_neg_r <= 2'b11 ; //Hinweis: Standardwert
      end
      else begin
         sel_clk1_neg_r <= {sel_clk1_neg_r[0], sel_clk1_r[2]} ;
      end
   end

   //3-Zyklus-Pufferung verwenden, um die AND-Operation zwischen dem anderen Taktsteuersignal und diesem Taktsteuersignal zu synchronisieren
   always @(posedge clk2 or negedge rstn) begin
      if (!rstn) begin
         sel_clk2_r     <= 3'b0 ; //Hinweis: Standardwert
      end
      else begin
         //sel clk und sel clk1
         sel_clk2_r     <= {sel_clk2_r[1:0], !sel_clk1 & (!sel_clk1_neg_r[1])} ;
      end
   end

   //Bei der fallenden Flanke 2-Zyklus-Pufferung für das Taktauswahlsignal verwenden
   always @(negedge clk2 or negedge rstn) begin
      if (!rstn) begin
         sel_clk2_neg_r <= 2'b0 ; //Hinweis: Standardwert
      end
      else begin
         sel_clk2_neg_r <= {sel_clk2_neg_r[0], sel_clk2_r[2]} ;
      end
   end

   //Bei der Durchführung von Taktlogikoperationen wird im Allgemeinen eine spezifische Prozesszellenbibliothek verwendet.
   //Hier werden stattdessen die in Verilog integrierten Logikgatterzellen verwendet.
   wire clk1_gate, clk2_gate ;
   and (clk1_gate, clk1, sel_clk1_neg_r[1]) ;
   and (clk2_gate, clk2, sel_clk2_neg_r[1]) ;
   or  (clk_out, clk1_gate, clk2_gate) ;

endmodule

Die Testbench-Beschreibung lautet wie folgt; hauptsächlich wird das Auswahlsignal für asynchrone Takte erzeugt.

Beispiel

`timescale 1ns/1ps
module test ;
   reg          clk_100mhz, clk_200mhz ;
   reg          rstn ;
   reg          sel ;
   wire         clk_out ;

   always #(2.5)    clk_200mhz  = ~clk_200mhz ;
   always @(posedge clk_200mhz)
                    clk_100mhz  = #1 ~clk_100mhz ;

   initial begin
      clk_100mhz  = 0 ;
      clk_200mhz  = 0 ;
      rstn        = 0 ;
      sel         = 1 ;
      #11 rstn    = 1 ;
      #36.2 sel   = ~sel ;
      #119.7 sel   = ~sel ;
   end

   clk_switch u_clk_switch(
     .rstn      (rstn),
     .clk1      (clk_100mhz),
     .clk2      (clk_200mhz),
     .sel_clk1  (sel),
     .clk_out   (clk_out));

   initial begin
      forever begin
         #100;
         if ($time >= 10000)  $finish ;
      end
   end

endmodule

Die Simulationsergebnisse sind wie folgt. Es ist zu erkennen, dass beim Umschalten zwischen den Takten keine Störspitzen erzeugt werden, jedoch tritt eine Verzögerung auf.

Quellcode-Download für dieses Kapitel

Herunterladen