Schlüsselwörter: Gatterverzögerung, D-Flipflop


Gatterverzögerungstypen

Die in den beiden vorherigen Abschnitten vorgestellten Gatterschaltungen haben keine Verzögerung; tatsächliche Gatterschaltungen weisen alle eine Verzögerung auf.

Verilog ermöglicht es Benutzern, Gatter anzugeben, um die Ausbreitungsverzögerung von Eingängen zu Ausgangssignalen zu definieren.

Es gibt hauptsächlich drei Arten von Gatterverzögerungen.

Anstiegsverzögerung

Wenn sich ein Gattereingang ändert, wird die Übergangszeit, die erforderlich ist, damit der Gatterausgang von 0, x, z auf 1 wechselt, als Anstiegsverzögerung bezeichnet.

Abfallverzögerung

Wenn sich ein Gattereingang ändert, wird die Übergangszeit, die erforderlich ist, damit der Gatterausgang von 1, x, z auf 0 wechselt, als Abfallverzögerung bezeichnet.

Abschaltverzögerung

Die Abschaltverzögerung bezieht sich auf die Übergangszeit, die erforderlich ist, damit der Gatterausgang von 0, 1, x in den hochohmigen Zustand z wechselt.

Die Übergangszeit, die erforderlich ist, damit ein Gatter von 0, 1, z auf x wechselt, ist nicht explizit definiert, aber die benötigte Zeit kann durch die anderen Verzögerungsarten bestimmt werden; sie entspricht dem kleinsten der oben genannten drei Verzögerungswerte.

Gatterverzögerungen können beim Instanziieren eines Gatter-Primitivs definiert werden. Das Definitionsformat ist wie folgt:

gate_type [delay]  [instance_name]  (signal_list) ;

Hier kann die Anzahl der Verzögerungen 0, 1, 2 oder 3 betragen.

Die folgende Tabelle zeigt die Verzögerungswerte für verschiedene Anzahlen von Verzögerungsangaben.

VerzögerungstypKeine Verzögerung1 Verzögerung (d)2 Verzögerungen (d1, d2)3 Verzögerungen (d1, d2, d3)
Anstieg0dd1d1
Abfall0dd2d2
Ausschalten0dmin(d1, d2)d3
to_x0dmin(d1, d2)min(d1, d2, d3)

Wenn kein Verzögerungswert angegeben ist, beträgt die Standardverzögerung 0.

Wenn der Benutzer 1 Verzögerungswert angibt, dann sind alle Arten von Verzögerungswerten gleich diesem Wert.

Wenn der Benutzer 2 Verzögerungswerte angibt, repräsentieren sie jeweils die Anstiegsverzögerung und die Abfallverzögerung, und die Ausschalt- und "to_x"-Verzögerungen sind beide gleich dem kleineren dieser 2 Verzögerungswerte.

Wenn der Benutzer 3 Verzögerungswerte angibt, repräsentieren sie jeweils die Anstiegsverzögerung, Abfallverzögerung und Ausschaltverzögerung, und die "to_x"-Verzögerung ist die kleinste dieser 3 Verzögerungswerte.

Eine Instanziierung eines primitiven Gatters auf Gate-Ebene mit Verzögerungswerten sieht wie folgt aus:

Beispiel

   //Anstiegs-, Abfall- und Ausschaltverzögerung sind alle 1
   and #(1)             (OUT1, IN1, IN2) ;
   //Anstiegsverzögerung = 2.1, Abfallverzögerung = 2, Ausschaltverzögerung = 2
   or  #(2.1, 2)        (OUT2, IN1, IN2) ;
   //Anstiegsverzögerung = 2, Abfallverzögerung = 1, Ausschaltverzögerung = 1.3
   bufif0 #(2, 1, 1.3)  (OUT3, IN1, CTRL) ;

Es sollte beachtet werden, dass Mehreingangsgatter (wie AND-Gatter) und Mehrausgangsgatter (wie NOT-Gatter) höchstens 2 Verzögerungen definieren können, weil der Ausgang nicht z sein wird.

Drei-Zustands-Gatter und unidirektionale Schalter (MOS-Transistoren, CMOS-Transistoren usw.) können 3 Verzögerungen definieren.

Pull-up- und Pull-down-Gatter haben keine Verzögerung, weil sie ein Hardware-Attribut darstellen; der Pull-up-/Pull-down-Zustand ändert sich nicht und es gibt keinen Ausgangswert.

Bidirektionale Schalter (tran) haben beim Übertragen von Signalen keine Verzögerung, und Verzögerungsdefinitionen sind nicht erlaubt.

Bidirektionale Schalter mit Steueranschlüssen (tranif1, tranif0) haben beim Umschalten eine Einschalt- oder Ausschaltverzögerung. Solche bidirektionalen Schalter können mit 0, 1 oder 2 Verzögerungen angegeben werden, zum Beispiel:

Beispiel

   //Einschalt- und Ausschaltverzögerung sind jeweils 1
   tranif0 #(1)         (inout1, inout2, CTRL);
   //Einschaltverzögerung = 1, Ausschaltverzögerung = 1.2
   tranif1 #(1, 1.2)    (inout3, inout4, CTRL);

Minimale/typische/maximale Verzögerungen

Aufgrund von Unterschieden in den Fertigungsprozessen integrierter Schaltkreise schwankt die Verzögerung von Bauelementen in tatsächlichen Schaltungen immer innerhalb eines bestimmten Bereichs. In Verilog können Benutzer nicht nur die 3 Arten von Gatterverzögerungen angeben, sondern auch die minimalen, typischen und maximalen Werte für jede Art angeben. In der Kompilierungs- oder Simulationsphase kann einer dieser Verzögerungswerte ausgewählt werden, wodurch eine realistischere Simulation unterstützt wird.

  • Minimalwert: die minimale Verzögerung, die das Gatter-Primitiv hat.
  • Typischer Wert: die typische Verzögerung, die das Gatter-Primitiv hat.
  • Maximalwert: die maximale Verzögerung, die das Gatter-Primitiv hat.

Das folgende Instanziierungsbeispiel veranschaulicht die Verwendung von minimalen, typischen und maximalen Verzögerungen.

Beispiel

   //alle Verzögerungstypen: min 1, typisch 2, max 3
   and #(1:2:3)             (OUT1, IN1, IN2) ;
   //Anstiegsverzögerung: min 1, typisch 2, max 3
   //Abfallverzögerung: min 3, typisch 4, max 5
   //Ausschaltverzögerung: min min(1,3), typisch min(2,4), max min(3,5)
   or  #(1:2:3, 3:4:5)        (OUT2, IN1, IN2) ;
   //Anstiegsverzögerung: min 1, typisch 2, max 3
   //Abfallverzögerung: min 3, typisch 4, max 5
   //Ausschaltverzögerung: min 2, typisch 3, max 4
   bufif0 #(1:2:3, 3:4:5, 2:3:4)  (OUT3, IN1, CTRL) ;

D-Flipflop

Als Nächstes entwerfen wir ein D-Flipflop aus der Perspektive der Gattermodellierung.

SR-Flipflop

Das Strukturdiagramm und die Wahrheitstabelle des SR-Flipflops sind wie folgt.

  • 1. Wenn S niedrig ist, ist der Ausgang Q von G1 hoch und wird auf den Eingang von G2 zurückgeführt. Wenn R zu diesem Zeitpunkt hoch ist, ist der Ausgang Q' von G2 niedrig.
  • 2. Wenn R niedrig und S hoch ist, verläuft die Analyse ähnlich.
  • 3. Wenn sowohl S als auch R hoch sind, gilt: Wenn Q = 1 (Q' = 0), dann bleibt der Ausgang Q' nach der Rückführung von Q auf den Eingang von G2 0; nach der Rückführung von Q' auf den Eingang von G1 bleibt der Ausgang Q 1, was einen stabilen Zustand darstellt. Wenn Q = 0 (Q' = 1), verläuft die Analyse ähnlich, und Q und Q' bleiben unverändert. Das heißt, wenn sowohl S als auch R hoch sind, hat die Schaltung eine Haltefunktion.
  • 4. Wenn sowohl S als auch R niedrig sind, dann sind die Ausgänge Q und Q' beide hoch, und sie sind nicht mehr komplementär. Daher ist dieser Fall verboten.

SR-Latch

Durch das Hinzufügen von zwei NAND-Gattern vor dem grundlegenden SR-Flipflop entsteht ein SR-Latch mit Enable-Eingang.

Das SR-Latch und seine Wahrheitstabelle sind wie folgt.

  • Wenn EN=0 ist, sind G3 und G4 deaktiviert, und das SR-Latch hält seinen Ausgangszustand unverändert.
  • Wenn EN=1, funktioniert es genau wie das einfache SR-Flipflop.

D-Latch

Die Eingänge des einfachen SR-Flipflops dürfen nicht beide 0 sein, und die Eingänge des SR-Latch mit Enable-Eingang dürfen nicht beide 1 sein; andernfalls entsteht der nicht komplementäre Widerspruch zwischen den Ausgängen Q und Q'.

Um diesen verbotenen Zustand zu beseitigen, wird ein Invertierungsmodul zum SR-Latch mit Enable-Eingang hinzugefügt, wodurch sichergestellt wird, dass die 2 Eingänge immer logisch entgegengesetzt sind, wodurch ein D-Latch entsteht.

Sein Strukturdiagramm und seine Wahrheitstabelle sind wie folgt.

  • 1. Wenn EN=1, ändert sich der Ausgangszustand mit dem Eingangszustand.
  • 2. Wenn EN=0, bleibt der Ausgangszustand unverändert.

Ein D-Latch ist pegelgetriggert.

Wenn das D-Eingangssignal während der aktiven Phase von EN=1 mehrmals umschaltet, schaltet auch der Ausgang Q mehrmals um. Dies verringert die Störfestigkeit der Schaltung und ist für praktische Anforderungen kein sicherer Schaltkreis.

Um die Zuverlässigkeit des Flipflops zu verbessern und die Störfestigkeit der Schaltung zu erhöhen, wurde das D-Flipflop erfunden, das das Signal zu einem bestimmten Zeitpunkt übernimmt.

D-Flipflop

Die Kaskadierung zweier D-Latches mit invertiertem Takt ergibt ein einfaches D-Flipflop, auch als Flipflop bekannt.

Sein Strukturdiagramm und seine Wahrheitstabelle sind wie folgt.

Das D-Latch der ersten Stufe wird auch Master-Latch genannt; es übernimmt das Signal, wenn CP low ist. Das D-Latch der zweiten Stufe wird auch Slave-Latch genannt; sein Takt ist dem des Master-Latch entgegengesetzt, und es übernimmt das Signal, wenn CP high ist.

  • 1. Wenn CP=1, folgt der Ausgang Qm des Master-Latch den Änderungen des D-Eingangssignals, während sich der Slave-Latch im Haltezustand befindet und sein Ausgang Qs unverändert bleibt.
  • 2. Wenn CP von High auf Low wechselt, speichert der Master-Latch den aktuellen D-Zustand, überträgt ihn auf den Ausgang Qm und hält ihn unverändert. Der Ausgang Qs des Slave-Latch folgt den Änderungen von Qm. Zu diesem Zeitpunkt hält der Master-Latch im verriegelten Zustand Qm unverändert, sodass auch der Ausgang Qs des D-Flipflops, nachdem er den neuen Qm-Wert empfangen hat, unverändert bleibt.

Zusammenfassend speichert der Ausgang Qs des D-Flipflops das Signal an D nur bei der fallenden Flanke des Takts CP; zu anderen Zeiten hat das Ausgangssignal eine Haltefunktion.

Die Erweiterung des zweistufigen D-Latch zu einer Gatterebenenstruktur ist in der folgenden Abbildung dargestellt.

Wir führen eine Gatterebenen-Modellierung des D-Flipflops durch und fügen Gatterverzögerungen hinzu. Das Verilog-Modell lautet wie folgt:

Beispiel

module D_TRI(
            input       D, CP,
            output      Q, QR);
   parameter RISE_TIME = 0.11 ;
   parameter FALL_TIME = 0.07 ;
   //Teil1, NOT-Gatter
   wire         CPN, DN ;
   not  #(RISE_TIME, FALL_TIME)         (CPN, CP);
   not  #(RISE_TIME, FALL_TIME)         (DN, D);
   //part2, Master-Trigger
   wire         G3O, G4O ;
   nand #(RISE_TIME, FALL_TIME)         (G3O, D, CP);
   nand #(RISE_TIME, FALL_TIME)         (G4O, DN, CP);
   wire #(RISE_TIME, FALL_TIME)         G1O, G2O ;
   nand #(RISE_TIME, FALL_TIME)         (G1O, G3O, G2O);
   nand #(RISE_TIME, FALL_TIME)         (G2O, G4O, G1O);
   //part3, Slave-Trigger
   wire         G7O, G8O ;
   nand  #(RISE_TIME, FALL_TIME)        (G7O, G1O, CPN);
   nand  #(RISE_TIME, FALL_TIME)        (G8O, G2O, CPN);
   wire         G5O, G6O ;
   nand  #(RISE_TIME, FALL_TIME)        (G5O, G7O, G6O);
   nand  #(RISE_TIME, FALL_TIME)        (G6O, G8O, G5O);
   assign       Q = G5O ;
   assign       QR = G6O ;
endmodule

Die Testbench wird wie folgt geschrieben:

Beispiel

`timescale 1ns/1ps
module test ;
   reg  D, CP = 0 ;
   wire Q, QR ;
   always #5 CP = ~CP ;
   initial begin
      D = 0 ;
      #12 D = 1 ;
      #10 D = 0 ;
      #14 D = 1 ;
      #3  D = 0 ;
      #18 D = 0 ;
   end
   D_TRI u_d_trigger(
        .D      (D),
        .CP     (CP),
        .Q      (Q),
        .QR     (QR));
   initial begin
      forever begin
         #100;
         //$display("---gyc---%d", $time);
         if ($time >= 1000) begin
            $finish ;
         end
      end
   end
endmodule // test

Die Simulationsergebnisse sind wie folgt.

Wie aus der Abbildung ersichtlich ist, erfassen sowohl die Q/QR-Signale das D-Signal an der fallenden Flanke des Takts CP, bleiben innerhalb eines einzelnen Zyklus unverändert, und der Ausgang weist eine Verzögerung auf.

Vergrößern Sie den cap3-Zeitpunkt und verfolgen Sie die Verzögerung, wie in der folgenden Abbildung dargestellt.

  • Es gibt eine Anstiegsverzögerung von CP nach CPN von 110ps;
  • Es gibt eine Abfallverzögerung von CPN nach G8O von 70ps;
  • Es gibt eine Anstiegsverzögerung von G8O nach G6O von 110ps;
  • Es gibt eine Abfallverzögerung von G6O nach Q von 70ps;
  • Die Summe beträgt 360ps, was der konfigurierten Gatterverzögerung entspricht.

Quellcode für dieses Kapitel herunterladen

Herunterladen