NAND-Gatter-Beispiel

In einem UDP für kombinatorische Logik legt die Zustandstabelle verschiedene Eingangskombinationen und entsprechende Ausgangswerte fest. Jede nicht angegebene Kombination gibt x aus.

Ein einfaches UDP für ein NAND-Gatter kann wie folgt ausgedrückt werden:

primitive nand_my(out, a, b);
   output       out ;
   input        a, b ;

   table
    //a         b       :       out ;
      0         0       :       1 ;
      0         1       :       1 ;
      1         0       :       1 ;
      1         1       :       0 ;
   endtable
endprimitive

Wie im vorherigen Abschnitt erläutert, können die Portliste und der Deklarationsabschnitt geändert werden zu:

primitive nand_my(
  output       out,
  input        a, b);
  ......
endprimitive

Zustandstabelleneinträge

Das Syntaxformat für jede Zeile in der Zustandstabelle, die kombinatorische Logik repräsentiert, ist wie folgt:

<input1>  <input2>  ...  <inputN>  :  <output> ;
  • 1. Die Reihenfolge der Eingangssignale in der Zustandstabelle muss mit der Reihenfolge der UDP-Portliste übereinstimmen.
  • 2. Ein- und Ausgang werden durch einen Doppelpunkt:getrennt.
  • 3. Jede Zeile der Zustandstabelle wird mit einem Semikolon;abgeschlossen.
  • 4. Alle Eingangskombinationen, die einen eindeutigen Ausgangswert erzeugen können, müssen in der Zustandstabelle aufgeführt werden, sonst wird ein x-Wert ausgegeben.

Zum Beispiel: Wenn im obigen UDP nand_my a=0, b=x gilt, dann ist der Ausgang out = x, weil diese Kombination in der Tabelle nicht gefunden werden kann. Daher müssen beim Schreiben eines UDP alle Eingangskombinationen vollständig berücksichtigt werden.

Die Zustandstabelle des UDP nand_my kann geändert werden zu:

   table
    //a         b       :       out ;
      0         0       :       1 ;
      0         1       :       1 ;
      1         0       :       1 ;
      1         1       :       0 ;

      0         x       :       1 ;
      x         0       :       1 ;
   endtable

Don't-Care-Terme

In UDP nand_my ist der Ausgang 1, wenn entweder a oder b 0 ist.

Eingangssignale, die das Ausgangsergebnis nicht beeinflussen, sind Don't-Care-Terme, die durch ein Fragezeichen "?" dargestellt werden können. Der "?"-Eintrag in der Zustandstabelle wird automatisch zu 0, 1 oder x erweitert.

Daher kann die Zustandstabelle des UDP nand_my geändert werden zu:

   table
    //a         b       :       out ;
      0         ?       :       1 ;
      ?         0       :       1 ;
      1         1       :       0 ;

      // Die folgende Kombination gibt x aus, daher kann sie auch weggelassen werden. Verilog gibt standardmäßig x aus.
      1         x       :       x ;
      x         1       :       x ;
   endtable

UDP-Instanziierung

Das UDP-Aufrufformat ist genau dasselbe wie bei den eingebauten Primitiven auf Gatterebene.

Verwenden Sie das oben genannte UDP nand_my, um die Simulation des D-Flip-Flops in"1.3 Gatterverzögerung"abzuschließen.

Nach Entfernen der Verzögerungsinformationen sieht das D-Flip-Flop-Modell wie folgt aus.

Beispiele

module D_TRI(
            input       D, CP,
            output      Q, QR);

   //Teil1, NOT-Gatter
   wire         CPN, DN ;
   not          (CPN, CP);
   not          (DN, D);

   //part2, Master-Trigger
   wire         G3O, G4O ;
   nand_my      (G3O, D, CP);
   nand_my      (G4O, DN, CP);
   wire         G1O, G2O ;
   nand_my      (G1O, G3O, G2O);
   nand_my      (G2O, G4O, G1O);

   //part3, Slave-Trigger
   wire         G7O, G8O ;
   nand_my      (G7O, G1O, CPN);
   nand_my      (G8O, G2O, CPN);
   wire         G5O, G6O ;
   nand_my      (G5O, G7O, G6O);
   nand_my      (G6O, G8O, G5O);

   assign       Q = G5O ;
   assign       QR = G6O ;

endmodule

Die Testbench bleibt unverändert, und die Simulationsergebnisse sind wie folgt.

Wie aus der Abbildung ersichtlich ist, erfasst das Flip-Flop das D-Eingangssignal an der fallenden Flanke des Takts CP und leitet es an Q/QR weiter, was innerhalb eines einzelnen Taktzyklus unverändert bleibt.

Das vom UDP implementierte NAND-Gatter funktioniert korrekt.

Quellcode-Download für dieses Kapitel

Herunterladen