Clock-Gating
In der Regel besteht ein Taktbaum aus einer großen Anzahl von Puffern und Invertern. Da das Taktsignal das Signal mit der höchsten Umschaltrate im Design ist, kann die Leistungsaufnahme des Taktbaums bis zu 30% der Gesamtleistungsaufnahme des Designs betragen. Das Hinzufügen einer Clock-Gating-Schaltung kann die Schaltaktivität des Taktbaums reduzieren und Schaltleistung einsparen. Gleichzeitig reduziert die verringerte Schaltaktivität der Taktpins auch die interne Leistungsaufnahme der Register. Daher kann die Verwendung von Clock-Gating die Leistungsaufnahme effektiv senken.
Implementierungsprinzip
Einfach ausgedrückt kann Logik, die den Takt abschaltet, wenn ein Modul oder Flip-Flop nicht arbeitet, ohne die normale Funktionalität zu beeinträchtigen, als Clock-Gating-Logik bezeichnet werden. In diesem Fall ist der Takt nicht immer vorhanden, daher kann er anschaulich als "gated clock" beschrieben werden.

Es gibt hauptsächlich drei Methoden, um Clock-Gating zu implementieren.
1. Verwendung von UND-Logik
Die einfachste Methode besteht darin, direkt eine UND-Verknüpfung zwischen dem Clock-Enable-(Gating-)Signal und dem Takt durchzuführen.
Zum Beispiel, wenn diese Operation auf den Takt eines RAM-Blocks angewendet wird, lautet der Code wie folgt:
Beispiel
module clkgate_basic
(
input clk ,
input clken ,
input rstn ,
input wr_en ,
input [3:0] addr ,
input [7:0] data ,
output [7:0] q
);
//Takt-Gating
wire clk_gate = clk & clken ;
ram #(4, 8)
u1_ram16x8
(
.CLK (clk_gate),
.A (addr),
.D (data),
.EN (clken),
.WR (wr_en),
.Q (q));
endmodule
Das RAM-Modell ist wie folgt:
Beispiel
#( parameter AW = 2 ,
parameter DW = 3 )
(
input CLK ,
input [AW-1:0] A ,
input [DW-1:0] D ,
input EN ,
input WR , //1 für Schreiben und 0 für Lesen
output reg [DW-1:0] Q
);
parameter MASK = 3 ;
reg [DW-1:0] mem [0:(1<<AW)-1] ;
always @(posedge CLK) begin
if (EN && WR) begin
mem[A] <= D ;
end
else if (EN && !WR) begin
Q <= mem[A] ;
end
end
endmodule
Der Testbench-Code ist wie folgt:
Beispiel
module test ;
//Signaldeklaration
reg rstn ;
reg clk ;
reg clken ;
reg wr_en ;
reg [3:0] addr ;
reg [7:0] data ;
wire [7:0] q ;
initial begin
rstn = 0 ;
#7 rstn = 0 ;
end
always begin
#50 clk = 0 ;
#50 clk = 1 ;
end
//Datenlogik
initial begin
clken = 0 ;
wr_en = 0 ;
addr = 4'h3 ;
data = 8'h31 ;
# 53 ;
//(1) normales Schreiben und Lesen
clken = 1 ;
wr_en = 1 ;
repeat(9) begin
@(negedge clk) ;
data = data + 1 ;
addr = addr + 1 ;
end
@(negedge clk) ;
clken = 0 ;
wr_en = 0 ;
//lesen
#211;
addr = 4'h3 ;
clken = 1 ;
repeat(9) begin
@(negedge clk) ;
addr = addr + 1 ;
end
@(negedge clk) ;
//ende
clken = 0 ;
end // initial begin
clkgate_basic u_ram_clkgate
(
.clk (clk),
.clken (clken),
.rstn (rstn),
.wr_en (wr_en),
.addr (addr),
.data (data),
.q (q)
);
//Simulationsende
always begin
#100;
if ($time >= 10000) begin
#1 ;
$finish ;
end
end
endmodule
Erfassen Sie die RAM-Portsignale; die Testergebnisse sind wie folgt.
Wie in der Abbildung dargestellt, weist der RAM-Takt während des Intervalls zwischen Lese- und Schreibvorgängen eine Periode auf, in der er bei 0 bleibt. Der Takt schaltet nicht um, wenn der RAM nicht arbeitet, was in der Praxis auch den Stromverbrauch stark reduziert.

Die Nachteile dieser Methode sind ebenfalls offensichtlich. Aufgrund von Timing- oder Jitter-Problemen werden nach einer AND-Operation zwischen dem Clock-Enable-Signal und dem Takt leicht Glitches erzeugt, die digitale Schaltungen stark beeinträchtigen können.
Führen Sie im Testbench eine nicht ideale Simulation des Clock-Enable-Signals durch, indem Sie den folgenden Simulationscode hinzufügen:
Beispiel
#985;
addr = 4'h3 ;
clken = 1 ;
repeat(9) begin
@(negedge clk) ;
addr = addr + 1 ;
end
@(negedge clk) ;
clken = 0 ;
#20 clken = 1 ;
#21 clken = 0 ;
#31 clken = 1 ;
#13 clken = 0 ;
Die Simulationsergebnisse beim Lesen des RAM sind wie folgt.

Aus der Abbildung ist ersichtlich, dass aufgrund der Asynchronität oder des Jitters des Signals clken Glitches am Clock-Eingang zum RAM aufgetreten sind. Die Daten an Adresse 0x3 werden verpasst (abhängig vom Timing des Enable-Signals), und die Daten an Adresse 0xC werden zweimal gelesen. Offensichtlich ist der Logikentwurf dieses Clock-Gatings sehr gefährlich.
Um solche Probleme zu lösen, ist eine Latch-Struktur erforderlich, um Glitches zu beseitigen.
2. Verwendung eines Latches
Im Kapitel des Verilog-Tutorials"6.5 Verilog: Latch vermeiden"wird erwähnt, dass die Erzeugung von Latches im Digitalentwurf vermieden werden sollte, aber Clock-Gating ist eine Ausnahme. Daher muss man sich bei der Timing-Analyse keine Sorgen um die Latches machen, die vom Clock-Gating-Teil erzeugt werden.
Das Schaltbild für die Verwendung eines Latches zum Beseitigen von Clock-Gating-Glitches ist unten dargestellt.
Das Clock-Enable-Signal wird an der fallenden Flanke des Takts gelatcht und für einen Taktzyklus unverändert gehalten. Das gelatchte Signal wird dann mit dem Takt UND-verknüpft, wodurch Glitches im Gated Clock beseitigt werden können.

Schreiben Sie den Gated-Clock-Logikteil des Simulationsbeispiels, der direkt die AND-Operation verwendet, so um, dass Latch-Logik verwendet wird; die Änderungen sind wie folgt:
Beispiel
reg en_latch ;
always @(*) begin
if (!clk) begin
en_latch = clken ;
end
end
wire clk_gate = clk & en_latch ;
Die Simulationsergebnisse sind wie folgt.
Obwohl die Daten an Adresse 0x3 weiterhin fehlen (im Zusammenhang mit dem Timing des Enable-Signals), ist der RAM-Takt jetzt ein normaler Takt, und es treten keine Glitches auf (das gelb hervorgehobene CLK-Signal).

3. Verwendung einer Standardzellenbibliothek
Obwohl die Verwendung eines Latches das Auftreten von Glitches beim Clock-Gating beheben kann, erfordert auch das Timing strenge Einschränkungen.
Beim FPGA- oder IC-Design enthält die Synthesebibliothek häufig integrierte Gating-Logikzellen. Solche Gating-Logikzellen wurden umfangreich iteriert und verifiziert, wodurch sie bequemer und sicherer zu verwenden sind.
Daher werden in Clock-Gating-Designs im Allgemeinen direkt spezielle integrierte Gating-Logikzellen instanziiert. Die Instanziierungsmethode ähnelt der von Basiszellen wie AND-Gattern und Buffern; sie werden einfach direkt instanziiert.
Nutzung
Die ordnungsgemäße Verwendung von Clock-Gating-Logik zur Steuerung des Schaltungstakts kann ebenfalls effektiv den Stromverbrauch senken.
1. Manuelles Gating
Fügen Sie ein Clock-Enable-Signal hinzu, um manuell zu steuern, ob der Arbeitstakt des Moduls anliegt.
Wenn das Modul arbeitet, wird das Enable-Signal aktiviert und der Takt eingeschaltet; wenn das Modul im Leerlauf ist, wird das Enable-Signal deaktiviert und der Takt ausgeschaltet, wodurch Strom gespart wird.
Das Simulationsdesign aus dem vorherigen Abschnitt kann als Beispiel für manuelles Gating angesehen werden. Während des RAM-Lese-/Schreibvorgangs ist das Enable-Signal high, der RAM-Takt ist eingeschaltet und der RAM beginnt zu arbeiten; wenn das Enable-Signal low ist, arbeitet der RAM nicht, und zu diesem Zeitpunkt liegt kein Eingangstakt an.
2. Automatisches Gating
Während des Betriebs kann ein Modul seinen eigenen Arbeitszustand automatisch erkennen und ein Busy-Signal ausgeben. Extern kann dieses Indikatorsignal verwendet werden, um Clock-Gating auf einen Teil der internen Logik des Moduls anzuwenden, wodurch Taktumschaltungen reduziert und eine automatische Gating-Steuerung erreicht wird.
Im Gegensatz zum manuellen Gating weisen diese Module während der Arbeit kurze Leerlaufzustände auf. Beim automatischen Gating werden nicht genutzte Takte während dieser kurzen Leerlaufzustände abgeschaltet, anstatt wie beim manuellen Gating direkt den Takt des gesamten Moduls abzuschalten; andernfalls würde das Modul nicht mehr normal funktionieren.
Beispielsweise hat ein UART nach Abschluss einer Datenübertragung einen Leerlaufzustand. Zu diesem Zeitpunkt können die Takte von Modulen wie FIFO-Logik und Baudratengenerierungslogik automatisch abgeschaltet werden.
Beispielsweise kann in einem Design, das eine CPU enthält, Logik hinzugefügt werden, um den Leerlaufzustand des Busses zu erkennen und das Umschalten des Bustakts automatisch zu steuern, um den Stromverbrauch zu reduzieren.
Aus Platzgründen werden hier keine Simulationsbeispiele bereitgestellt.
3. Automatische Gating-Einfügung
Wenn nach Abschluss des RTL-Designs eine Logiksynthese durchgeführt wird, optimiert der Compiler auch automatisch die Logik des Codes, was das Gating der Takteingänge einiger Flip-Flops umfasst. Beispielsweise lautet die RTL-Beschreibung eines synchronen D-Flip-Flops mit Enable-Anschluss wie folgt:
Beispiel
always @(posedge CLK) begin
if (EN) begin
Q = D ;
end
end
Seine RTL-Simulationswellenform vor der Synthese wird unten gezeigt:

Die Simulationswellenform nach der Synthese erscheint häufig wie unten dargestellt:

Aus dem Vergleich ist ersichtlich, dass nach der Synthese das EN-Signal nicht mehr vorhanden ist und der Takt (CP-Anschluss) nach dem Clock-Gating nicht kontinuierlich anliegt. Dies gewährleistet nicht nur die logische Korrektheit, sondern reduziert auch das Takt-Toggling und senkt die Leistungsaufnahme.
Quellcode-Download für dieses Kapitel
Herunterladen