Schlüsselwörter: Verzögerungs-Backannotation, SDF

Die Verzögerungs-Backannotation ist der Prozess, bei dem der Designer auf Basis des Zellbibliotheksprozesses, der Gate-Level-Netzliste sowie der Kapazitäts- und Widerstandsinformationen im Layout mit digitalen Designwerkzeugen Verzögerungsinformationen in die Gate-Level-Netzliste annotiert. Mithilfe der back-annotierten Netzliste kann eine genaue Timing-Simulation durchgeführt werden, wodurch die Simulation näher an eine tatsächlich arbeitende digitale Schaltung heranreicht.

Ablauf der Verzögerungs-Backannotation

Bei den Simulationen in den vorherigen Tutorials handelt es sich im Wesentlichen um funktionale Simulationen. Ob beim IC-Design oder bei der FPGA-Entwicklung – die Timing-Simulation ist unverzichtbar. Der Abschnitt "1.4 Verilog-Entwurfsmethodik" im Verilog-Tutorial beschreibt außerdem den vollständigen Entwicklungsablauf für digitales Design.

Im Folgenden erklären wir, wie die Verzögerungs-Backannotation in diesem Ablauf verwendet wird, als Wiederholung und Festigung.

  • (1) Verwenden Sie eine Hardwarebeschreibungssprache, um die Beschreibung auf RTL-Ebene abzuschließen und eine funktionale Simulation durchzuführen.
  • (2) Wenden Sie bestimmte Timing-Constraints auf Signale wie Takt, Reset und Ausgangsports an, einschließlich Einstellungen für Taktfrequenz, Timing-Checks, Verzögerungen usw., und verwenden Sie diese für die Logiksynthese.
  • (3) Die synthetisierte Gate-Level-Netzliste enthält verschiedene grob geschätzte Verzögerungsinformationen. An diesem Punkt können Sie Verzögerungsinformationen wie Hold, Recovery, Removal und Interconnect entfernen, eine vorläufige Timing-Simulation und statische Timing-Analyse (STA) durchführen und zunächst prüfen, ob Timing wie Setup die Timing-Anforderungen erfüllt. Viele Unternehmen oder Einzelpersonen überspringen die Simulation in diesem Schritt ebenfalls.
  • (4) Führen Sie Place-and-Route für die Gate-Level-Netzliste durch, um sie in eine Layout-Level-Netzliste umzuwandeln. Basierend auf Informationen wie Komponentengeometrie und Fertigungsprozess können die Kapazitäts- und Widerstandsinformationen in der Layoutschaltung extrahiert und anschließend daraus die Verzögerungswerte im Layout berechnet werden.
  • (5) Rückannotieren Sie die Verzögerungsinformationen aus dem Layout nach Place-and-Route in die Layout-Level-Netzliste, sodass die Verzögerungswerte in der Netzliste genau angepasst werden können. Führen Sie dann erneut eine Timing-Simulation und STA durch, um zu prüfen, ob die Timing-Anforderungen erfüllt sind.
  • (6) Wenn alle Überprüfungen bestanden sind, kann mit dem Download, der Implementierung oder der Produktion fortgefahren werden. Bei Timing-Verletzungen prüfen Sie zunächst die Einstellungen der Timing-Constraints, z. B. ob Verzögerungsparameter, Taktfrequenz, Signalbeziehungen usw. korrekt eingestellt sind, und führen Sie dann erneut Place-and-Route durch, um zu prüfen, ob die Verletzungen beseitigt werden können. Wenn keine der oben genannten Maßnahmen die Verletzungen beseitigen kann, muss zum ursprünglichen Design zurückgegangen und die RTL-Beschreibung optimiert werden.

Das schematische Diagramm dieses Prozesses ist wie folgt. Der gelb hervorgehobene Teil gibt die Betriebsanweisungen an, die im digitalen Designablauf hinzugefügt werden können.


SDF-Datei

SDF (Standard Delay Format) ist eine Standarddatei im Verzögerungsformat, die häufig zur Verzögerungsrückannotation verwendet wird. Diese Datei enthält alle Parameter für die Simulation wie IOPATH, INTERCONNECT, TIMING CHECK und andere Verzögerungs- und Timing-Constraint-Parameter. Im Folgenden wird die SDF-Datei kurz eingeführt.

Dateiformat

Die SDF-Datei wird mit dem Schlüsselwort DELAYFILE deklariert und enthält Schlüsselwortinformationen wie DESIGN, DATE usw.

Die Verzögerungszeit und die Timing-Constraint-Parameter werden alle innerhalb von CELL beschrieben.

Eine SDF-Datei besteht aus Dateideklarationsinformationen und vielen verschiedenen CELLs, wobei das Format wie folgt lautet.

(DELAYFILE
(DESIGN "top")
(DATE "Love Sep 7 11:11:11 2017")
......
(TIMESCALE 1ns)
(CELL
  ......
)
(CELL
  ......
)
......
)

Verzögerungstypen

Die Verzögerungstypen in der SDF-Datei umfassen Zellverzögerung und Leitungsverzögerung. Die Zellverzögerung bezieht sich auf die interne Verzögerung von Logikgatter-Zellbauelementen, während sich die Leitungsverzögerung auf die Verzögerung von Verbindungen zwischen Bauelementen über Leitungen bezieht.

Die Beschreibung der Zellverzögerung lautet wie folgt. Sie definiert die Anstiegsverzögerung und die Abfallverzögerung zwischen den Eingangsports (A/B) und dem Ausgangsport (Z) des Moduls "and_gate" und gibt die Minimal- und Maximalwerte an.

(CELL
  (CELLTYPE "and_gate")  //Modulname
  (INSTANCE u_and)       //Instanzname; wenn mehrstufiger Zugriff erforderlich ist, geben Sie die Zugriffshierarchie an
  (DELAY
    (ABSOLUTE
    (IOPATH A Z (1.5::1.8) (1.3::1.7))  //Anstiegsverzögerung: Minimum 1.5, Maximum 1.8
    (IOPATH B Z (1.5::1.8) (1.3::1.7))  //Abfallverzögerung: Minimum 1.3, Maximum 1.7
    )
  )
)

Die Beschreibung der Leitungsverzögerung lautet wie folgt. Sie definiert die Anstiegsverzögerung und die Abfallverzögerung vom Ausgang u_and zum Eingang u_dt im Modul "top" und gibt die Minimal- und Maximalwerte an.

Im Allgemeinen können die RTL-Simulation oder die synthetisierte Gate-Level-Netzliste die Leitungsverzögerung ignorieren, weil das Backend noch Place and Route erneut durchführen muss. Die Netzliste nach Place and Route kommt der realen Schaltung nahe, daher muss an diesem Punkt die Leitungsverzögerung berücksichtigt werden.

(CELL
  (CELLTYPE "top") //Modulname
  (INSTANCE)       //Wenn es das Top-Level-Entwurfsmodul ist, kann der Instanzname ignoriert werden
  (DELAY
    (ABSOLUTE
    (INTERCONNECT u_and.Z u_dt.D (0.500::0.751) (0.400::0.551))
    //(INTERCONNECT u_and/Z u_dt/D (0.500::0.751) (0.400::0.551))
    //Hierarchie-Zugriffssymbol: einige Compiler unterstützen ".", einige unterstützen "/"; dies hier beachten
    )
  )
)

Bedingte Verzögerungen und Timing-Checks

In CELL kann das Schlüsselwort COND auch verwendet werden, um bedingte Verzögerungen anzugeben.

Gleichzeitig können auch Timing-Checks innerhalb von CELL durchgeführt werden.

Ein Beispiel für eine Verzögerungsangabe und einen Timing-Check für einen D-Flipflop ist wie folgt.

(CELL
  (CELLTYPE "d_gate")
  (INSTANCE u_dt)
  (DELAY
    (ABSOLUTE
    // wenn D=1, beträgt die Anstiegsverzögerung 1.3-2.3, die Abfallverzögerung beträgt 1.5-2.2
    (COND D==1'b1 (IOPATH CP Q (1.3::2.3) (1.5::2.2)))
    // wenn D=0, beträgt die Anstiegsverzögerung 1.2-2.1, die Abfallverzögerung beträgt 1.4-2.0
    // hier dient es nur zur Veranschaulichung der Verwendung von COND; der Abfallverzögerungsparameter kann nicht verwendet werden, wenn D=1
    // der Anstiegsverzögerungsparameter kann nicht verwendet werden, wenn D=0
    (COND D==1'b0 (IOPATH CP Q (1.2::2.1) (1.4::2.0)))
    )
  )
  (TIMINGCHECK
  (SETUP D (posedge CP) (0.8::1))
  //Setup-Prüfung: Wenn die D-CP-Zeit kleiner als 0.8 oder 1 ist, wird eine Verletzung ausgegeben
  )
)

Nutzung

Verilog stellt die Systemfunktion $sdf_annotate bereit, um eine SDF-Datei aufzurufen, um den Prozess der Verzögerungs-Backannotation abzuschließen.

Das Verwendungsformat ist wie folgt:

$sdf_annotate ('sdf_file'[, module_instance] [,'sdf_configfile'][,'sdf_logfile'][,'mtm_spec'] [,'scale_factors'][,'scale_type']);

Hier muss sdf_file angegeben werden; die übrigen Parameter sind optional.

Hier werden nur die ersten paar häufig verwendeten Parameter erläutert.

  • sdf_file: der SDF-Dateiname, einschließlich Pfadinformationen.
  • module_instance: der Name des instanziierten Designmoduls, im Allgemeinen der Name des im Testbench instanziierten digitalen Designmoduls; achten Sie darauf, die Hierarchie konsistent mit den Deklarationen im Inhalt der SDF-Datei zu halten.
  • log_file: das Protokoll über SDF während der Kompilierung, zum einfachen Nachschlagen.
  • mtm_spec: gibt den zu verwendenden Verzögerungstyp an. Optionen sind MAXIMUM, MINIMUM und TYPICAL, was bedeutet, dass die maximalen, minimalen bzw. typischen Werte verwendet werden, die in der SDF-Datei annotiert sind. Natürlich gibt das obige SDF-Dateibeispiel keine typischen Werte an.

Simulation mit specify

Das Folgende verwendet specify, um eine einfache Timing-Simulation durchzuführen, um sie mit der Timing-Simulation unter Verwendung einer SDF-Datei zu vergleichen.

Eine AND-Gatter-Logikbeschreibung mit Verzögerungen, die mit specify angegeben werden, ist wie folgt:

module and_gate(
   output  Z,
   input   A, B);

   assign Z = A & B ;

   angeben
      specparam t_rise = 1.3:1.5:1.7 ;
      specparam t_fall = 1.1:1.3:1.6 ;
      (A, B  *> Z) = (t_rise, t_fall) ;
   endspecify

 endmodule

Eine D-Flipflop-Beschreibung mit Verzögerungen, die mit specify angegeben werden, ist wie folgt:

Beispiel

module d_gate(
            output      Q ,
            input       D, CP);

   reg                  Q_r ;
   always @(posedge CP)
     Q_r <= D ;
   assign       Q = Q_r ;

   angeben
      if (D == 1'b1)
        (posedge CP => (Q +: D)) = (1.3:1.5:1.7, 1.1:1.4:1.9) ;
      if (D == 1'b0)
        (posedge CP => (Q +: D)) = (1.2:1.4:1.6, 1.0:1.3:1.8) ;
      $setup(D, posedge CP, 1);
   endspecify

endmodule

Die Beschreibung des Top-Level-Moduls lautet wie folgt. Ihre Hauptfunktion besteht darin, die Ausgabe der UND-Logik in ein D-Flipflop zum Zwischenspeichern einzugeben.

Beispiel

module top(
   output  and_out,
   input   in1, in2, clk);

   wire    res_tmp ;
   and_gate u_and(res_tmp, in1, in2);
   d_gate u_dt(and_out, res_tmp, clk);

endmodule

Die Testbench-Beschreibung lautet wie folgt. Während der Simulation wird "+maxdelays" gesetzt, um die maximalen Verzögerungswerte zu verwenden.

Beispiel

`timescale 1ns/1ps
module test ;
   wire         and_out ;
   reg          in1, in2 ;
   reg          clk ;

   initial begin
      clk = 0 ;
      forever begin
          #(10/2) clk = ~clk ;
      end
   end

   initial begin
      in1 = 0 ; in2 = 0 ;
      # 32 ;
      in1 = 1 ; in2 = 1 ;
      # 13 ;
      in1 = 1 ; in2 = 0 ;
   end

   top   u_top(
               .and_out (and_out),
               .in1     (in1),
               .in2     (in2),
               .clk     (clk));

   initial begin
      forever begin
         #100;
         if ($time >= 1000)  $finish ;
      end
   end

endmodule // test

Das Simulations-Timing ist unten dargestellt. Aus der Abbildung können wir erkennen:

  • (1) Die Anstiegsverzögerung vom AND-Gatter-Eingang A/B zum Ausgang Z beträgt 33.7-32=1.7ns;
  • (2) Die Verbindungsverzögerung vom AND-Gatter-Ausgang Z zum Flipflop-Eingang D beträgt 0;
  • (3) Die Zeitdifferenz vom D-Anschluss des Flipflops zum CP-Anschluss beträgt 35-33.7=1.3ns, was größer als die im Setup-Check festgelegte 1ns ist, daher erfüllt das Timing die Anforderungen und es liegt keine Verletzung vor.
  • (4) Die Anstiegsverzögerung vom CP-Anschluss des Flipflops zum Ausgang Q beträgt 36.7-35=1.7ns;

Zusammenfassend entsprechen die Simulationsergebnisse den Entwurfsparametern.

Simulation mit SDF

Behalten Sie die im SDF-Dateibeispiel verwendeten Parameter unverändert bei, und integrieren Sie mehrere CELL-Beschreibungen in eine vollständige SDF-Datei namens "simple_test.sdf".

Fügen Sie die folgenden Anweisungen zum Testbench hinzu, um die Verzögerungsinformationen aus der SDF-Datei in das entworfene Modul top rückzuannotieren, und führen Sie die Timing-Simulation erneut aus.

   initial begin
      $sdf_annotate("../rtl/simple_test.sdf", u_top, , "sdf.log", "MAXIMUM", ,);
   end

Die Simulations-Timing- und Log-Ausgabeinformationen sind wie folgt. Aus der Abbildung ist zu erkennen:

  • (1) Die Anstiegsverzögerung vom Eingang A/B des AND-Gatters zum Ausgang Z beträgt 33.8-32=1.8ns;
  • (2) Die Verbindungsverzögerung vom Ausgang Z des AND-Gatters zum Eingang D des Flipflops beträgt 34.551-33.8=0.751ns, nicht mehr 0.
  • (3) Die Zeitdifferenz vom D-Anschluss des Flipflops zum CP-Anschluss beträgt 35-34.551=0.449ns, was weniger als die bei der Setup-Prüfung eingestellte 1ns ist. Daher erfüllt das Timing die Anforderungen nicht, und es wird eine Verletzungsmeldung ausgegeben.
  • (4) Die Anstiegsverzögerung vom CP-Anschluss des Flipflops zum Ausgangsanschluss Q beträgt 37.3-35=2.3ns.

Zusammenfassend entsprechen die Simulationsergebnisse den Entwurfsparametern, aber es liegt eine Timing-Verletzung vor. Der Hauptgrund ist, dass die Daten am AND-Gatter-Eingang und der Flipflop-Takt asynchron und unabhängig voneinander sind. Um solche asynchronen Probleme zu lösen, lesen Sie bitte das nächste Kapitel, "Kapitel 4: Synchron und Asynchron".

Es ist zu beachten, dass:

Im Vergleich zu specify-Block-Anweisungen können SDF-Dateien auch Leitungsverzögerungen zwischen Modulen angeben.

Im Allgemeinen kommt die Verwendung von SDF-Dateien zur Angabe von Timing-Informationen von Netzlisten auf Layout-Ebene dem tatsächlichen digitalen Schaltkreis am nächsten. Verglichen mit RTL- oder synthetisierten Gate-Level-Netzlisten ist das Timing dieser Version am schlechtesten.

Wenn eine SDF-Datei modulinterne Pfadverzögerungen angibt, muss der specify-Block des ursprünglichen Moduls beibehalten werden, und die Bedingungen, Typen usw. der im specify-Block und in der SDF-Datei angegebenen Verzögerungen müssen übereinstimmen, obwohl die Verzögerungswerte unterschiedlich sein können. Geben Sie zum Beispiel die Verzögerung im specify-Block bedingungslos an:

(A => Z) = (1.3, 1.7) ;

Geben Sie eine bedingte Verzögerung in der SDF-Datei an:

(COND A==1'b1&&B==1'b1 (IOPATH A Z (1.5::1.8) (1.3::1.7)))

Dann wird während der Kompilierungsphase eine SDF-Warnung mit "IOPATH from A to Z is not found." gemeldet. Die von der SDF-Datei festgelegte Verzögerung ist ungültig. Hier sollte die SDF-Datei ebenfalls die bedingungslose Methode verwenden, um Pfadverzögerungen anzugeben.

Dieses Mal wurde die SDF-Datei nur manuell geschrieben, um die SDF-Datei und ihre Verwendung vorzustellen. In der Realität werden SDF-Dateien von Designern mit Hilfe von IC-Design-Tools (wie PrimeTime) generiert, daher müssen Sie sich über den vorherigen Hinweis nicht zu viele Gedanken machen; achten Sie einfach beim Debuggen darauf. Im Allgemeinen ist die Gate-Level-Netzliste im digitalen Design riesig, sodass das manuelle Schreiben von SDF-Dateien ebenfalls unpraktisch ist.

Quellcode-Download für dieses Kapitel

Herunterladen