Exemple de porte NAND

Dans un UDP de logique combinatoire, la table d'état spécifie différentes combinaisons d'entrées et les valeurs de sortie correspondantes. Toute combinaison non spécifiée produit x.

Un UDP simple de porte NAND peut s'exprimer comme suit :

primitive nand_my(out, a, b);
   output       out ;
   input        a, b ;

   table
    //a b : out ;
      0         0       :       1 ;
      0         1       :       1 ;
      1         0       :       1 ;
      1         1       :       0 ;
   endtable
endprimitive

Comme expliqué dans la section précédente, la liste des ports et la section de déclaration peuvent être modifiées comme suit :

primitive nand_my(
  output       out,
  input        a, b);
  ......
endprimitive

Éléments de la table d'état

Le format de syntaxe de chaque ligne de la table d'état représentant une logique combinatoire est le suivant :

<input1>  <input2>  ...  <inputN>  :  <output> ;
  • 1. L'ordre des signaux d'entrée dans la table d'état doit être cohérent avec l'ordre de la liste des ports de l'UDP.
  • 2. L'entrée et la sortie utilisent un deux-points:pour les séparer.
  • 3. Chaque ligne de la table d'état se termine par un point-virgule;pour terminer.
  • 4. Toutes les combinaisons d'entrée pouvant produire une valeur de sortie définie doivent être listées dans la table d'état, sinon une valeur x sera émise.

Par exemple, dans l'UDP nand_my ci-dessus, si a=0, b=x, alors la sortie out = x, car cette combinaison ne peut pas être trouvée dans la table. Par conséquent, lors de l'écriture d'un UDP, toutes les combinaisons d'entrée doivent être pleinement prises en compte.

La table d'état de l'UDP nand_my peut être modifiée en :

   table
    //a b : out ;
      0         0       :       1 ;
      0         1       :       1 ;
      1         0       :       1 ;
      1         1       :       0 ;

      0         x       :       1 ;
      x         0       :       1 ;
   endtable

Termes indifférents

Dans l'UDP nand_my, lorsque a ou b vaut 0, la sortie vaut 1.

Les signaux d'entrée qui n'affectent pas le résultat de sortie sont des termes indifférents, qui peuvent être représentés par un point d'interrogation « ? ». L'élément « ? » dans la table d'état sera automatiquement étendu à 0, 1 ou x.

Par conséquent, la table d'état de l'UDP nand_my peut être modifiée comme suit :

   table
    //a b : out ;
      0         ?       :       1 ;
      ?         0       :       1 ;
      1         1       :       0 ;

      // La combinaison suivante produira x, elle peut donc aussi être omise. Verilog produit x par défaut.
      1         x       :       x ;
      x         1       :       x ;
   endtable

Instanciation UDP

Le format d'appel d'UDP est exactement le même que celui des primitives de niveau porte intégrées.

Utilisez l'UDP nand_my ci-dessus pour compléter la simulation de la bascule D dans« 1.3 Délai de porte ».

Une fois les informations de délai supprimées, le modèle de bascule D est le suivant.

Exemples

module D_TRI(
            input       D, CP,
            output      Q, QR);

   //partie 1, porte NON
   wire         CPN, DN ;
   not          (CPN, CP);
   not          (DN, D);

   //partie 2, déclencheur maître
   wire         G3O, G4O ;
   nand_my      (G3O, D, CP);
   nand_my      (G4O, DN, CP);
   wire         G1O, G2O ;
   nand_my      (G1O, G3O, G2O);
   nand_my      (G2O, G4O, G1O);

   //partie 3, déclencheur esclave
   wire         G7O, G8O ;
   nand_my      (G7O, G1O, CPN);
   nand_my      (G8O, G2O, CPN);
   wire         G5O, G6O ;
   nand_my      (G5O, G7O, G6O);
   nand_my      (G6O, G8O, G5O);

   assign       Q = G5O ;
   assign       QR = G6O ;

endmodule

Le banc de test reste inchangé, et les résultats de simulation sont les suivants.

Comme on peut le voir sur la figure, la bascule capture le signal d'entrée D sur le front descendant de l'horloge CP et le transmet à Q/QR, qui reste inchangé au cours d'un même cycle d'horloge.

La porte NAND implémentée par l'UDP fonctionne correctement.

Téléchargement du code source de ce chapitre

Téléchargement