Ключевые слова: триггер, защелка

Что такое защелка

Защелка — это чувствительный к уровню запоминающий элемент. Действие по сохранению данных зависит от значения уровня входного тактового сигнала (или сигнала разрешения). Только когда защелка находится в разрешенном состоянии, выход изменяется вместе с входными данными.

Когда сигнал уровня неактивен, выходной сигнал изменяется вместе с входным сигналом, как будто проходит через буфер; когда уровень активен, выходной сигнал фиксируется. Любое изменение сигнала возбуждения напрямую приводит к изменению состояния выхода защелки, что с большой вероятностью может вызвать колебания из-за нестабильных переходных характеристик.

Схема защелки приведена ниже:

Триггер — это чувствительный к фронту запоминающий элемент. Действие по сохранению данных (переход состояния) синхронизируется нарастающим или спадающим фронтом сигнала (ограничивая переход состояния запоминающего элемента очень коротким промежутком времени).

Схема триггера приведена ниже:

Регистр — это переменная в Verilog, используемая для временного хранения данных, участвующих в операциях, и результатов операций. Когда переменная объявлена как регистр, она может быть синтезирована в триггер, защелку или даже переменную типа wire. Однако в большинстве случаев мы ожидаем, что она будет синтезирована в триггер, но иногда из-за проблем с написанием кода она может быть синтезирована в нежелательную структуру защелки.

Основные опасности защелок:

  • 1) Входное состояние может изменяться несколько раз, что легко приводит к глитчам и увеличивает неопределённость схемы следующего каскада;
  • 2) В большинстве ресурсов FPGA реализация структуры защёлки может потребовать больше ресурсов, чем триггер;
  • 3) Наличие защёлок усложняет статический временной анализ.

Защёлки в основном используются для управления стробированием тактового сигнала. В общем проектировании следует избегать появления защёлок.

Неполная структура if

В комбинационной логике неполная структура if-else сгенерирует защёлку.

Например, в следующей модели в операторе if отсутствует ветвь else. По умолчанию значение регистра q в ветви else остаётся неизменным, что означает выполнение функции хранения данных. Следовательно, регистр q будет синтезирован в структуру защёлки.

Пример

module module1_latch1(
    input       data,
    input       en ,
    output reg  q) ;
   
    always @(*) begin
        if (en) q = data ;
    end

endmodule

Существует в основном два способа избежать таких защёлок: один — дополнить структуру if-else, другой — присвоить сигналу начальные значения.

Например, оператор always в приведённой выше модели можно изменить на следующие две формы:

Пример

    // Дополните структуру условных ветвлений
    always @(*) begin
        if (en)  q = data ;
        else     q = 1'b0 ;
    end

    // Присвоить начальное значение
    always @(*) begin
        q = 1'b0 ;
        if (en) q = data ; // Если en валиден, перезаписать значение q; иначе q останется 0.
    end

Однако в последовательностной логике неполная структура if-else не создаёт защёлку, как показано в следующей модели.

Это потому, что регистр q обладает способностью хранить значение, и его значение изменяется только по фронту тактового сигнала, что как раз и является характеристикой триггера.

Пример

module module1_ff(
    input       clk ,
    input       data,
    input       en ,
    output reg  q) ;
   
    always @(posedge clk) begin
        if (en) q <= data ;
    end

endmodule

В комбинационной логике, когда в условном операторе много операторов присваивания, неполные операторы присваивания при каждом условии ветвления также будут создавать защёлку.

Фактически, с точки зрения логического разложения каждого сигнала, это эквивалентно неполной структуре if-else, где соответствующий сигнал регистра не имеет поведения присваивания при других условиях. Например:

Пример

module module1_latch11(
    input       data1,
    input       data2,
    input       en ,
    output reg  q1 ,
    output reg  q2) ;
   
    always @(*) begin
        if (en)   q1 = data1 ;
        else      q2 = data2 ;
    end

endmodule

Эту ситуацию также можно избежать, завершив операторы присваивания или задав начальные значения. Например:

Пример

    always @(*) begin
        // q1 = 0; q2 = 0; // или задайте начальные значения для q1/q2 здесь
        if (en)  begin
            q1 = data1 ;
            q2 = 1'b0 ;
        end
        else begin
            q1 = 1'b0 ;
            q2 = data2 ;
        end
    end

Неполная структура case

Принцип возникновения защёлок из-за операторов case почти такой же, как у операторов if. В комбинационной логике, когда список элементов case неполон и не добавлено ключевое слово default, или несколько операторов присваивания неполны, также будет сгенерирована защёлка. Например:

Пример

module module1_latch2(
    input       data1,
    input       data2,
    input [1:0] sel ,
    output reg  q ) ;
   
    always @(*) begin
        case(sel)
            2'b00:  q = data1 ;
            2'b01:  q = data2 ;
        endcase
    end

endmodule

Конечно, существуют также два способа устранения таких защёлок: дополнить список элементов case или задать начальные значения для сигнала.

При дополнении списка элементов case можно перечислить все варианты элементов или использовать ключевое слово default, чтобы охватить остальные варианты элементов.

Например, приведённый выше оператор always можно изменить следующими двумя способами.

Пример

    always @(*) begin
        case(sel)
            2'b00:    q = data1 ;
            2'b01:    q = data2 ;
            default:  q = 1'b0 ;
        endcase
    end

    always @(*) begin
        case(sel)
            2'b00:  q = data1 ;
            2'b01:  q = data2 ;
            2'b10, 2'b11 :  
                    q = 1'b0 ;
        endcase
    end

Присваивание исходного сигнала или проверка условия

В комбинационной логике, если источник присваивания сигнала включает сам сигнал или если условие проверки содержит логику для самого сигнала, также будет сгенерирована защёлка. Это связано с тем, что сигнал также должен обладать способностью к хранению, но его не управляет тактовый сигнал. Такие проблемы могут возникать в операторах if, операторах case и тернарных выражениях, например:

Пример

    //сам сигнал как часть условия
    reg a, b ;
    always @(*) begin
        if (a & b)  a = 1'b1 ;   //a -> защёлка
        else a = 1'b0 ;
    end
   
    //сам сигнал является источником присваивания
    reg        c;
    wire [1:0] sel ;
    always @(*) begin
        case(sel)
            2'b00:    c = c ;    //c -> защёлка
            2'b01:    c = 1'b1 ;
            default:  c = 1'b0 ;
        endcase
    end

    //сам сигнал как часть условия в "? выражении"
    wire      d, sel2;
    assign    d =  (sel2 && d) ? 1'b0 : 1'b1 ;  //d -> защёлка

Есть только один способ избежать таких защёлок: избегать этого стиля кодирования в комбинационной логике. Не присваивайте сигналу значение от него самого и не используйте сам присваиваемый сигнал в логике условий.

Например, если немедленный вывод не требуется, сигнал можно задержать на один такт перед объединением соответствующей логики. Первый код, который выше сгенерировал защёлку, можно описать так:

Пример

    reg   a, b ;
    reg   a_r ;
   
    always (@posedge clk)
        a_r  <= a ;
       
    always @(*) begin
        if (a_r & b)  a = 1'b1 ;   //защёлки нет
        else a = 1'b0 ;
    end

Неполный список чувствительных сигналов

Если список чувствительности в блоке always@() в комбинационной логике неполон и блок не срабатывает, когда должен, соответствующий регистр всё ещё будет удерживать предыдущий выходной результат, тем самым создавая защёлку.

В этом случае завершение списка чувствительных сигналов или непосредственное использование always@(*) позволит устранить защелку.

Итог

Короче говоря, чтобы избежать генерации защелок, в комбинационной логике необходимо учитывать следующие моменты:

  • 1) Структура операторов if-else или case должна быть полной.
  • 2) Не помещайте сигнал, которому присваивается значение, в источник присваивания или в условия.
  • 3) Для списка чувствительных сигналов рекомендуется использовать always@(*).

Скачать исходный код

Скачать