Reloj de compuerta

Normalmente, el árbol de reloj está compuesto por una gran cantidad de buffers e inversores. Y como la señal de reloj es la que tiene la mayor tasa de conmutación en el diseño, el consumo del árbol de reloj puede llegar a ser hasta el 30% del consumo total del diseño. Al añadir un circuito de reloj de compuerta (clock gating), se reduce la actividad de conmutación del árbol de reloj, lo que ahorra energía de conmutación. Al mismo tiempo, al reducir la conmutación de los pines de reloj, también se reduce el consumo interno de los registros. Por lo tanto, el uso de reloj de compuerta puede reducir eficazmente el consumo de energía.

Principio de implementación

En términos sencillos, cuando un módulo o flip-flop no está trabajando, la lógica que apaga el reloj sin afectar la función normal se puede llamar lógica de reloj de compuerta. En este caso, el reloj no está presente todo el tiempo, por lo que se puede denominar visualmente como reloj de compuerta.

Hay principalmente los siguientes 3 métodos para implementar el reloj de compuerta.

1. Uso de lógica AND

El método más simple es realizar directamente la operación lógica AND entre la señal de habilitación de reloj (compuerta) y el reloj.

Por ejemplo, para realizar esta operación en el reloj de una RAM, el código es el siguiente:

Ejemplo

// use and-logic
module  clkgate_basic
    (
        input           clk ,
        input           clken ,
        input           rstn ,
        input           wr_en ,
        input [3:0]     addr ,
        input [7:0]     data ,
        output [7:0]    q
     );

   //clk gate
  wire                 clk_gate = clk & clken ;
   ram #(4, 8)
      u1_ram16x8
        (
         .CLK   (clk_gate),
         .A     (addr),
         .D     (data),
         .EN    (clken),
         .WR    (wr_en),
         .Q     (q));

endmodule

El modelo de la RAM es el siguiente:

Ejemplo

module  ram
    #(  parameter       AW = 2 ,
        parameter       DW = 3 )
    (
        input                   CLK ,
        input [AW-1:0]          A ,
        input [DW-1:0]          D ,
        input                   EN ,
        input                   WR ,    //1 for write and 0 for read
        output reg [DW-1:0]     Q
     );

   parameter            MASK = 3 ;

   reg [DW-1:0]         mem [0:(1<<AW)-1] ;
   always @(posedge CLK) begin
      if (EN && WR) begin
         mem[A]  <= D ;
      end
      else if (EN && !WR) begin
         Q       <= mem[A] ;
      end
   end

endmodule

El código del testbench es el siguiente:

Ejemplo

`timescale 1ns/1ns
module test ;
   //signals declaration
   reg          rstn ;
   reg          clk ;
   reg          clken ;
   reg          wr_en ;
   reg [3:0]    addr ;
   reg [7:0]    data ;
   wire [7:0]   q ;

   initial begin
      rstn      = 0 ;
      #7 rstn   = 0 ;
   end

   always begin
      #50 clk = 0 ;
      #50 clk = 1 ;
   end

   //data logic
   initial begin
      clken     = 0 ;
      wr_en     = 0 ;
      addr      = 4'h3 ;
      data      = 8'h31 ;
      # 53 ;
      //(1) normal write and read
      clken     = 1 ;
      wr_en     = 1 ;
      repeat(9) begin
         @(negedge clk) ;
         data   = data + 1 ;
         addr   = addr + 1 ;
      end
      @(negedge clk) ;
      clken     = 0 ;
      wr_en     = 0 ;

      //read
      #211;
      addr      = 4'h3 ;
      clken     = 1 ;
      repeat(9) begin
         @(negedge clk) ;
         addr   = addr + 1 ;
      end
      @(negedge clk) ;
      //end
      clken     = 0 ;
   end // initial begin

   clkgate_basic u_ram_clkgate
    (
        .clk    (clk),
        .clken  (clken),
        .rstn   (rstn),
        .wr_en  (wr_en),
        .addr   (addr),
        .data   (data),
        .q      (q)
     );

   //simulation finish
   always begin
      #100;
      if ($time >= 10000)  begin
         #1 ;
         $finish ;
      end
   end

endmodule

Capturando las señales de los puertos de la RAM, los resultados de la prueba son los siguientes.

Como se muestra en la figura, durante las operaciones de lectura y escritura, el reloj de la RAM tiene un período en el que permanece en 0. El reloj no conmuta cuando la RAM no está trabajando, lo que en la práctica también reduce mucho el consumo de energía.

Las desventajas de este método también son muy evidentes. Debido a problemas de temporización o de jitter, después de realizar la operación AND entre la señal de habilitación de reloj y el reloj, es fácil que se generen glitches, lo que puede afectar gravemente al circuito digital.

En el testbench, para simular de forma no ideal la señal de habilitación de reloj, se añade el siguiente código de simulación:

Ejemplo

      //(2) jitter at the end of read
      #985;
      addr      = 4'h3 ;
      clken     = 1 ;
      repeat(9) begin
         @(negedge clk) ;
         addr   = addr + 1 ;
      end
      @(negedge clk) ;
      clken     = 0 ;
      #20 clken = 1 ;
      #21 clken = 0 ;
      #31 clken = 1 ;
      #13 clken = 0 ;

El resultado de la simulación de lectura de la RAM es el siguiente.

Como se observa en la figura, debido a problemas asíncronos o de fluctuación de la señal clken, el reloj de entrada a la RAM ya presenta glitches. El dato en la dirección 0x3 se omite (relacionado con la temporización de la señal de habilitación), y el dato en la dirección 0xC se lee dos veces. Evidentemente, el diseño lógico de este reloj de compuerta es muy peligroso.

Para resolver este tipo de problemas, se necesita utilizar una estructura de latch para eliminar los glitches.

2. Uso de latch

En el capítulo del "Tutorial de Verilog""6.5 Verilog: Evitar Latch"se menciona que en el diseño digital se debe evitar la generación de Latch, pero el clock gating es una excepción. Por lo tanto, al realizar el análisis de temporización, no es necesario preocuparse por el Latch generado en la parte de clock gating.

El diagrama del circuito que utiliza latch para eliminar los glitches del reloj de compuerta se muestra a continuación.

En el flanco descendente del reloj, se captura la señal de habilitación de reloj y se mantiene sin cambios durante un ciclo de reloj. Luego, la señal capturada se combina con el reloj mediante una operación AND, lo que permite eliminar los glitches del reloj de compuerta.

En el ejemplo de simulación, la parte de la lógica de reloj de compuerta que realizaba directamente la operación AND se modifica para usar lógica de latch, quedando de la siguiente manera:

Ejemplo

   //(2) using latch
   reg                  en_latch ;
   always @(*) begin
      if (!clk) begin
         en_latch       = clken ;
      end
   end
   wire clk_gate = clk & en_latch ;

El resultado de la simulación es el siguiente.

Aunque el dato en la dirección 0x3 todavía se omite (relacionado con la temporización de la señal de habilitación), el reloj de la RAM ya es un reloj normal y ya no aparecen glitches (la señal CLK marcada en amarillo).

3. Uso de la biblioteca de celdas estándar

Aunque el uso de latch puede resolver la aparición de glitches en el reloj de compuerta, la temporización también requiere restricciones estrictas.

En el diseño de FPGA o IC, la biblioteca de síntesis suele contener celdas de lógica de compuerta integradas. Este tipo de celdas de lógica de compuerta han pasado por numerosas actualizaciones, iteraciones y verificaciones, por lo que su uso es más conveniente y seguro.

Por lo tanto, en general, el diseño de reloj de compuerta también invoca directamente las celdas de lógica de compuerta integradas dedicadas. El método de invocación es similar al de las celdas básicas como compuertas AND y buffers; basta con instanciarlas directamente.

Forma de uso

El uso razonable de la lógica de reloj de compuerta para controlar el reloj del circuito también reducirá eficazmente el consumo de energía.

1. Gating manual

Añadir una señal de habilitación de reloj para controlar manualmente si el reloj de trabajo del módulo está presente o no.

Cuando el módulo está trabajando, la señal de habilitación se activa y el reloj se enciende; cuando el módulo está inactivo, la señal de habilitación se desactiva y el reloj se apaga, ahorrando energía.

El diseño de simulación de la sección anterior puede considerarse un ejemplo de gating manual. Cuando la RAM lee o escribe, la señal de habilitación está en alto, el reloj de la RAM se activa y la RAM comienza a funcionar; cuando la señal de habilitación está en bajo, la RAM no trabaja y en ese momento no hay reloj de entrada.

2. Gating automático

Cuando el módulo está trabajando, puede detectar automáticamente su propio estado de funcionamiento y generar una señal busy (ocupado). El exterior puede utilizar esta señal indicadora para aplicar clock gating a parte de la lógica interna del módulo, reduciendo la conmutación del reloj y logrando un control de gating automático.

A diferencia del gating manual, estos módulos tienen breves estados inactivos durante el funcionamiento. El gating automático consiste en apagar el reloj innecesario durante estos breves estados inactivos, en lugar de apagar directamente el reloj de todo el módulo como en el gating manual, de lo contrario el módulo ya no podría funcionar correctamente.

Por ejemplo, UART tiene un estado inactivo después de completar una transmisión de datos. En este momento, se pueden apagar automáticamente los relojes de módulos como la lógica FIFO o la lógica de generación de baudios.

Por ejemplo, en diseños que incluyen CPU, se puede añadir lógica para detectar el estado inactivo del bus y controlar automáticamente el reloj del bus, reduciendo así el consumo de energía.

Por limitación de espacio, no se proporcionarán más ejemplos de simulación aquí.

3. Inserción automática de gating

Cuando se realiza la síntesis lógica después de completar el diseño RTL, el compilador también optimiza automáticamente la lógica del código, lo que incluye aplicar gating al terminal de reloj de algunos flip-flops. Por ejemplo, la descripción RTL de un flip-flop D síncrono con terminal de habilitación es la siguiente:

Ejemplo

   //(2) Flip-Flop with enable port
   always @(posedge CLK) begin
      if (EN) begin
         Q       = D ;
      end
   end

Su simulación RTL previa se muestra en la siguiente figura:

La forma de onda de simulación después de la síntesis generalmente se muestra como en la siguiente figura:

Al comparar, se puede ver que después de la síntesis ya no existe la señal EN, y el reloj (terminal CP) ya no está presente todo el tiempo después del clock gating. Esto garantiza la corrección lógica, reduce la conmutación del reloj y disminuye el consumo de energía.

Descarga del código fuente de este capítulo

Download