キーワード: ゲート遅延, D フリップフロップ
ゲート遅延の種類
前の2節で紹介したゲートレベル回路には遅延がありませんでしたが、実際のゲートレベル回路には遅延があります。
Verilog では、ユーザーがゲート遅延を使用して、入力から出力信号への伝搬遅延を定義できます。
ゲート遅延の種類には、主に以下の3つがあります。
立ち上がり遅延
ゲートの入力が変化するとき、ゲートの出力が 0,x,z から 1 に変化するのに必要な遷移時間を、立ち上がり遅延と呼びます。

立ち下がり遅延
ゲートの入力が変化するとき、ゲートの出力が 1,x,z から 0 に変化するのに必要な遷移時間を、立ち下がり遅延と呼びます。

ターンオフ遅延
ターンオフ遅延とは、ゲートの出力が 0,1,x からハイインピーダンス状態 z に変化するのに必要な遷移時間のことです。

ゲート出力が 0,1,z から x に変化するのに必要な遷移時間は明確には定義されていませんが、その所要時間は他の遅延タイプによって決まります。つまり、上記3つの遅延値のうち最小の遅延です。
ゲート遅延は、ゲートセルのインスタンス化時に定義できます。定義形式は次のとおりです。
gate_type [delay] [instance_name] (signal_list) ;
ここで、delay の数は 0 個、1 個、2 個、または 3 個にできます。
次の表は、遅延の数が異なる場合の、各種類の遅延の値の説明です。
| 遅延タイプ | 遅延なし | 1 個の遅延 (d) | 2 個の遅延 (d1, d2) | 3 個の遅延 (d1, d2, d3) |
|---|---|---|---|---|
| 立ち上がり | 0 | d | d1 | d1 |
| 立ち下がり | 0 | d | d2 | d2 |
| ターンオフ | 0 | d | min(d1, d2) | d3 |
| to_x | 0 | d | min(d1, d2) | min(d1, d2, d3) |
ユーザーが遅延値を指定しない場合、デフォルトの遅延は 0 です。
ユーザーが 1 つの遅延値を指定した場合、すべてのタイプの遅延値はその値になります。
ユーザーが 2 つの遅延値を指定した場合、それらはそれぞれ立ち上がり遅延と立ち下がり遅延を表し、ターンオフ遅延と「to_x」遅延は、この2つの遅延値のうち小さい方になります。
ユーザーが 3 つの遅延値を指定した場合、それらはそれぞれ立ち上がり遅延、立ち下がり遅延、ターンオフ遅延を表し、「to_x」遅延はこの3つの遅延値のうち最小のものになります。
遅延値を伴うゲートレベルセルのインスタンス化は次のとおりです。
例
and #(1) (OUT1, IN1, IN2) ;
//rise delay = 2.1, fall dalay = 2, trun-off delay = 2
or #(2.1, 2) (OUT2, IN1, IN2) ;
//rise delay = 2, fall dalay = 1, trun-off delay = 1.3
bufif0 #(2, 1, 1.3) (OUT3, IN1, CTRL) ;
注意すべき点として、多入力ゲート(ANDゲートなど)と多出力ゲート(NOTゲートなど)は、出力が z になることがないため、最大でも2つの遅延しか定義できません。
三態ゲートと一方向スイッチ単路(MOS トランジスタ、CMOS トランジスタなど)は、3 つの遅延を定義できます。
プルアップ/プルダウンのゲートレベル回路には遅延がありません。それはハードウェアの属性を表すものであり、プルアップ/プルダウンの状態は変化せず、出力値もないためです。
双方向スイッチ(tran)は信号伝送時に遅延がなく、遅延定義の追加は許可されていません。
制御端を持つ双方向スイッチ(tranif1, tranif0)は、スイッチ切り替え時にオンまたはオフの遅延が発生するため、この種の双方向スイッチには 0 個、1 個、または 2 個の遅延を指定できます。例:
例
tranif0 #(1) (inout1, inout2, CTRL);
//turn-on delay = 1, turn-off delay = 1.2
tranif1 #(1, 1.2) (inout3, inout4, CTRL);
最小/典型/最大遅延
集積回路の製造プロセスの差異により、実際の回路におけるデバイスの遅延は常に一定の範囲内で変動します。Verilog では、ユーザーは3種類のゲート遅延を指定できるだけでなく、各タイプのゲート遅延に対して最小値、典型値、最大値を指定できます。コンパイルまたはシミュレーション段階でどの遅延値を使用するかを選択でき、より実際に即したシミュレーションをサポートします。
- 最小値:ゲートセルが持つ最小の遅延。
- 典型値:ゲートセルが持つ典型遅延。
- 最大値:ゲートセルが持つ最大の遅延。
次に、インスタンス化の例を通じて、最小、典型、最大遅延の使い方を説明します。
例
and #(1:2:3) (OUT1, IN1, IN2) ;
//立ち上がり遅延:最小遅延 1, 典型遅延 2, 最大遅延 3
//立ち下がり遅延:最小遅延 3, 典型遅延 4, 最大遅延 5
//ターンオフ遅延:最小遅延 min(1,3), 典型遅延 min(2,4), 最大遅延 min(3,5)
or #(1:2:3, 3:4:5) (OUT2, IN1, IN2) ;
//立ち上がり遅延:最小遅延 1, 典型遅延 2, 最大遅延 3
//立ち下がり遅延:最小遅延 3, 典型遅延 4, 最大遅延 5
//ターンオフ遅延:最小遅延 2, 典型遅延 3, 最大遅延 4
bufif0 #(1:2:3, 3:4:5, 2:3:4) (OUT3, IN1, CTRL) ;
D フリップフロップ
次に、ゲートレベルモデリングの観点から D フリップフロップを設計します。
SR フリップフロップ
SR フリップフロップの構造図と真理値表は次のとおりです。
- 1、S がローレベルのとき、G1 の出力 Q はハイレベルになり、G2 の入力にフィードバックされます。このとき R がハイレベルであれば、G2 の出力 Q' はローレベルになります。
- 2、R がローレベルで S がハイレベルの場合も、同様に解析できます。
- 3、S と R がともにハイレベルのとき、Q = 1 (Q' = 0) であれば、Q が G2 の入力にフィードバックされた後も出力 Q' は 0 のままで、Q' が G1 の入力にフィードバックされた後も出力 Q は 1 のままであり、安定状態となります。Q = 0 (Q' = 1) の場合も同様に、Q と Q' の値は維持されます。つまり、S と R がともにハイレベルのとき、この回路は保持機能を持ちます。
- 4、S と R がともにローレベルの場合、出力 Q と Q' はともにハイレベルになり、もはや相補の関係ではなくなります。したがって、この状態は禁止されています。


SR ラッチ
基本的な SR フリップフロップの前に 2 つの NAND ゲートを追加すると、制御端付き SR ラッチを構成できます。
SR ラッチとその真理値表は次のとおりです。
- EN=0 のとき、G3、G4 はオフになり、SR ラッチは出力状態を保持します。
- EN=1 のときは、基本的な SR フリップフロップと動作原理はまったく同じです。


D ラッチ
基本的な SR フリップフロップの入力は同時に 0 にできず、制御端付き SR ラッチの入力は同時に 1 にできません。そうでないと、出力 Q と Q' の非相補的な矛盾が生じます。
この許されない状態を排除するため、制御端付き SR ラッチの構造に反転モジュールを追加し、2 つの入力が常に逆の論理になるようにしたものが D ラッチです。
その構造図と真理値表は次のとおりです。
- 1、EN=1 のとき、出力状態は入力状態の変化に応じて変化します。
- 2、EN=0 のとき、出力状態は保持されます。


D ラッチはレベルトリガです。
EN=1 の有効期間中に D 端の信号が複数回反転すると、出力 Q も複数回反転します。これにより回路の耐ノイズ性が低下し、実際に求められる安全な回路とはいえません。
フリップフロップの信頼性を高め、回路の耐ノイズ性を強化するために、特定のタイミングで信号をラッチする D フリップフロップが考案されました。
D フリップフロップ
2 つの D ラッチを縦続接続し、クロックを反転させると、簡単な D フリップフロップが構成されます。これはフリップフロップ(Flip-flop)とも呼ばれます。
その構造図と真理値表は次のとおりです。
第1段の D ラッチはマスターラッチとも呼ばれ、CP がローレベルのときにラッチします。第2段の D ラッチはスレーブラッチとも呼ばれ、マスターラッチとは逆のクロックで動作し、CP がハイレベルのときにラッチします。


- 1、CP=1 のとき、マスターラッチの出力 Qm は D 端の信号の変化に追従しますが、スレーブラッチは保持状態にあり、出力 Qs は変化しません。
- 2、CP がハイレベルからローレベルに変化すると、マスターラッチは現在の D の状態をラッチし、出力 Qm に伝えて保持します。一方、スレーブラッチの出力 Qs は Qm の変化に追従します。このとき、ラッチ状態にあるマスターラッチの出力 Qm は一定に保たれるため、D フリップフロップの出力 Qs は新しい Qm の値を受け取った後も一定に保たれます。
以上のことから、D フリップフロップの出力 Qs は、クロック CP の立ち下がりエッジでのみ D 端の信号をラッチし、それ以外の時間は出力信号を保持する機能を持ちます。
2段の D ラッチをゲートレベル構造に展開すると、次の図のようになります。

D フリップフロップをゲートレベルでモデリングし、ゲートレベル遅延を追加した Verilog モデルは次のとおりです。
例
input D, CP,
output Q, QR);
parameter RISE_TIME = 0.11 ;
parameter FALL_TIME = 0.07 ;
//part1, not gate
wire CPN, DN ;
not #(RISE_TIME, FALL_TIME) (CPN, CP);
not #(RISE_TIME, FALL_TIME) (DN, D);
//part2, master trigger
wire G3O, G4O ;
nand #(RISE_TIME, FALL_TIME) (G3O, D, CP);
nand #(RISE_TIME, FALL_TIME) (G4O, DN, CP);
wire #(RISE_TIME, FALL_TIME) G1O, G2O ;
nand #(RISE_TIME, FALL_TIME) (G1O, G3O, G2O);
nand #(RISE_TIME, FALL_TIME) (G2O, G4O, G1O);
//part3, slave trigger
wire G7O, G8O ;
nand #(RISE_TIME, FALL_TIME) (G7O, G1O, CPN);
nand #(RISE_TIME, FALL_TIME) (G8O, G2O, CPN);
wire G5O, G6O ;
nand #(RISE_TIME, FALL_TIME) (G5O, G7O, G6O);
nand #(RISE_TIME, FALL_TIME) (G6O, G8O, G5O);
assign Q = G5O ;
assign QR = G6O ;
endmodule
testbench は次のように記述します。
例
module test ;
reg D, CP = 0 ;
wire Q, QR ;
always #5 CP = ~CP ;
initial begin
D = 0 ;
#12 D = 1 ;
#10 D = 0 ;
#14 D = 1 ;
#3 D = 0 ;
#18 D = 0 ;
end
D_TRI u_d_trigger(
.D (D),
.CP (CP),
.Q (Q),
.QR (QR));
initial begin
forever begin
#100;
//$display("---gyc---%d", $time);
if ($time >= 1000) begin
$finish ;
end
end
end
endmodule // test
シミュレーション結果は次のとおりです。
図から分かるように、Q/QR信号はともにクロックCPの立ち下がりエッジでD端の信号を取り込み、単一周期内で保持され、出力には遅延があります。

cap3時点を拡大し、遅延を追跡します。下図のとおりです。
- CP端からCPN端への立ち上がり遅延は、時間は110psです。
- CPN端からG8O端への立ち下がり遅延は、時間は70psです。
- G8O端からG6O端への立ち上がり遅延は、時間は110psです。
- G6O端からQ端への立ち下がり遅延は、時間は70psです。
- 合計360psであり、設定されたゲート遅延に一致します。

本章のソースコードダウンロード
Download