キーワード:偶数分周,奇数分周,半整数分周,小数分周

Verilog を学び始めた頃は、多くのモジュールはカウンタと分周器で構成されています。例えば、PWM パルス幅変調、周波数カウンタなどです。分周ロジックもまた、カウントロジックによって実現されることがよくあります。この節では主に、偶数分周、奇数分周、半整数分周、および小数分周について簡単にまとめます。

偶数分周

フリップフロップの反転出力を入力に接続する方式を用いると、簡単な 2 分周回路を構成できます。

これを基礎としてカスケード接続することで、4 分周、8 分周回路を構成できます。

回路の実装は下図のようになります。Verilog で記述する場合は、簡単な反転ロジックを使用するだけで済みます。

偶数分周の係数が大きすぎる場合は、分周係数 N を巡回カウントして分周を行う必要があります。カウント値が分周係数の中央値 N/2 に達したときにクロックを反転させると、分周後のクロックのデューティ比を 50% に保証できます。偶数分周であるため、分周係数の中央値 N/2 を巡回カウントすることもできます。

偶数分周の Verilog 記述例を以下に示します。

例

module even_divisor
  # (parameter DIV_CLK = 10 )
    (
    input               rstn ,
    input               clk,
    output              clk_div2,
    output              clk_div4,
    output              clk_div10
    );

   //2 分周
   reg                  clk_div2_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         clk_div2_r     <= 'b0 ;
      end
      else begin
         clk_div2_r     <= ~clk_div2_r ;
      end
   end
   assign       clk_div2 = clk_div2_r ;

   //4 分周
   reg                  clk_div4_r ;
   always @(posedge clk_div2 or negedge rstn) begin
      if (!rstn) begin
         clk_div4_r     <= 'b0 ;
      end
      else begin
         clk_div4_r     <= ~clk_div4_r ;
      end
   end
   assign clk_div4      = clk_div4_r ;

   //N/2 カウント
   reg [3:0]            cnt ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         cnt    <= 'b0 ;
      end
      else if (cnt == (DIV_CLK/2)-1) begin
         cnt    <= 'b0 ;
      end
      else begin
         cnt    <= cnt + 1'b1 ;
      end
   end

   //出力クロック
   reg                  clk_div10_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         clk_div10_r <= 1'b0 ;
      end
      else if (cnt == (DIV_CLK/2)-1 ) begin
         clk_div10_r <= ~clk_div10_r ;
      end
   end
   assign clk_div10 = clk_div10_r ;
endmodule

testbench では、入力クロックなどの信号を与えるだけでよいので、ここでは省略します。

シミュレーション結果は以下のとおりです。

奇数分周

奇数分周でデューティ比 50% が要求されない場合は、偶数分周の方法に従って分周できます。すなわち、カウンタが分周係数 N を巡回計算し、そのカウント値に応じて一定のデューティ比を選択して分周クロックを出力します。

奇数分周の出力クロックにおいて、ハイレベルとローレベルの差が 1 サイクルだけの場合、ソースクロックの両エッジ特性を利用し、「AND 演算」または「OR 演算」を用いて分周クロックのデューティ比を 50% に調整できます。

OR 演算によるデューティ比の調整

「OR 演算」を用いてデューティ比 50% の 3 分周を生成するタイミング図を以下に示します。

ソースクロックの立ち上がりエッジを利用して、ハイレベルが 1 サイクル、ローレベルが 2 サイクルの 3 分周クロックを分周生成します。

ソースクロックの立ち下がりエッジを利用して、ハイレベルが 1 サイクル、ローレベルが 2 サイクルの 3 分周クロックを分周生成します。

2 つの 3 分周クロックは、カウンタの同じ値かつ異なるエッジで生成され、位相差はクロックの半周期です。その後、2 つのクロックに対して「OR 演算」を行うと、デューティ比 50% の 3 分周クロックを得ることができます。

同様に、9 分周の場合、立ち上がりエッジと立ち下がりエッジでそれぞれハイレベルが 4 サイクル、ローレベルが 5 サイクルの 9 分周クロックを生成し、その後 2 つのクロックに対して「OR 演算」を行えばよいです。Verilog 記述は以下のとおりです。

例

module odo_div_or
  #(parameter DIV_CLK = 9)
   (
    input               rstn ,
    input               clk,
    output              clk_div9
    );

   //カウンタ
   reg [3:0]            cnt ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         cnt    <= 'b0 ;
      end
      else if (cnt == DIV_CLK-1) begin
         cnt    <= 'b0 ;
      end
      else begin
         cnt    <= cnt + 1'b1 ;
      end
   end

   //立ち上がりエッジで9分周を生成
   reg                  clkp_div9_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         clkp_div9_r <= 1'b0 ;
      end
      else if (cnt == (DIV_CLK>>1)-1 ) begin //カウント4-8はローレベル
        clkp_div9_r <= 0 ;
      end
      else if (cnt == DIV_CLK-1) begin //カウント0-3はハイレベル
        clkp_div9_r <= 1 ;
      end
   end
 
   //立ち下がりエッジで9分周を生成
   reg                  clkn_div9_r ;
   always @(negedge clk or negedge rstn) begin
      if (!rstn) begin
         clkn_div9_r <= 1'b0 ;
      end
      else if (cnt == (DIV_CLK>>1)-1 ) begin
        clkn_div9_r <= 0 ;
      end
      else if (cnt == DIV_CLK-1) begin
        clkn_div9_r <= 1 ;
      end
   end

   //OR演算、通常は基本論理セルライブラリを使用
   // or (clk_div9, clkp_div9_r, clkn_div9_r) ;
   assign clk_div9 = clkp_div9_r | clkn_div9_r ;

endmodule

シミュレーション結果は以下のとおりです。

AND 演算によるデューティ比の調整

「AND 演算」を用いてデューティ比 50% の 3 分周を生成するタイミング図を以下に示します。

ソースクロックの立ち上がりエッジを利用して、ハイレベルが 2 サイクル、ローレベルが 1 サイクルの 3 分周クロックを分周生成します。

ソースクロックの立ち下がりエッジを利用して、ハイレベルが 2 サイクル、ローレベルが 1 サイクルの 3 分周クロックを分周生成します。

2 つの 3 分周クロックは、カウンタの同じ値かつ異なるエッジで生成され、位相差はクロックの半周期です。その後、2 つのクロックに対して「AND 演算」を行うと、デューティ比 50% の 3 分周クロックが得られます。

同様に、9 分周の場合、立ち上がりエッジと立ち下がりエッジでそれぞれハイレベルが 5 サイクル、ローレベルが 4 サイクルの 9 分周クロックを生成し、その後 2 つのクロックに対して「AND 演算」を行えばよいです。Verilog 記述は以下のとおりです。

例

module odo_div_and
   #( parameter DIV_CLK = 9 )
   (
    input               rstn ,
    input               clk,
    output              clk_div9
    );

   //カウンタ
   reg [3:0]            cnt ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         cnt    <= 'b0 ;
      end
      else if (cnt == DIV_CLK-1) begin
         cnt    <= 'b0 ;
      end
      else begin
         cnt    <= cnt + 1'b1 ;
      end
   end

   //立ち上がりエッジで9分周を生成
   reg                  clkp_div9_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         clkp_div9_r <= 1'b0 ;
      end
      else if (cnt == (DIV_CLK>>1) ) begin //カウント5-8はローレベル
        clkp_div9_r <= 0 ;
      end
      else if (cnt == DIV_CLK-1) begin //カウント0-4はハイレベル
        clkp_div9_r <= 1 ;
      end
   end

   //立ち下がりエッジで9分周を生成
   reg                  clkn_div9_r ;
   always @(negedge clk or negedge rstn) begin
      if (!rstn) begin
         clkn_div9_r <= 1'b0 ;
      end
      else if (cnt == (DIV_CLK>>1) ) begin
        clkn_div9_r <= 0 ;
      end
      else if (cnt == DIV_CLK-1) begin
        clkn_div9_r <= 1 ;
      end
   end

   //AND演算、通常は基本論理セルライブラリを使用
   //and (clk_div9, clkp_div9_r, clkn_div9_r) ;
   assign clk_div9 = clkp_div9_r & clkn_div9_r ;

endmodule

シミュレーション結果は以下のとおりです。

半整数分周

クロックの両エッジロジックを利用すると、クロックを半整数に分周できます。ただし、どのように調整しても、半整数分周のデューティ比が 50% になることはありません。半整数分周の方法は多くありますが、ここでは奇数分周のデューティ比調整に類似した 1 つの方法のみを紹介します。

  • (1) 例えば 3.5 倍分周を行う場合、カウンタは 7 まで巡回カウントし、それぞれ 4 個と 3 個のソースクロック周期からなる 2 つの分周クロックを生成します。7 個のソースクロックから 2 つの分周クロックが生成されたという観点では、この処理は 3.5 倍分周を実現していますが、各分周クロックは厳密な 3.5 倍分周ではありません。
  • (2) 次に、周期が不均一な分周クロックを調整します。1 回の巡回カウント中に、ソースクロックの立ち下がりエッジで、それぞれ 4 個と 3 個のソースクロック周期からなる 2 つの分周クロックを生成します。最初に生成された 2 つの周期が不均一なクロックと比較して、今回生成された 2 つのクロックの位相は、一方がソースクロック半周期遅れ、他方がソースクロック半周期進みます。
  • (3) 2 回生成したクロックに対して「OR 演算」を行うと、周期が均一な 3.5 倍分周クロックが得られます。分周波形の概略図を以下に示します。

3.5 倍クロック分周の Verilog 記述は以下のとおりです。

例

module half_divisor(
    input               rstn ,
    input               clk,
    output              clk_div3p5
    );

   //カウンタ
   parameter            MUL2_DIV_CLK = 7 ;
   reg [3:0]            cnt ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         cnt    <= 'b0 ;
      end
      else if (cnt == MUL2_DIV_CLK-1) begin //2倍分周比をカウント
         cnt    <= 'b0 ;
      end
      else begin
         cnt    <= cnt + 1'b1 ;
      end
   end

   reg                  clk_ave_r ;
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         clk_ave_r <= 1'b0 ;
      end
      //first cycle: 4 source clk cycle
      else if (cnt == 0) begin
         clk_ave_r <= 1 ;
      end
      //2nd cycle: 3 source clk cycle
      else if (cnt == (MUL2_DIV_CLK/2)+1) begin
         clk_ave_r <= 1 ;
      end
      else begin
         clk_ave_r <= 0 ;
      end
   end

   //adjust
   reg                  clk_adjust_r ;
   always @(negedge clk or negedge rstn) begin
      if (!rstn) begin
         clk_adjust_r <= 1'b0 ;
      end
      //今回のクロックはデューティ比を一致させるためだけのもの
      else if (cnt == 1) begin
         clk_adjust_r <= 1 ;
      end
      //今回のクロックは正確な分周比を一致させるためだけのもの
      else if (cnt == (MUL2_DIV_CLK/2)+1 ) begin
         clk_adjust_r <= 1 ;
      end
      else begin
         clk_adjust_r <= 0 ;
      end
   end

   assign clk_div3p5 = clk_adjust_r | clk_ave_r ;

endmodule

シミュレーション結果は以下のとおりです。

小数分周

基本原理

不規則な小数分周では、分周後の各クロック周期をソースクロック周期の小数分周倍にすることはできません。また、分周後のクロックのデューティ比をすべて 50% にすることもできません。Verilog はクロックを小数でカウントできないためです。半整数分周で最初の分周時に導入した「平均周波数」の概念と同様に、小数分周も可変分周と複数回の平均化に基づく方法で実現されます。

例えば 7.6 倍分周を行う場合、ソースクロック 76 周期の時間が分周クロック 10 周期の時間と等しくなるようにすればよいです。このとき、76 個のソースクロック周期内で 8 分周を 6 回、7 分周を 4 回行う必要があります。別の例として、5.76 倍分周を行う場合、576 個のソースクロック周期内で 6 分周を 76 回、5 分周を 24 回行う必要があります。

以下で、これらの分周パラメータの計算過程について説明します。

7 分周を行う場合、70 個のソースクロック周期内で 10 回の 7 分周を行うと解釈できます。76 個のソースクロック周期内でも 10 回の分周を行う場合、余分な 6 個のソースクロック周期を 70 個のソースクロック周期内に追加・配分することに相当し、これで 7.6 倍分周が完了します。分周処理中、必然的に 6 つの分周クロックは 8 分周で得られ、残りの 4 つの分周クロックは元の 7 分周の状態を維持します。

多くの資料では、これらの分周パラメータを計算するための二元一次連立方程式が示されています。以下を参照してください。その原理は上記の分析と同じであり、上記の計算過程を身につけることをお勧めします。

7N + 8M = 76
N  + M   = 10 

ここで、7 は整数分周、N は整数分周の回数です。8 と M は、整数分周に 1 を加えた後の分周係数とその分周回数です。

平均化の原理

7.6 倍分周を例にすると、7 分周と 8 分周の実装順序は一般に次の 4 通りがあります:

  • (1) 最初に 4 回の 7 分周を行い、次に 6 回の 8 分周を行います;
  • (2) 最初に 6 回の 8 分周を行い、次に 4 回の 7 分周を行います;
  • (3) 4 回の 7 分周を 6 回の 8 分周の中に均等に挿入します;
  • (4) 6 回の 8 分周を 4 回の 7 分周の中に均等に挿入します。

最初の 2 つの方法ではクロック周波数が不均一で、位相ジッタが大きいため、一般的には後者の 2 つの平均挿入方法を用いて小数分周を行います。

平均挿入は、分周回数の差を累積する方法で実現できます。7.6 分周の実装手順は以下のとおりです:

  • (1) 1 回目の分周差分は 76-10*7 = 6 < 10 なので、1 回目は 7 分周を行います。
  • (2) 2 回目の差分累積結果は 6+6=12 > 10 なので、2 回目は 8 分周を使用し、同時に差分を 12-10=2 に変更します。
  • (3) 3 回目の差分累積結果は 2+6=8 < 10 なので、3 回目は 7 分周を使用します。
  • (4) 4 回目の差分累積結果は 8+6=14 > 10 なので、4 回目は 8 分周を使用し、差分を 14-10=4 に変更します。

同様に、6回の8分周を4回の7分周に平均的に挿入するプロセスを完了します。

以下の表は、平均挿入法の分周プロセスを示しています。

分周回数差値累積差値修正分周周期
1667
26+6=1228
32+6=887
48+6=1448
54+6=1008
6667
76+6=1228
82+6=887
98+6=1448
104+6=1008

設計シミュレーション

上記の小数分周実装方法に基づくVerilog記述は以下のとおりです。

例

module frac_divisor
  #(
   parameter            SOURCE_NUM = 76 , //cycles in source clock
   parameter            DEST_NUM   = 10  //cycles in destination clock
   )
   (
    input               rstn ,
    input               clk,
    output              clk_frac
    );
 
   //7分周パラメータ、8分周パラメータ、回数差値
   parameter    SOURCE_DIV = SOURCE_NUM/DEST_NUM ;
   parameter    DEST_DIV   = SOURCE_DIV + 1;
   parameter    DIFF_ACC   = SOURCE_NUM - SOURCE_DIV*DEST_NUM ;


   reg [3:0]            cnt_end_r ;  //可変分周周期
   reg [3:0]            main_cnt ;   //メインカウンタ
   reg                  clk_frac_r ; //クロック出力、ハイレベル周期数は1
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         main_cnt    <= 'b0 ;
         clk_frac_r  <= 1'b0 ;
      end
      else if (main_cnt == cnt_end_r) begin
         main_cnt    <= 'b0 ;
         clk_frac_r  <= 1'b1 ;
      end
      else begin
         main_cnt    <= main_cnt + 1'b1 ;
         clk_frac_r  <= 1'b0 ;
      end
   end
   //出力クロック
   assign       clk_frac        = clk_frac_r ;
   //差値累積器イネーブル制御
   wire         diff_cnt_en     = main_cnt == cnt_end_r ;

   //差値累積器ロジック
   reg [4:0]            diff_cnt_r ;
   wire [4:0]           diff_cnt = diff_cnt_r >= DEST_NUM ?
                                   diff_cnt_r -10 + DIFF_ACC :
                                   diff_cnt_r + DIFF_ACC ;                                
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         diff_cnt_r <= 0 ;
      end
      else if (diff_cnt_en) begin
         diff_cnt_r <= diff_cnt ;
      end
   end

   //分周周期変数の制御ロジック
   always @(posedge clk or negedge rstn) begin
      if (!rstn) begin
         cnt_end_r      <= SOURCE_DIV-1 ;
      end
      //差値累積器がオーバーフローしたとき、分周周期を修正
      else if (diff_cnt >= 10) begin
         cnt_end_r      <= DEST_DIV-1 ;
      end
      else begin
         cnt_end_r      <= SOURCE_DIV-1 ;
      end
   end

endmodule

シミュレーション結果は以下のとおりです。

分周のまとめ

偶数分周は、クロックの両エッジロジックを使用せずにデューティ比50%のクロック分周を実現でき、最も理想的な分周状況です。

奇数分周でデューティ比50%の分周クロックを生成する場合は、クロックの両エッジロジックを使用する必要があります。デューティ比が要求されない場合は、実装方法は偶数分周と類似しています。

半整数分周は特別な小数分周であり、両エッジロジックを使用して設計できます。一定のロジックによって2つの両エッジクロック信号を最終的な1系統の出力クロックに統合する場合、選択ロジックを使用しないことをお勧めします。グリッチ現象が発生しやすく、回路に一定の不確実性が増すためです。例えば、以下の記述は推奨されません。

assign clk_div3p5 = (cnt == 1 || cnt ==2) ? clk_ave_r
                                          : clk_adjust_r ;

小数分周の基本思想は、出力クロックが一定期間内の平均周波数で分周要件を満たせばよいというものです。ただし、位相ジッタを考慮すると、分周係数が変化する分周ロジックに対して平均化操作を行う必要もあります。

本章のソースコードダウンロード

Download