信号が高速クロックドメインから低速クロックドメインへ伝送されてくる場合、信号の特性に応じて同期処理を行う必要があります。単一ビット信号については、一般にレベル信号とパルス信号に区別できます。

レベル信号同期

同期論理設計において、レベル信号とは長時間変化しない状態を維持する信号を指します。変化しない時間の制限は、低速クロックに対する相対的なものです。高速クロックの信号がハイレベルまたはローレベルを維持する時間が十分に長く、低速クロックがタイミング制約を満たす条件で取得できる限り、その信号はレベル信号とみなすことができます。

レベル信号は安全に取得できるため、高速クロックドメインから低速クロックドメインへのレベル信号も遅延フリップフロップ方式で同期を取ります。

パルス信号同期

同期論理設計において、パルス信号とは高速クロックドメインから出力される有効幅が低速クロックの周期より小さい信号を指します。低速クロックドメインがこのような狭いパルス信号を直接取得しようとすると、取りこぼす可能性があります。

このようなパルス信号のパルス幅がすべて同じであり、2つのクロック周波数の比率が分かっている場合、「高速クロックドメインでのパルス幅拡張+低速クロックドメインでの遅延フリップフロップ」方式で同期を取ることができます。

一方で狭いパルス信号がレベル信号の特性を示す場合、つまり信号の有効幅が低速クロックの周期より大きくて低速クロックが取得できる場合があります。そのような信号に対してパルス拡張を行うのは明らかに非効率的です。この場合は、「ハンドシェイク伝送」方式で同期を取ることができます。

パルス信号のハイレベル期間を有効信号期間と仮定すると、その基本原理は以下のとおりです。

  • (1) 高速クロックドメインはパルス信号を検出し、ハイレベルを検出したらハイレベル信号 pulse_fast_r を出力します。または、高速クロックドメインがハイレベル信号を出力するとき、すぐに信号をローレベルに引き下げず、まず出力信号のハイレベル状態を維持します。
  • (2) 低速クロックドメインは高速クロックドメインの信号 pulse_fast_r を遅延フリップフロップでサンプリングします。このときパルス信号は高速クロックドメインによってハイレベル状態に保持されているため、遅延フリップフロップで確実にその信号を取得できます。
  • (3) 低速クロックドメインはハイレベル信号 pulse_fast2s_r の取得を確認したら、それを高速クロックドメインにフィードバックします。
  • (4) 高速クロックドメインはフィードバック信号 pulse_fast2s_r を遅延フリップフロップでサンプリングします。フィードバック信号がハイレベルであることを検出できれば、低速クロックドメインが有効なハイレベル信号を受信したことを証明します。このとき高速クロックドメイン自身の論理がパルス信号のハイレベル状態を要求しなくなっていれば、高速クロックドメインのパルス信号をローレベルに引き下げます。

この方法の本質は、相互にハンドシェイクすることで狭いパルス信号のパルス幅を拡張することです。

ハンドシェイク信号を使用した同期処理の Verilog モデルの記述は以下のとおりです。

例

//同期モジュールの動作クロックが約 25MHz のモジュール
//非同期データは動作クロックが 100MHz のモジュールからのもの
module pulse_syn_fast2s
  #( parameter          PULSE_INIT = 1'b0
   )
  (
   input                rstn,
   input                clk_fast,
   input                pulse_fast,
   input                clk_slow,
   output               pulse_slow);

   wire                 clear_n ;
   reg                  pulse_fast_r ;
   /**************** fast clk ***************/
   //(1) 高速クロックドメインがパルス信号を検出したとき、すぐにパルス信号をローレベルに引き下げない
   always@(posedge clk_fast or negedge rstn) begin
        if (!rstn)
           pulse_fast_r  <= PULSE_INIT ;
        else if (!clear_n)
           pulse_fast_r  <= 1'b0 ;
        else if (pulse_fast)
           pulse_fast_r  <= 1'b1 ;
   end

   reg  [1:0]           pulse_fast2s_r ;
   /************ slow clk *************/
   //(2) 低速クロックドメインが信号を遅延フリップフロップでサンプリングする
   always@(posedge clk_slow or negedge rstn) begin
      if (!rstn)
        pulse_fast2s_r     <= 3'b0 ;
      else
        pulse_fast2s_r     <= {pulse_fast2s_r[0], pulse_fast_r} ;
   end
   assign pulse_slow = pulse_fast2s_r[1] ;

   reg [1:0]            pulse_slow2f_r ;
   /********* feedback for slow clk to fast clk *******/
   //(3) フィードバック信号を遅延フリップフロップでサンプリングする
   always@(posedge clk_fast or negedge rstn) begin
      if (!rstn)
        pulse_slow2f_r  <= 1'b0 ;
      else
        pulse_slow2f_r  <= {pulse_slow2f_r[0], pulse_slow} ;
   end
   //高速クロックドメインのパルス信号をローレベルに引き下げる制御
   assign clear_n = ~(!pulse_fast && pulse_slow2f_r[1]) ;


endmodule

testbench の記述は以下のとおりです。

例

`timescale 1ns/1ps

module test ;
   reg          clk_100mhz, clk_25mhz ;
   reg          rstn ;

   initial begin
      clk_100mhz = 0 ;
      clk_25mhz  = 0 ;
      rstn = 0 ;
      #11 rstn = 1 ;
   end
   always #(10/2)   clk_100mhz  = ~clk_100mhz ;
   always #(45/2)   clk_25mhz   = ~clk_25mhz ;

   reg [7:0]            cnt ;
   reg                  pulse_sig ;
   always @(posedge clk_100mhz or negedge rstn) begin
      if (!rstn) begin
         cnt     <= 'b0 ;
      end
      else begin
         cnt    <= cnt + 1'b1 ;
      end
   end

   //狭いパルス生成部分
   always @(posedge clk_100mhz or negedge rstn) begin
      if (!rstn) begin
         pulse_sig      <= 1'b0 ;
      end
      else if (cnt == 5 ||
               cnt == 40 || cnt == 42 ||
               cnt >= 75 && cnt <= 81 || cnt == 85 || cnt == 87 )
      begin
         pulse_sig      <= 1'b1 ;
      end
      else begin
         pulse_sig      <= 1'b0 ;
      end
   end

   pulse_syn_fast2s u_fast2s_pulse(
      .rstn             (rstn),
      .clk_fast         (clk_100mhz),
      .pulse_fast       (pulse_sig),
      .clk_slow         (clk_25mhz),
      .pulse_slow       ());

   initial begin
      forever begin
         #100;
         if ($time >= 10000)  $finish ;
      end
   end

endmodule // test

シミュレーション結果は以下のとおりです。図から分かることは次のとおりです。

  • (1) 高速クロックドメインの単一の狭いパルス信号は低速クロックドメインによって取得されますが、同期後の信号は遅延が長く、パルス幅が大きくなります。信号遅延は遅延フリップフロップとフィードバッククリアによるものであり、回避できません。パルス幅が大きくなる問題は、遅延フリップフロップによるエッジ検出方式で処理できます。
  • (2) 隣接する2つの狭いパルス信号を同期させた後のパルス幅は、単一の狭いパルスを同期させた後のパルス幅と変わりません。つまり、同期回路は2つ目の狭いパルスの検出を取りこぼします。これもハンドシェイク伝送で同期問題を処理する際の特徴であり、高速クロックドメインのパルス信号の変化速度が速すぎる場合、この方法では隣接するパルスを識別できません。
  • (3) 複数の幅の異なるパルス信号が互いに近接している場合、この同期方法では複数のパルス信号を識別できませんが、同期後の信号のパルス幅は比較的大きくなる可能性があります。

多ビット幅データの同期

多ビット幅のデータを同期する場合、そのデータの各ビットをレベル信号とみなせる、つまり一定期間内に各ビットのデータが変化せず低速クロックが取得できるのであれば、いくつかのフリップフロップリソースを消費して多ビット幅のデータを単純な遅延フリップフロップで同期させることができます。

しかし、データの変化速度が速すぎる場合は、遅延フリップフロップによるサンプリング方式は使用できません。このときデータの各ビットはもはやレベル信号ではなく、変化するタイミングもばらつきがあり、非同期クロックでフリップフロップによるサンプリングを行うと、パス遅延の違いによって生じる誤ったデータを取得する可能性があります。

この種の非同期問題を解決する一般的な方法は、非同期 FIFO (First In First Out) を使用することです。詳細は次の節を参照してください。『4.4 FIFO 設計』。

本章のソースコードダウンロード

Download