Cuando la señal se transmite desde el dominio de reloj rápido al dominio de reloj lento, debe sincronizarse de acuerdo con las características de la señal. Para señales de un solo bit, generalmente se pueden distinguir entre señales de nivel y señales de pulso.
Sincronización de señales de nivel
En el diseño de lógica síncrona, una señal de nivel se refiere a una señal que permanece sin cambios durante un largo período. El tiempo de permanencia se refiere al dominio de reloj lento. Siempre que el período de tiempo en que la señal de alta o baja del reloj rápido permanezca sea lo suficientemente largo como para que el reloj lento pueda muestrearla satisfaciendo las restricciones de tiempo, la señal puede considerarse una señal de nivel.
Dado que la señal de nivel puede ser muestreada de manera segura, la señal de nivel que va del dominio de reloj rápido al dominio de reloj lento también se sincroniza mediante el método de registro de retardo.
Sincronización de señales de pulso
En el diseño de lógica síncrona, una señal de pulso se refiere a una señal cuya anchura de pulso de salida desde el dominio de reloj rápido es menor que el período del reloj lento. Si el dominio de reloj lento muestrea directamente esta señal, es posible que se pierda.
Si las anchuras de dichas señales de pulso son consistentes y se conoce la relación de frecuencia entre los dos relojes, se puede adoptar el método de "expansión de pulso en el dominio de reloj rápido + registro de retardo en el dominio de reloj lento" para sincronizar.
Si algunas señales a veces se comportan como señales de pulso estrecho y a veces presentan características de señales de nivel, es decir, a veces el ancho efectivo es mayor que el período del reloj lento y puede ser muestreada por él, entonces realizar una expansión de pulso para tales señales es obviamente antieconómica. En este caso, se puede sincronizar mediante el método de "transferencia de apretón de manos".
Suponiendo que el período de nivel alto de la señal de pulso es el período de señal válido, el principio básico es el siguiente.
- (1) El dominio de reloj rápido detecta la señal de pulso; cuando detecta una señal de pulso de nivel alto, eleva la señal pulse_fast_r del dominio de reloj rápido. El dominio de reloj rápido detecta una señal de pulso de nivel alto, eleva pulse_fast_r del dominio de reloj rápido. Cuando el dominio de reloj rápido detecta una señal de pulso de nivel alto, eleva pulse_fast_r del dominio de reloj rápido.
- (2) El dominio de reloj lento muestrea con registro de retardo la señal pulse_fast_r del dominio de reloj rápido. Debido a que en ese momento pulse_fast_r se mantiene en nivel alto por el dominio de reloj rápido, el registro de retardo del dominio de reloj lento seguramente podrá muestrearla.
- (3) El dominio de reloj lento muestrea con registro de retardo la señal pulse_fast_r del dominio de reloj rápido; cuando el dominio de reloj lento muestrea la señal de nivel alto pulse_fast_r, envía la señal de retroalimentación al dominio de reloj rápido.
- (4) El dominio de reloj rápido muestrea con registro de retardo la señal de retroalimentación pulse_fast_r_sync. Si detecta que la señal de retroalimentación es de nivel alto, indica que el dominio de reloj lento ha recibido la señal válida. En este momento, si la lógica del dominio de reloj rápido ya no requiere que la señal de pulso esté en estado de nivel alto, puede reducir pulse_fast_r.
La esencia de este método es expandir la anchura de los pulsos estrechos mediante el apretón de manos mutuo. Utilizando señales de apretón de manos para la transmisión entre dominios de reloj, la señal muestreada por el dominio de reloj lento es la señal elevada.
El modelo Verilog que utiliza señales de apretón de manos para la transmisión entre dominios de reloj se describe a continuación.
Ejemplo
// Datos asíncronos provienen de un módulo con reloj de trabajo de 100 MHz
module pulse_syn_fast2s
#( parameter PULSE_INIT = 1'b0
)
(
input rstn,
input clk_fast,
input pulse_fast,
input clk_slow,
output pulse_slow);
wire clear_n ;
reg pulse_fast_r ;
/**************** fast clk ***************/
//(1) Cuando el dominio de reloj rápido detecta la señal de pulso, eleva la señal pulse_fast_r del dominio de reloj rápido; esta señal es una señal de nivel
always@(posedge clk_fast or negedge rstn) begin
if (!rstn)
pulse_fast_r <= PULSE_INIT ;
else if (!clear_n)
pulse_fast_r <= 1'b0 ;
else if (pulse_fast)
pulse_fast_r <= 1'b1 ;
end
reg [1:0] pulse_fast2s_r ;
/************ slow clk *************/
//(2) El dominio de reloj lento muestrea con registro de retardo la señal pulse_fast_r del dominio de reloj rápido
always@(posedge clk_slow or negedge rstn) begin
if (!rstn)
pulse_fast2s_r <= 3'b0 ;
else
pulse_fast2s_r <= {pulse_fast2s_r[0], pulse_fast_r} ;
end
assign pulse_slow = pulse_fast2s_r[1] ;
reg [1:0] pulse_slow2f_r ;
/********* feedback for slow clk to fast clk *******/
//(3) El dominio de reloj lento muestrea con registro de retardo la señal pulse_fast_r del dominio de reloj rápido; cuando muestrea la señal de nivel alto pulse_fast_r, envía la señal de retroalimentación al dominio de reloj rápido
always@(posedge clk_fast or negedge rstn) begin
if (!rstn)
pulse_slow2f_r <= 1'b0 ;
else
pulse_slow2f_r <= {pulse_slow2f_r[0], pulse_slow} ;
end
//(4) El dominio de reloj rápido muestrea con registro de retardo la señal de retroalimentación pulse_fast_r_sync. Si detecta que la retroalimentación es de nivel alto, indica que el dominio de reloj lento ha recibido la señal válida. En este momento, si la lógica del dominio de reloj rápido ya no requiere que la señal de pulso esté en nivel alto, puede reducir pulse_fast_r
assign clear_n = ~(!pulse_fast && pulse_slow2f_r[1]) ;
endmodule
// La descripción del testbench es la siguiente.
Ejemplo
module test ;
reg clk_100mhz, clk_25mhz ;
reg rstn ;
initial begin
clk_100mhz = 0 ;
clk_25mhz = 0 ;
rstn = 0 ;
#11 rstn = 1 ;
end
always #(10/2) clk_100mhz = ~clk_100mhz ;
always #(45/2) clk_25mhz = ~clk_25mhz ;
reg [7:0] cnt ;
reg pulse_sig ;
always @(posedge clk_100mhz or negedge rstn) begin
if (!rstn) begin
cnt <= 'b0 ;
end
else begin
cnt <= cnt + 1'b1 ;
end
end
// Parte de generación de pulsos estrechos
always @(posedge clk_100mhz or negedge rstn) begin
if (!rstn) begin
pulse_sig <= 1'b0 ;
end
else if (cnt == 5 ||
cnt == 40 || cnt == 42 ||
cnt >= 75 && cnt <= 81 || cnt == 85 || cnt == 87 )
begin
pulse_sig <= 1'b1 ;
end
else begin
pulse_sig <= 1'b0 ;
end
end
pulse_syn_fast2s u_fast2s_pulse(
.rstn (rstn),
.clk_fast (clk_100mhz),
.pulse_fast (pulse_sig),
.clk_slow (clk_25mhz),
.pulse_slow ());
initial begin
forever begin
#100;
if ($time >= 10000) $finish ;
end
end
endmodule // test
Los resultados de la simulación son los siguientes, como se puede ver en la figura:
- (1) Una sola señal de pulso estrecho del dominio de reloj rápido es muestreada por el dominio de reloj lento, pero la señal sincronizada tiene un retardo mayor. Esto se debe al registro de retardo y al borrado de retroalimentación, y no se puede eliminar. El problema del ancho de pulso ensanchado puede resolverse mediante el método de detección de flancos con registro de retardo.
- (2) El ancho de pulso de la señal sincronizada después de dos señales de pulso estrecho adyacentes es el mismo que el de una sola señal de pulso estrecho sincronizada; es decir, se pierde el segundo pulso estrecho. Esto se debe a que el método de sincronización por apretón de manos no es adecuado para sincronizar señales de pulso muy cercanas entre sí.
- (3) Cuando múltiples señales de pulso estrecho están muy cercanas entre sí, el método de sincronización por apretón de manos no puede garantizar el éxito de la sincronización, por lo que este método solo es adecuado para sincronizar señales de pulso relativamente separadas.

Sincronización de datos de múltiples bits
Cuando se sincronizan datos de múltiples bits, si cada bit de los datos es una señal de nivel, es decir, los datos permanecen sin cambios durante un período de tiempo y pueden ser muestreados por el reloj, se puede muestrear directamente con un registro de retardo en el dominio de reloj rápido, o también se puede adoptar el método de muestreo con registro de retardo en el dominio de reloj lento para datos de múltiples bits.
Pero si la velocidad de cambio de los datos es demasiado rápida, ya no se puede usar el método de registro de retardo. Porque en este momento cada bit de los datos ya no es una señal de nivel, los tiempos de cambio son irregulares, y si se usa el método de registrar primero y luego muestrear, se pueden muestrear datos incorrectos.
El método común para resolver este tipo de problemas asíncronos es usar FIFO asíncrono (First In First Out). Consulte la siguiente sección para más detalles:4.4 Diseño de FIFO。
Descarga del código fuente de este capítulo
Download