Ключевые слова: задержка, инерционная задержка

Задержка в операторе задержки непрерывного присваивания используется для управления временной задержкой от момента изменения любого операнда до момента присваивания нового значения левой части оператора.

Задержки, как правило, не синтезируемы.

Задержками регистров также можно управлять; это объясняется в разделе управления временем.

Задержки непрерывного присваивания обычно можно разделить на обычную задержку присваивания, неявную задержку и задержку объявления.

Следующие 3 примера функционально эквивалентны и соответствуют трём различным способам записи задержек непрерывного присваивания.

//Обычная задержка, результат A&B присваивается Z с задержкой 10 единиц времени
wire Z, A, B ;
assign #10    Z = A & B ;
 
//Неявная задержка: при объявлении переменной wire выполняется непрерывное присваивание ей с определённой задержкой.
wire A, B;
wire #10        Z = A & B;
 
//Задержка объявления: при объявлении переменной wire указывается задержка. Поэтому все непрерывные присваивания этой переменной будут отложены до указанного времени. За исключением моделирования на уровне вентилей, этот метод моделирования обычно не рекомендуется.
wire A, B;
wire #10 Z ;
assign           Z =A & B

Инерционная задержка

В приведенном выше примере, если A или B изменится, будет задержка в 10 единиц времени, прежде чем Z получит новое значение. Если в течение этих 10 единиц времени, то есть до того, как Z получит новое значение, A или B снова изменится, то текущее новое значение A или B будет использовано при вычислении нового значения Z. Поэтому это называется инерционной задержкой, означающей, что если ширина импульса сигнала меньше задержки, она не влияет на выход.

Поэтому при моделировании задержку нужно задавать разумно, чтобы предотвратить ситуацию, когда некоторые сигналы не могут быть эффективно задержаны.

Выполните моделирование задержки для логики элемента AND с задержкой.

Пример

module time_delay_module(
    input   ai, bi,
    output  so_lose, so_get, so_normal);
 
    assign #20      so_lose      = ai & bi ;
    assign  #5      so_get       = ai & bi ;
    assign          so_normal    = ai & bi ;
endmodule

Ссылка на тестовый стенд приведена ниже:

Пример

`timescale 1ns/1ns

module test ;
    reg  ai, bi ;
    wire so_lose, so_get, so_normal ;
 
    initial begin
        ai        = 0 ;
        #25 ;      ai        = 1 ;
        #35 ;      ai        = 0 ;        //60ns
        #40 ;      ai        = 1 ;        //100ns
        #10 ;      ai        = 0 ;        //110ns
    end
 
    initial begin
        bi        = 1 ;
        #70 ;      bi        = 0 ;
        #20 ;      bi        = 1 ;
    end
 
    time_delay_module u_wire_delay(
        .ai              (ai),
        .bi              (bi),
        .so_lose         (so_lose),
        .so_get          (so_get),
        .so_normal       (so_normal));
 
    initial begin
        forever begin
            #100;
            //$display("---gyc---%d", $time);
            if ($time >= 1000) begin
                $finish ;
            end
        end
    end
 
endmodule

Результаты моделирования следующие:

Сигнал so_normal — это обычная логика AND.

Поскольку все задержки больше 5ns, результат сигнала so_get — это операция AND, задержанная на 5ns.

Первая часть сигнала so_lose — это результат операции AND, задержанный на 20ns.

Поскольку длительность второго высокого уровня сигнала ai меньше 20ns, сигнал so_lose пропустит обнаружение задержки этого импульса из-за инерционной задержки, поэтому последующая часть сигнала so_lose по-прежнему равна 0.

Скачать исходный код

Скачать