Ключевые слова: module, port, bidirectional port, PAD

Структурное моделирование имеет 3 типа операторов описания: операторы инстанцирования вентилей (вентильного уровня), операторы инстанцирования UDP (User Defined Primitive) и операторы инстанцирования модулей. В этом разделе в основном рассматриваются наиболее широко используемые операторы инстанцирования на уровне модулей.

Модуль

Модуль — это форма определения базовой единицы в Verilog, а также интерфейс для взаимодействия с внешним миром.

Формат модуля определяется следующим образом:

module module_name 
#(parameter_list)
(port_list) ;
              Declarations_and_Statements ;
endmodule

Определение модуля должно начинаться с ключевого слова `module` и заканчиваться ключевым словом `endmodule`.

Имя модуля, сигналы портов, объявления портов и необязательные объявления параметров и т. д. указываются перед операторами Verilog, используемыми в проекте (Declarations_and_Statements на рисунке).

Внутри модуля есть 5 необязательных частей: объявления переменных, операторы потока данных, операторы поведенческого уровня, инстанцирования низкоуровневых модулей, а также задачи и функции, как показано на рисунке ниже. Порядок и расположение этих 5 частей произвольны. Однако все переменные должны быть объявлены до использования. Конкретное место объявления переменных не требуется, но они должны быть размещены перед использованием.

Большая часть кода моделирования, приведённого ранее, использует объявления модулей; вы можете обратиться к нему самостоятельно. Мы не будем приводить конкретные примеры здесь. Когда ниже будут представлены порты, мы выполним подробное моделирование.

Порт

Порт — это интерфейс для взаимодействия модуля с внешним миром. Для внешней среды внутренняя часть модуля невидима, и вызовы модуля могут выполняться только через подключения портов.

Список портов

Определение модуля содержит необязательный список портов, в котором обычно перечисляются сигнальные переменные без типа и без разрядности в объявлении модуля. Ниже приведён список портов для модели PAD:

module pad(
    DIN, OEN, PULL,
    DOUT, PAD);

Если модуль не взаимодействует с внешней средой, ему не нужно объявлять список портов. Например, в наших предыдущих моделях тестовый модуль в файле test.sv не объявлял конкретные порты.

module test ;  //直接分号结束
    ......     //数据流或行为级描述
endmodule

Объявление портов

(1) После того как сигналы портов перечислены в списке портов, их можно объявить в теле модуля.

В соответствии с направлением порта существует 3 типа портов: input, output и двунаправленный порт (inout).

Типы input и inout нельзя объявлять как тип данных reg, потому что тип reg используется для хранения значений, тогда как входные порты могут только отражать изменения внешних сигналов, подключённых к ним, и не могут хранить значения этих сигналов.

output можно объявлять как тип данных wire или reg.

Объявление портов модуля pad из приведённого выше примера можно выразить в теле модуля следующим образом:

Пример

// объявление типа порта
input        DIN, OEN ;
input [1:0]  PULL ;  //(00,01-отключить подтяжку, 11-подтяжка к питанию, 10-подтяжка к земле)
inout        PAD ;   //значение PAD
output       DOUT ;  //загрузка PAD, когда PAD настроен как вход

// объявление типа данных порта
wire         DIN, OEN ;
wire  [1:0]  PULL ;
wire         PAD ;
reg          DOUT ;

(2) В Verilog порты неявно объявляются как переменные типа wire. То есть, если порт имеет атрибут wire, нет необходимости снова объявлять тип порта как wire. Однако, если порт имеет атрибут reg, объявление reg нельзя опускать.

Объявление порта в приведённом выше примере можно упростить следующим образом:

Пример

// объявление типа порта
input        DIN, OEN ;
input [1:0]  PULL ;    
inout        PAD ;    
output       DOUT ;    
reg          DOUT ;

(3) Конечно, объявление сигнала DOUT можно объединить в один оператор:

output reg      DOUT ;

(4) Существует также более краткий и часто используемый способ объявления портов, а именно: перечислить порты и их типы в объявлении модуля. Порты типа reg должны быть объявлены либо в объявлении модуля, либо в теле модуля. Например, следующие два стиля записи эквивалентны.

Пример

module pad(
    input        DIN, OEN ,
    input [1:0]  PULL ,
    inout        PAD ,
    output reg   DOUT
    );
 
module pad(
    input        DIN, OEN ,
    input [1:0]  PULL ,
    inout        PAD ,
    output       DOUT
    );
 
    reg        DOUT ;

Моделирование порта inout

Смоделируйте модель pad, включающую тип порта inout. Полный код модели pad выглядит следующим образом:

Пример

module pad(
    //DIN, драйвер pad, когда pad настроен как output
    //OEN, направление pad (1-input, o-output)
    input        DIN, OEN ,
    //функция pull (00,01-dispull, 10-pullup, 11-pulldown)
    input [1:0]  PULL ,
    inout        PAD ,
    //нагрузка pad, когда pad настроен как input
    output reg   DOUT
    );
 
    //вход:(не влияет на внешнюю входную логику pad), выход: DIN->PAD
    assign       PAD = OEN? 'bz : DIN ;
 
    //вход:(PAD->DOUT)
    always @(*) begin
        if (OEN == 1) begin //вход
            DOUT   = PAD ;
        end
        else begin
            DOUT   = 'bz ;
        end
    end
 
    //используйте вентиль с тремя состояниями в Verilog для реализации функции подтягивания вверх/вниз
    bufif1  puller(PAD, PULL[0], PULL[1]);
 
endmodule

Код тестового стенда выглядит следующим образом:

Пример

`timescale 1ns/1ns
 
module test ;
    reg          DIN, OEN ;
    reg [1:0]    PULL ;
    wire         PAD ;
    wire         DOUT ;
 
    reg          PAD_REG ;
    assign       PAD = OEN ? PAD_REG : 1'bz ; //
 
    initial begin
        PAD_REG   = 1'bz ;        //pad без управления в начале
        OEN       = 1'b1 ;        //моделирование входа
        #0 ;      PULL      = 2'b10 ;   //подтяжка к низкому уровню
        #20 ;     PULL      = 2'b11 ;   //подтяжка к высокому уровню
        #20 ;     PULL      = 2'b00 ;   //отключить подтяжку
        #20 ;     PAD_REG   = 1'b0 ;
        #20 ;     PAD_REG   = 1'b1 ;
 
        #30 ;     OEN       = 1'b0 ;    //моделирование выхода
                  DIN       = 1'bz ;
        #15 ;     DIN       = 1'b0 ;
        #15 ;     DIN       = 1'b1 ;
    end
 
    pad u_pad(
        .DIN     (DIN) ,
        .OEN     (OEN) ,
        .PULL    (PULL) ,
        .PAD     (PAD) ,
        .DOUT    (DOUT)
    );
 
    initial begin
        forever begin
            #100;
            if ($time >= 1000)  $finish ;
        end
    end
 
endmodule // test

Результаты моделирования следующие:

Анализ результатов моделирования выглядит следующим образом:

Когда направление PAD — вход и драйвер отсутствует, функция подтяжки может отражаться через значение PAD.

В первые 60ns сторона драйвера PAD_REG для PAD находится в z, что можно считать отсутствием драйва. Поэтому в начале PULL=2, подтяжка к нулю, значение PAD равно 0; при 20ns PULL=3, подтяжка к единице, значение PAD равно 1;

При 40ns PULL=0, функция подтяжки отсутствует, а входное значение PAD равно z.

После 60ns~100ns сторона драйвера PAD_REG для PAD начинает нормальное управление. В это время это эквивалентно тому, что PAD напрямую подключен к PAD_REG, поэтому значение PAD остается согласованным с его управляющим значением.

В приведенном выше анализе направление PAD всегда является входом, и все выходные терминалы DOUT остаются согласованными со значением PAD.

Когда направление PAD — выход, то есть при 120ns OEN=0, значение PAD остается согласованным со значением входного терминала DIN.

Скачать исходный код

Скачать