Ключевые слова: defparam, parameter, instantiation, ram

Когда один модуль создаёт экземпляр другого модуля, модуль более высокого уровня может переопределять значения параметров модуля более низкого уровня. Это позволяет передавать разные параметры нескольким модулям с одинаковым именем во время компиляции, без необходимости создавать новые файлы для модулей, которые отличаются только параметрами.

Существует 2 способа переопределения параметров: 1) с использованием ключевого слова defparam, 2) создание экземпляра модуля со значениями параметров.

Оператор defparam

Ключевое слово defparam можно использовать для переопределения значений параметров модулей нижнего уровня через иерархические ссылки на модули.

Например, переопределите параметр MASK однопортового модуля RAM, у которого линии адреса и данных обе имеют ширину 4 бита:

Пример

//создание экземпляра
defparam     u_ram_4x4.MASK = 7 ;
ram_4x4 u_ram_4x4
    (
        .CLK    (clk),
        .A      (a[4-1:0]),
        .D      (d),
        .EN     (en),
        .WR     (wr),    //1 для записи и 0 для чтения
        .Q      (q)    );

Модель ram_4x4 выглядит следующим образом:

Пример

module  ram_4x4
    (
     input               CLK ,
     input [4-1:0]       A ,
     input [4-1:0]       D ,
     input               EN ,
     input               WR ,    //1 для записи и 0 для чтения
     output reg [4-1:0]  Q    );
 
    parameter        MASK = 3 ;
 
    reg [4-1:0]     mem [0:(1<<4)-1] ;
    always @(posedge CLK) begin
        if (EN && WR) begin
            mem[A]  <= D & MASK;
        end
        else if (EN && !WR) begin
            Q       <= mem[A] & MASK;
        end
    end
 
endmodule

Выполните простое моделирование этого, а тестовый стенд записан следующим образом:

Пример

`timescale 1ns/1ns
 
module test ;
    parameter    AW = 4 ;
    parameter    DW = 4 ;
 
    reg                  clk ;
    reg [AW:0]           a ;
    reg [DW-1:0]         d ;
    reg                  en ;
    reg                  wr ;
    wire [DW-1:0]        q ;
 
    //генерация тактового сигнала
    always begin
        #15 ;     clk = 0 ;
        #15 ;     clk = 1 ;
    end
 
    initial begin
        a         = 10 ;
        d         = 2 ;
        en        = 'b0 ;
        wr        = 'b0 ;
        repeat(10) begin
            @(negedge clk) ;
            en     = 1'b1;
            a      = a + 1 ;
            wr     = 1'b1 ;  //команда записи
            d      = d + 1 ;
        end
        a         = 10 ;
        repeat(10) begin
            @(negedge clk) ;
            a      = a + 1 ;
            wr     = 1'b0 ;  //команда чтения
        end
    end // initial begin
 
    //создание экземпляра
    defparam     u_ram_4x4.MASK = 7 ;
    ram_4x4 u_ram_4x4
    (
        .CLK    (clk),
        .A      (a[AW-1:0]),
        .D      (d),
        .EN     (en),
        .WR     (wr),    //1 для записи и 0 для чтения
        .Q      (q)
     );
 
    //остановка моделирования
    initial begin
        forever begin
            #100;
            if ($time >= 1000)  $finish ;
        end
    end
 
endmodule // test

Результаты моделирования следующие:

В жёлтой части рисунка, когда адрес равен c в первый раз, записываются данные 4; когда адрес равен c во второй раз, считываются данные 4. Видно, что RAM в этот момент работает корректно, и MASK не равен 3, потому что bit2 выходного сигнала Q RAM не маскируется.

Когда адрес равен 1 в первый раз, записываются данные 9; когда адрес равен 1 во второй раз, считанные данные равны 1, потому что в этот момент MASK равен 7, и bit3 выходного сигнала Q RAM маскируется. Из этого видно, что параметр MASK был корректно переопределён.

Параметризованное создание экземпляра модуля

Второй метод заключается в записи новых значений параметров в оператор создания экземпляра модуля при создании экземпляра модуля, тем самым переопределяя значения параметров исходного модуля.

Например, выполните параметризованное создание экземпляра модуля для RAM-модуля с переменной разрядностью адреса и данных:

Пример

ram #(.AW(4), .DW(4))
    u_ram
    (
        .CLK    (clk),
        .A      (a[AW-1:0]),
        .D      (d),
        .EN     (en),
        .WR     (wr),    //1 для записи и 0 для чтения
        .Q      (q)
     );

Модель RAM выглядит следующим образом:

Пример

module  ram
    #(  parameter       AW = 2 ,
        parameter       DW = 3 )
    (
        input                   CLK ,
        input [AW-1:0]          A ,
        input [DW-1:0]          D ,
        input                   EN ,
        input                   WR ,    //1 для записи и 0 для чтения
        output reg [DW-1:0]     Q
     );
 
    reg [DW-1:0]         mem [0:(1<<AW)-1] ;
    always @(posedge CLK) begin
        if (EN && WR) begin
            mem[A]  <= D ;
        end
        else if (EN && !WR) begin
            Q       <= mem[A] ;
        end
    end
 
endmodule

При моделировании просто замените инстанцированный модуль u_ram_4x4 на этот инстанцированный модуль u_ram в предыдущем тестбенче или добавьте его снова.

Результаты моделирования следующие. Как видно из рисунка, параметры AW и DW RAM-модуля оба были переопределены на 4, и RAM работает корректно.

Различия и рекомендации

(1) Так же, как при создании экземпляра с портами модуля, при параметризованном создании экземпляра можно также передавать параметры по порядку, не указывая исходные имена параметров. Например, создание экземпляра u_ram можно описать так:

ram #(4, 4)   u_ram (......) ;

(2) Конечно, defparam также можно использовать для переопределения параметров, объявленных в объявлении портов модуля, а параметризованное создание экземпляра также может переопределять параметры, объявленные в теле модуля. Например, создание экземпляров u_ram и u_ram_4x4 можно описать так:

Пример

defparam     u_ram.AW = 4 ;
defparam     u_ram.DW = 4 ;
ram u_ram(......);
ram_4x4  #(.MASK(7))    u_ram_4x4(......);

(3) Можно ли смешивать эти два способа переопределения параметров модуля? Конечно! Предпосылка такова: все параметры должны быть объявлены либо в объявлении портов модуля, либо в теле модуля. Например, объявление u_ram также можно выразить так (параметры в теле модуля можно проверить своими собственными экспериментами):

Пример

defparam     u_ram.AW = 4 ;
ram #(.DW(4)) u_ram (......);  // Только кто-то столь же скучающий, как я, стал бы экспериментировать с таким стилем записи

(4) Что, если в модуле есть и параметры, объявленные в объявлении портов модуля, и параметры, объявленные в теле модуля? Можно ли переопределить эти два типа параметров одновременно? Например, добавьте параметр MASK в модуль RAM, и модель выглядит следующим образом:

Пример

module  ram
    #(  parameter       AW = 2 ,
        parameter       DW = 3 )
    (
        input                   CLK ,
        input [AW-1:0]          A ,
        input [DW-1:0]          D ,
        input                   EN ,
        input                   WR ,    //1 для записи и 0 для чтения
        output reg [DW-1:0]     Q    );
 
    parameter            MASK = 3 ;
 
    reg [DW-1:0]         mem [0:(1<<AW)-1] ;
    always @(posedge CLK) begin
        if (EN && WR) begin
            mem[A]  <= D ;
        end
        else if (EN && !WR) begin
            Q       <= mem[A] ;
        end
    end
 
endmodule

На этом этапе использование defparam для переопределения значения параметра MASK приводит к ошибке компиляции:

Пример

// Ошибка будет сообщаться, когда все используют defparam
defparam     u_ram.AW = 4 ;
defparam     u_ram.DW = 4 ;
defparam     u_ram.MASK = 7 ;
ram u_ram  (......);
 
// Переопределение параметра в теле модуля с помощью defparam также вызовет ошибку
defparam     u_ram.MASK = 7 ;
ram #(.AW(4), .DW(4))   u_ram (......);

Вот ключевой момент!!! Если вы используете способ параметризованного создания экземпляра модуля для переопределения значения параметра MASK, компиляция не выдаст ошибку, и MASK будет успешно переопределён!

ram #(.AW(4), .DW(4), .MASK(7)) u_ram (......);

Возможное объяснение состоит в том, что с точки зрения компилятора, если в объявлении портов модуля есть параметры, параметры в теле рассматриваются как тип localparam, и использование defparam не может переопределить параметры, объявленные в теле модуля.

Это также может быть связано с компилятором; вы можете поэкспериментировать и с другими компиляторами.

(5) Рекомендуется не использовать метод defparam при создании экземпляра существующего модуля и переопределении его связанных параметров. В дополнение к вышеуказанным недостаткам, defparam, как правило, не синтезируется.

(6) Также рекомендуется при написании модуля, если вы заранее знаете, что он будет инстанцирован и что параметры нужно будет переопределить, записывать эти параметры перед объявлением портов модуля (используя ключевое слово hash#для указания).

Скачать исходный код

Скачать

Итоги этапа

На самом деле, после этого введения вы вполне можете использовать знания языка Verilog, полученные ранее, чтобы построить небольшую соломенную хижину из аппаратных схем. Да, небольшую соломенную хижину. Из-за особой природы языков описания аппаратуры, соответствующих реальным аппаратным схемам, при построении различных моделей на Verilog вы должны учитывать, как выглядит фактически сгенерированная схема и соответствует ли она практическим требованиям. Иногда RTL-моделирование может пройти успешно, но фактическая схема, сгенерированная в итоге, может работать некорректно.

Поэтому, чтобы добавить кирпичи и черепицу к вашей маленькой соломенной хижине, вам всё ещё нужно изучить продвинутую часть. Конечно, продвинутая часть может лишь превратить вашу маленькую соломенную хижину в прочный кирпичный дом, способный выдерживать ветер и снег, но он всё ещё может рухнуть, если произойдёт землетрясение.

Если вы хотите укрепить свой кирпичный дом и построить виллу, то вам нужно изучить больше продвинутых тем Verilog, таких как PLI (Programming Language Interface), UDP (User Defined Primitives), временные ограничения и временной анализ и т. д. Вам также нужно участвовать в большем количестве проектных работ, чтобы накопить опыт, и уделять особое внимание некоторым методам проектирования, таким как проектирование с низким энергопотреблением, асинхронное проектирование и т. д. Конечно, обучение использованию SystemVerilog для комплексной верификации добавит ещё один уровень защиты вашему зданию.

Но если вы хотите до конца изучить все знания о цифровых схемах и Verilog, чтобы построить защищённый от снарядов президентский дворец, то мы действительно не в силах помочь. Потому что море знаний не имеет конца, и нет берега, чтобы повернуть назад.

Из-за ограничений по объёму здесь представлена только продвинутая часть. Если будет возможность, продвинутые темы и темы по методикам также будут добавлены.