Palabras clave: retardo, retardo inercial

El retardo en la declaración de asignación continua se utiliza para controlar el retardo de tiempo entre el cambio de cualquier operando y la asignación de un nuevo valor al extremo izquierdo de la declaración.

El retardo generalmente no es sintetizable.

El retardo de los registros también se puede controlar; esto se explicará en la sección de control de temporización.

El retardo de asignación continua generalmente se puede dividir en retardo de asignación ordinario, retardo implícito y retardo de declaración.

Los siguientes 3 ejemplos tienen funciones equivalentes y corresponden a tres formas diferentes de escribir el retardo de asignación continua.

//Retardo ordinario: el resultado del cálculo de A&B se asigna a Z después de un retardo de 10 unidades de tiempo
wire Z, A, B ;
assign #10    Z = A & B ;
 
//Retardo implícito: al declarar una variable tipo wire, se realiza una asignación continua con un cierto retardo.
wire A, B;
wire #10        Z = A & B;
 
//Retardo de declaración: al declarar una variable tipo wire se especifica un retardo. Por lo tanto, todas las asignaciones continuas a esa variable se retrasarán hasta el tiempo especificado. A menos que se use en modelado a nivel de puerta, generalmente no se recomienda usar este método para modelar.
wire A, B;
wire #10 Z ;
assign           Z =A & B

Retardo inercial

En el ejemplo anterior, si cualquier variable A o B cambia, habrá un retardo de 10 unidades de tiempo antes de que Z obtenga el nuevo valor. Si dentro de estas 10 unidades de tiempo, es decir, antes de que Z obtenga el nuevo valor, cualquier valor de A o B vuelve a cambiar, entonces al calcular el nuevo valor de Z se tomará el nuevo valor actual de A o B. Por eso se llama retardo inercial, es decir, si el ancho del pulso de la señal es menor que el retardo, no tiene efecto en la salida.

Por lo tanto, durante la simulación, el retardo debe establecerse razonablemente para evitar que algunas señales no puedan realizar un retardo efectivo.

Realizar una simulación de retardo para una lógica de puerta AND con retardo.

Ejemplo

module time_delay_module(
    input   ai, bi,
    output  so_lose, so_get, so_normal);
 
    assign #20      so_lose      = ai & bi ;
    assign  #5      so_get       = ai & bi ;
    assign          so_normal    = ai & bi ;
endmodule

El testbench se referencia de la siguiente manera:

Ejemplo

`timescale 1ns/1ns

module test ;
    reg  ai, bi ;
    wire so_lose, so_get, so_normal ;
 
    initial begin
        ai        = 0 ;
        #25 ;      ai        = 1 ;
        #35 ;      ai        = 0 ;        //60ns
        #40 ;      ai        = 1 ;        //100ns
        #10 ;      ai        = 0 ;        //110ns
    end
 
    initial begin
        bi        = 1 ;
        #70 ;      bi        = 0 ;
        #20 ;      bi        = 1 ;
    end
 
    time_delay_module  u_wire_delay(
        .ai              (ai),
        .bi              (bi),
        .so_lose         (so_lose),
        .so_get          (so_get),
        .so_normal       (so_normal));
 
    initial begin
        forever begin
            #100;
            //$display("---gyc---%d", $time);
            if ($time >= 1000) begin
                $finish ;
            end
        end
    end
 
endmodule

El resultado de la simulación es el siguiente:

La señal so_normal es la lógica AND normal.

Debido a que todos los retardos son mayores que 5ns, el resultado de la señal so_get es el resultado de la operación AND retrasado 5ns.

La primera parte de la señal so_lose es el resultado de la operación AND retrasado 20ns.

Debido a que la duración del segundo nivel alto de la señal ai es menor que 20ns, la señal so_lose perderá la detección de retardo de este pulso debido al retardo inercial, por lo que la segunda mitad de la señal so_lose sigue siendo 0.

Descarga del código fuente

Download