Ключевые слова: управление задержкой, запуск по событию, запуск по фронту, запуск по уровню

Verilog предоставляет 2 основных типа методов управления временем: управление задержкой и управление событиями. Управление событиями в основном делится на управление событиями с запуском по фронту и управление событиями, чувствительное к уровню.

Управление задержкой

Управление временем на основе задержки встречается в выражениях и задаёт временной интервал между началом и завершением выполнения оператора.

Задержка может быть числом, идентификатором или выражением.

В зависимости от различия позиции в выражении управление задержкой можно далее разделить на обычную задержку и встроенную задержку.

Обычная задержка

Когда встречается обычная задержка, оператор должен подождать определённое время, а затем присвоить результат вычисления целевому сигналу.

Формат: #delay procedural_statement, например:

reg  value_test ;
reg  value_general ;
#10  value_general    = value_test ;

Другой способ записи этого метода задержки — напрямую использовать знак решётки#в качестве независимого оператора выполнения задержки, например:

#10 ;
value_ single         = value_test ;

Встроенная задержка

Когда встречается встроенная задержка, оператор сначала сохраняет результат вычисления, затем ждет определенное время, прежде чем присвоить его целевому сигналу.

Управление встроенной задержкой добавляется после оператора присваивания. Например:

reg  value_test ;
reg  value_embed ;
value_embed        = #10 value_test ;

Следует отметить, что эффекты этих 2 методов управления задержкой различаются.

Когда правая часть оператора присваивания в операторе задержки является константой, оба метода управления задержкой могут обеспечить одинаковый эффект отложенного присваивания.

Когда правая часть оператора присваивания в операторе задержки является переменной, два метода управления задержкой могут давать разные эффекты отложенного присваивания.

Например, следующий код моделирования:

Пример

`timescale 1ns/1ns
 
module test ;
    reg  value_test ;
    reg  value_general, value_embed, value_single ;
 
    //signal source
    initial begin
        value_test        = 0 ;
        #25 ;      value_test        = 1 ;
        #35 ;      value_test        = 0 ;        //absolute 60ns
        #40 ;      value_test        = 1 ;        //абсолютная 100ns
        #10 ;      value_test        = 0 ;        //абсолютная 110ns
    end
 
    //(1)общее управление задержкой
    initial begin
        value_general     = 1;
        #10 value_general  = value_test ; //10ns, value_test=0
        #45 value_general  = value_test ; //55ns, value_test=1
        #30 value_general  = value_test ; //85ns, value_test=0
        #20 value_general  = value_test ; //105ns, value_test=1
    end
 
    //(2)встроенное управление задержкой
    initial begin
        value_embed       = 1;
        value_embed  = #10 value_test ; //0ns, value_test=0
        value_embed  = #45 value_test ; //10ns, value_test=0
        value_embed  = #30 value_test ; //55ns, value_test=1
        value_embed  = #20 value_test ; //85ns, value_test=0
    end
 
    //(3)управление одиночной задержкой
    initial begin
        value_single      = 1;
        #10 ;
        value_single = value_test ; //10ns, value_test=0
        #45 ;
        value_single = value_test ; //55ns, value_test=1
        #30 ;
        value_single = value_test ; //85ns, value_test=0
        #20 ;
        value_single = value_test ; //105ns, value_test=1
    end
 
    always begin
        #10;
        if ($time >= 150) begin
            $finish ;
        end
    end
 
endmodule

Результаты моделирования следующие. Из рисунка видно:

  • (1) Два выражения общей задержки дают одинаковые результаты выполнения.
  • (2) Метод присваивания с общей задержкой: после встречи с оператором задержки сначала задерживают на определённое время, затем присваивают текущий операнд целевому сигналу. Он не обладает свойством «инерционной задержки» и не будет пропускать относительно узкие импульсы.
  • (3) Метод присваивания со встроенной задержкой: после встречи с оператором задержки сначала вычисляют результат в правой части выражения, затем задерживают на определённое время и присваивают его целевому сигналу.

Ниже анализируется процесс присваивания встроенной задержки:

value_embed  = #10 value_test ; //0ns, value_test=0

В момент 0ns выполняется этот оператор задержки.

Сначала присвоить 0 сигналу value_embed, выход равен 0 после задержки 10ns;

value_embed  = #45 value_test ; //10ns, value_test=0

В момент 10ns выполняется этот оператор задержки.

Поскольку в этот момент value_test всё ещё равен 0, значение value_embed остаётся неизменным.

То есть до 55ns значение value_embed остаётся равным 0.

value_embed  = #30 value_test ; //55ns, value_test=1

Аналогично, в момент 55ns значение value_test равно 1, присвоить его value_embed и задержать вывод на 30ns.

Таким образом, в момент 85ns value_embed выводит 1.

value_embed  = #20 value_test ; //85ns, value_test=0

Аналогично, в момент 105ns value_embed выводит 0.

Управление событиями по фронту

В Verilog событие означает изменение значения переменной типа reg или wire.

Управление временем, инициируемое событиями, в основном делится на следующие типы.

Общее управление событиями

Управление событиями использует символ@для обозначения.

Условием выполнения оператора является то, что значение сигнала претерпевает определенное изменение.

Ключевое слово posedge обозначает положительный фронт сигнала, negedge — отрицательный фронт. Если направление перехода не указано, оба изменения фронта вызовут соответствующие события. Например:

Пример

//Пока сигнал clk изменяется, выполнять q<=d, модель D-триггера по обоим фронтам
always @(clk) q <= d ;                
//По положительному фронту сигнала clk выполнять q<=d, модель D-триггера по положительному фронту
always @(posedge clk) q <= d ;  
//По отрицательному фронту сигнала clk выполнять q<=d, модель D-триггера по отрицательному фронту
always @(negedge clk) q <= d ;
//Немедленно вычислить значение d и присвоить его q по положительному фронту clk. Такой стиль записи не рекомендуется.
q = @(posedge clk) d ;      

Управление именованными событиями

Пользователи могут объявить переменную типа event и запускать эту переменную, чтобы определить, произошло ли событие. Именованные события объявляются с помощью ключевого слова event, а для обозначения сигнала запуска используется->. Например:

Пример

event     start_receiving ;
always @( posedge clk_samp) begin
        -> start_receiving ;       //Возрастающий фронт тактового сигнала выборки как момент временного триггера
end
 
always @(start_receiving) begin
    data_buf = {data_if[0], data_if[1]} ; //В момент триггера объединить многомерные данные
end

Список чувствительности

Когда любой из нескольких сигналов или событий изменяется и может инициировать выполнение оператора, Verilog использует выражение 'ИЛИ' для описания этой ситуации, применяя ключевое словоorдля соединения нескольких событий или сигналов. Список, состоящий из этих событий или сигналов, называется 'списком чувствительности'. Конечно, 'or' также можно заменить запятой,чтобы заменить его. Например:

Пример

//Модель D-триггера с активным низким уровнем сброса
always @(posedge clk or negedge rstn)    begin      
//always @(posedge clk , negedge rstn) begin      
//Вы также можете использовать запятые для перечисления нескольких событий-триггеров
    if(! rstn)begin
        q <= 1'b ;      
    end
    else begin
        q <= d ;
    end
end

Когда в комбинационной логике много входных переменных, запись списка чувствительности становится громоздкой. В этом случае более краткой формой записи является@*или@(*), что указывает на чувствительность к изменениям всех входных переменных в блоке операторов. Например:

Пример

always @(*) begin
//always @(a, b, c, d, e, f, g, h, i, j, k, l, m) begin
//Оба варианта записи эквивалентны
    assign s = a? b+c : d ? e+f : g ? h+i : j ? k+l : m ;
end

Управление событиями по уровню

Все рассмотренные ранее средства управления событиями требуют ожидания изменения значения сигнала или запуска события; для его представления используется@+sensitivity list.

Verilog также поддерживает использование уровня в качестве чувствительного сигнала для управления синхронизацией, то есть выполнение последующих операторов должно ожидать, пока условие станет истинным. В Verilog ключевое слово wait используется для представления такой ситуации, чувствительной к уровню. Например:

Пример

initial begin
    wait (start_enable) ;      //Ожидание сигнала запуска
    forever begin
        //После активации сигнала запуска интегрировать данные по переднему фронту clk_samp
        @(posedge clk_samp)  ;
        data_buf = {data_if[0], data_if[1]} ;      
    end
end

Скачать исходный код

Скачать