Проектирование последовательного FIR-фильтра

Описание проекта

Параметры проектирования не изменены и согласованы с параметрами параллельного FIR-фильтра. То есть для входных сигналов в виде смешанных синусоид с частотами 7.5 MHz и 250 KHz после прохождения через FIR-фильтр высокочастотный сигнал на 7.5 MHz отфильтровывается, и остаётся только сигнал 250 KHz.

输入频率:    7.5MHz 和 250KHz
采样频率:    50MHz
阻带:           1MHz-6MHz
阶数:           15 (N=15)

В последовательном проекте 16 задержанных отсчётов данных последовательно обрабатываются операциями умножения и сложения с временным разделением в течение 16 тактов, после чего отфильтрованное значение выводится под управлением тактового сигнала. Учитывая симметрию коэффициентов FIR-фильтра, период вычисления одного отфильтрованного выходного значения можно сократить до 8 тактов. В последовательном проекте за такт выполняется только одна операция умножения, поэтому в проекте требуется только один умножитель. В этом случае данные должны корректно подаваться один раз каждые 8 тактов. Однако для обеспечения правильности частоты выходного сигнала рабочий тактовый сигнал должен быть в 8 раз выше частоты дискретизации, т.е. 400 MHz. Преимущество этого метода — низкое потребление ресурсов, но он требует высокой рабочей частоты, и данные не могут выводиться непрерывно.

Последовательное проектирование

Код модуля умножителя, используемого в проекте, см. в умножителе из предыдущего конвейерного проекта.

Для удобного и быстрого моделирования также можно напрямую использовать знак умножения*для выполнения операции умножения. В проекте добавлено макроопределение SAFE_DESIGN, чтобы выбирать, какой умножитель использовать.

Коэффициенты FIR-фильтра можно сгенерировать в MATLAB; подробности см. в приложении.

Пример

/**********************************************************
>> Описание : изучение FIR с последовательной технологией
>> V190403 : Fs:50Mhz, fstop:1-6Mhz, order:16, sys clk:400MHz
***********************************************************/

`define SAFE_DESIGN
 
module fir_serial_low(
    input                rstn,
    input                clk,   // Системный рабочий тактовый сигнал, 400MHz
    input                en ,   // Сигнал валидности входных данных
    input        [11:0]  xin,   // Входные данные сигнала со смешанными частотами
    output               valid, // Сигнал валидности выходных данных
    output       [28:0]  yout   // Выходные данные
    );
 
   //задержка разрешения входных данных
    reg [11:0]            en_r ;
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            en_r[11:0]      <= 'b0 ;
        end
        else begin
            en_r[11:0]      <= {en_r[10:0], en} ;
        end
    end
 
    //коэффициент FIR
    wire        [11:0]   coe[7:0] ;
    assign coe[0]        = 12'd11 ;
    assign coe[1]        = 12'd31 ;
    assign coe[2]        = 12'd63 ;
    assign coe[3]        = 12'd104 ;
    assign coe[4]        = 12'd152 ;
    assign coe[5]        = 12'd198 ;
    assign coe[6]        = 12'd235 ;
    assign coe[7]        = 12'd255 ;
 
    //(1) Секция сдвига входных данных
    reg [2:0]            cnt ;
    целое число              i, j ;
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            cnt <= 3'b0 ;
        end
        else if (en || cnt != 0) begin
            cnt <= cnt + 1'b1 ;    //подсчёт 8 циклов
        end
    end
 
    reg [11:0]           xin_reg[15:0];
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            for (i=0; i<16; i=i+1) begin
                xin_reg[i]  <= 12'b0;
            end
        end
        else if (cnt == 3'd0 && en) begin    //Считывание валидных данных один раз каждые 8 циклов
            xin_reg[0] <= xin ;
            for (j=0; j<15; j=j+1) begin
                xin_reg[j+1] <= xin_reg[j] ; // Сдвиг данных
            end
        end
    end
 
    //(2) Коэффициенты симметричны; сложите первые и последние данные 16 сдвиговых регистров
    reg  [11:0]          add_a, add_b ;
    reg  [11:0]          coe_s ;
    wire [12:0]          add_s ;
    wire [2:0]           xin_index = cnt>=1 ? cnt-1 : 3'd7 ;
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            add_a  <= 13'b0 ;
            add_b  <= 13'b0 ;
            coe_s  <= 12'b0 ;
        end
        else if (en_r[xin_index]) begin //из en_r[1]
            add_a  <= xin_reg[xin_index] ;
            add_b  <= xin_reg[15-xin_index] ;
            coe_s  <= coe[xin_index] ;
        end
    end
    assign add_s = {add_a} + {add_b} ;  
 
    //(3) Операция умножения, использующая только один умножитель
    reg        [24:0]    mout ;
`ifdef SAFE_DESIGN
    wire                 en_mult ;
    wire [3:0]           index_mult = cnt>=2 ? cnt-1 : 4'd7 + cnt[0] ;
    mult_man #(13, 12)   u_mult_single    //Инстанцировать самостоятельно разработанный конвейерный умножитель
        (.clk        (clk),
         .rstn       (rstn),
         .data_rdy   (en_r[index_mult]),  //Обратите внимание на временное соответствие данных
         .mult1      (add_s),
         .mult2      (coe_s),
         .res_rdy    (en_mult),  
         .res        (mout)
        );
 
`else
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            mout   <= 25'b0 ;
        end
        else if (|en_r[8:1]) begin
            mout   <= coe_s * add_s ;  //Прямое умножение
        end
    end
    wire                 en_mult = en_r[2];
`endif
 
    //(4) Накопление, 8 групп 25-битных данных -> 1 группа 29-битных данных
    reg        [28:0]    sum ;
    reg                  valid_r ;
    //Счетчик разрешения выхода умножения
    reg [4:0]            cnt_acc_r ;
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            cnt_acc_r <= 'b0 ;
        end
        else if (cnt_acc_r == 5'd7) begin  //Подсчёт 8 циклов
            cnt_acc_r <= 'b0 ;
        end
        else if (en_mult || cnt_acc_r != 0) begin //Пока en валиден, подсчёт продолжается
            cnt_acc_r <= cnt_acc_r + 1'b1 ;
        end
    end
 
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            sum      <= 29'd0 ;
            valid_r  <= 1'b0 ;
        end
        else if (cnt_acc_r == 5'd7) begin //Вывести отфильтрованное значение в 8-м цикле накопления
            sum      <= sum + mout;
            valid_r  <= 1'b1 ;
        end
        else if (en_mult && cnt_acc_r == 0) begin //Инициализация
            sum      <= mout ;
            valid_r  <= 1'b0 ;
        end
        else if (cnt_acc_r != 0) begin //накопление между циклами
            sum      <= sum + mout ;
            valid_r  <= 1'b0 ;
        end
    end
 
    // Фиксировать валидные выходные данные по фронту тактового сигнала, чтобы выходной сигнал не менялся слишком часто
    reg [28:0]           yout_r ;
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            yout_r <= 'b0 ;
        end
        else if (valid_r) begin
            yout_r <= sum ;
        end
    end
    assign yout = yout_r ;
 
    //(5) Задержка валидности выходных данных; то есть отбросить первые 15 отфильтрованных значений
    reg [4:0]    cnt_valid ;
    always @(posedge clk or negedge rstn) begin
        if (!rstn) begin
            cnt_valid      <= 'b0 ;
        end
        else if (valid_r && cnt_valid != 5'd16) begin
            cnt_valid      <= cnt_valid + 1'b1 ;
        end
    end
    assign valid = (cnt_valid == 5'd16) & valid_r ;

endmodule

testbench

Тестовый стенд написан следующим образом. Его основная функция — непрерывно, без прерываний, подавать данные смешанного синусоидального сигнала с частотами 250KHz и 7.5MHz. Входные данные смешанного сигнала также могут быть сгенерированы в MATLAB; подробности см. в приложении.

Здесь рабочая частота составляет 400MHz, но входные данные и сигнал валидности входных данных должны подаваться с частотой 50MHz.

Пример

module test ;
    //вход
    reg          clk ;
    reg          rst_n ;
    reg          en ;
    reg  [11:0]  xin ;
    //выход
    wire [28:0]  yout ;
    wire         valid ;

    parameter    SIMU_CYCLE   = 64'd1000 ;
    parameter    SIN_DATA_NUM = 200 ;

//=====================================
// Генерация clk 8*50MHz
    localparam   TCLK_HALF     = (10_000 >>3);
    initial begin
        clk = 1'b0 ;
        forever begin
            # TCLK_HALF clk = ~clk ;
        end
     end
 
//============================
// сброс и завершение
    initial begin
        rst_n = 1'b0 ;
        # 30        rst_n = 1'b1 ;
        # (TCLK_HALF * 2 * 8  * SIMU_CYCLE) ;
        $finish ;
    end
 
//=======================================
// считать данные cos в регистр
    reg          [11:0] stimulus [0: SIN_DATA_NUM-1] ;
    целое число      i ;
    initial begin
        $readmemh("../tb/cosx0p25m7p5m12bit.txt", stimulus) ;
        en = 0 ;
        i = 0 ;
        xin = 0 ;
        # 200 ;
        forever begin
            repeat(7)  @(negedge clk) ; //Простой в течение 7 тактов, данные подаются на 8-м такте
            en          = 1 ;
            xin         = stimulus[i] ;
            @(negedge clk) ;
            en          = 0 ;         //Сигнал валидности входных данных должен быть активен только один такт
            if (i == SIN_DATA_NUM-1)  i = 0 ;
            else  i = i + 1 ;
        end
    end
 
    fir_serial_low u_fir_serial (
        .clk         (clk),
        .rstn        (rst_n),
        .en          (en),
        .xin         (xin),
        .valid       (valid),
        .yout        (yout));

endmodule

Результаты моделирования

Из результатов моделирования на рисунке ниже видно, что сигнал после FIR-фильтра содержит только один низкочастотный сигнал (250KHz), а высокочастотный сигнал (7.5MHz) был отфильтрован. Для более эстетичного вида сигнала отфильтрованные данные после первых 16 отсчётов принимаются в качестве валидного выхода.

Локально увеличенная осциллограмма показана на рисунке ниже. При этом сигнал валидности входных данных en и сигнал валидности выходных данных valid являются импульсными сигналами с одинаковым периодом (50MHz) и не являются непрерывно валидными. Однако, поскольку рабочая тактовая частота составляет 400MHz, на выходе также будет синусоидальный сигнал с частотой 250KHz при частоте дискретизации 50MHz.

Приложение: Использование MATLAB (аналогично"Parallel FIR Filter Design"согласовано)

Сгенерировать коэффициенты FIR-фильтра

Откройте MATLAB, введите в командном окне команду: fdatool.

Затем откроется следующее окно. Настройте его в соответствии с параметрами FIR-фильтра, как показано ниже.

Выбранный здесь метод реализации FIR — метод наименьших квадратов (Least-squares). Разные методы реализации также дают разные эффекты фильтрации.

Нажмите File -> Export

Экспортируйте параметры фильтра и сохраните их в переменной coef, как показано на рисунке ниже.

В этот момент переменная coef должна быть данными с плавающей точкой. Умножьте её на определённый коэффициент для масштабирования, а затем возьмите её приближённые данные с фиксированной точкой в качестве параметров FIR-фильтра в проекте. Здесь коэффициент масштабирования равен 2048, результаты следующие.

Сгенерировать входной смешанный сигнал

Эталонный код для генерации смешанного входного сигнала с помощью MATLAB приведён ниже.

Сигнал представляет собой беззнаковые данные с фиксированной точкой с разрядностью 12 бит, хранящиеся в файлеcosx0p25m7p5m12bit.txt 。

Пример

clear all;close all;clc;
%=======================================================
% генерация данных cos-волны в формате txt hex
%=======================================================

fc          = 0.25e6 ;      %Центральная частота
fn          = 7.5e6 ;       %Частота помех
Fs          = 50e6 ;        %Частота дискретизации
T           = 1/fc ;        %Период сигнала
Num         = Fs * T ;      %Число точек дискретизации сигнала за период
t           = (0:Num-1)/Fs ;      %Дискретное время
cosx        = cos(2*pi*fc*t) ;    %Синусоидальный сигнал центральной частоты
cosn        = cos(2*pi*fn*t) ;    %Сигнал помех
cosy        = mapminmax(cosx + cosn) ;     %Амплитуда расширена до (-1,1) диапазон
cosy_dig    = floor((2^11-1) * cosy + 2^11) ;     %Амплитуда расширена до0~4095
fid         = fopen('cosx0p25m7p5m12bit.txt', 'wt') ;  %Записать файл данных
fprintf(fid, '%x\n', cosy_dig) ;
fclose(fid) ;
 
%Форма сигнала во временной области
figure(1);
subplot(121);plot(t,cosx);hold on ;
plot(t,cosn) ;
subplot(122);plot(t,cosy_dig) ;
 
%Форма сигнала в частотной области
fft_cosy    = fftshift(fft(cosy, Num)) ;
f_axis      = (-Num/2 : Num/2 - 1) * (Fs/Num) ;
figure(5) ;
plot(f_axis, abs(fft_cosy)) ;

Скачать исходный код

Скачать