Ключевые слова: тестбенч, моделирование, чтение/запись файлов
После завершения проектирования кода Verilog необходимо выполнить важный этап, а именно логико-функциональное моделирование. Файл стимулов моделирования называется тестбенчем и размещается на верхнем уровне проектируемых модулей, чтобы модули можно было систематически инстанцировать и вызывать для моделирования.
Не будет преувеличением сказать, что для слегка сложных проектов на Verilog, если не выполнять моделирование, более 99.9999% проектов не будут работать правильно, даже у опытных специалистов. Нельзя сказать, что моделирование важнее проектирования, но вообще говоря, моделирование занимает больше времени, чем проектирование. Иногда, с учётом различных сценариев применения, написание тестбенча может быть сложнее, чем проектирование на Verilog. Поэтому в индустрии цифровых схем специально различают инженеров-проектировщиков и инженеров по верификации.
Ниже мы кратко изучим тестбенч.
Разбор структуры тестбенча
Общая структура тестбенча выглядит следующим образом:
Фактически, самая базовая структура тестбенча включает объявление сигналов, стимулы и инстанцирование модулей.
В зависимости от сложности проекта необходимо добавить части тактирования и сброса. Конечно, для более сложных проектов часть со стимулами также будет более сложной. В зависимости от ваших потребностей в верификации выберите, нужны ли части самопроверки и завершения моделирования.
Конечно, части генерации сброса и тактового сигнала также можно рассматривать как стимулы, поэтому их все можно реализовать в одном блоке операторов. Результат самопроверки также можно использовать как условие завершения моделирования.
В реальном моделировании вы можете писать тестбенч в соответствии с вашими личными привычками; это всего лишь личное резюме.
Пример моделирования тестбенча
Многие тестбенчи уже были написаны в предыдущих главах. Фактически их структуры примерно одинаковы.
Ниже мы приводим простой пример конкатенации данных и проводим конкретный анализ тестбенча.
Функциональный модуль, который конкатенирует 2-битные данные в 8-битные, описывается следующим образом:
Пример
(
input clk ,
input rstn ,
input [1:0] din , //входные данные
input din_en ,
output [7:0] dout ,
output dout_en //выходные данные
);
// сдвиг данных и счётчик
reg [7:0] data_r ;
reg [1:0] state_cnt ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
state_cnt <= 'b0 ;
data_r <= 'b0 ;
end
else if (din_en) begin
state_cnt <= state_cnt + 1'b1 ; //Подсчёт данных
data_r <= {data_r[5:0], din} ; //Конкатенация данных
end
else begin
state_cnt <= 'b0 ;
end
end
assign dout = data_r ;
// разрешение вывода данных
reg dout_en_r ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
dout_en_r <= 'b0 ;
end
//Когда счётчик равен 3 и вводится 4-й элемент данных, синхронно выводится сигнал разрешения вывода данных
else if (state_cnt == 2'd3 & din_en) begin
dout_en_r <= 1'b1 ;
end
else begin
dout_en_r <= 1'b0 ;
end
end
//Здесь dout_en не объявляется напрямую как переменная reg; вместо этого он назначается через assign с использованием соответствующих регистров
assign dout_en = dout_en_r;
endmodule
Соответствующее описание тестбенча выглядит следующим образом, с добавленными операторами чтения/записи файлов:
Пример
//============== (1) ==================
//объявление сигналов
module test ;
reg clk;
reg rstn ;
reg [1:0] din ;
reg din_en ;
wire [7:0] dout ;
wire dout_en ;
//============== (2) ==================
//генерация тактового сигнала
real CYCLE_200MHz = 5 ; //
always begin
clk = 0 ; #(CYCLE_200MHz/2) ;
clk = 1 ; #(CYCLE_200MHz/2) ;
end
//============== (3) ==================
//генерация сброса
initial begin
rstn = 1'b0 ;
#8 rstn = 1'b1 ;
end
//============== (4) ==================
//мотивация
int fd_rd ;
reg [7:0] data_in_temp ; //для самопроверки
reg [15:0] read_temp ; //8bit ascii данные, 8bit \n
initial begin
din_en = 1'b0 ; //(4.1)
din = 'b0 ;
open_file("../tb/data_in.dat", "r", fd_rd); //(4.2)
wait (rstn) ; //(4.3)
# CYCLE_200MHz ;
//читать данные из файла
while (! $feof(fd_rd) ) begin //(4.4)
@(negedge clk) ;
$fread(read_temp, fd_rd);
din = read_temp[9:8] ;
data_in_temp = {data_in_temp[5:0], din} ;
din_en = 1'b1 ;
end
//остановить данные
@(posedge clk) ; //(4.5)
#2 din_en = 1'b0 ;
end
//открыть задачу
task open_file;
input string file_dir_name ;
input string rw ;
output int fd ;
fd = $fopen(file_dir_name, rw);
if (! fd) begin
$display("--- iii --- Не удалось открыть файл: %s", file_dir_name);
end
else begin
$display("--- iii --- %s успешно открыт.", file_dir_name);
end
endtask
//============== (5) ==================
//создание экземпляра модуля
data_consolidation u_data_process
(
.clk (clk),
.rstn (rstn),
.din (din),
.din_en (din_en),
.dout (dout),
.dout_en (dout_en)
);
//============== (6) ==================
//автоматическая проверка
reg [7:0] err_cnt ;
int fd_wr ;
initial begin
err_cnt = 'b0 ;
open_file("../tb/data_out.dat", "w", fd_wr);
forever begin
@(negedge clk) ;
if (dout_en) begin
$fdisplay(fd_wr, "%h", dout);
end
end
end
always @(posedge clk) begin
#1 ;
if (dout_en) begin
if (data_in_temp != dout) begin
err_cnt = err_cnt + 1'b1 ;
end
end
end
//============== (7) ==================
//завершение моделирования
always begin
#100;
if ($time >= 10000) begin
if (!err_cnt) begin
$display("-------------------------------------");
$display("Обработка данных прошла успешно!!!");
$display("-------------------------------------");
end
else begin
$display("-------------------------------------");
$display("В процессе обработки данных возникла ошибка!!!");
$display("-------------------------------------");
end
#1 ;
$finish ;
end
end
endmodule // test
Результаты моделирования приведены ниже. Как видно из рисунка, проектирование функции интеграции данных соответствует требованиям:
Подробный анализ тестбенча
1) Объявление сигналов
При объявлении модуля тестбенча обычно не требуется объявлять порты, поскольку стимулирующие сигналы обычно находятся внутри модуля тестбенча, а внешние сигналы отсутствуют.
Объявленные переменные должны все соответствовать портам тестируемого модуля. Конечно, переменные не обязаны иметь те же имена, что и порты тестируемого модуля. Однако переменные, соответствующие входным портам тестируемого модуля, должны быть объявлены как тип reg, например clk, rstn и т. д., а переменные, соответствующие выходным портам, должны быть объявлены как тип wire, например dout, dout_en.
2) Генерация тактового сигнала
Существует много способов генерации тактового сигнала; например, следующие два способа генерации также можно использовать для справки.
Пример
always #(CYCLE_200MHz/2) clk = ~clk;
initial begin
clk = 0 ;
forever begin
#(CYCLE_200MHz/2) clk = ~clk;
end
end
Следует отметить, что при использовании метода инверсии для генерации тактового сигнала регистру clk должно быть присвоено начальное значение.
При использовании параметрического метода для задания временных задержек, если параметр задержки является числом с плавающей точкой, этот параметр не следует объявлять с типом parameter. Например, в примере переменная CYCLE_200MHz имеет значение 2.5. Если её тип переменной — parameter, итоговый сгенерированный период тактового сигнала, скорее всего, будет равен 4ns. Конечно, точность timescale также нужно увеличить; единица измерения и точность не могут совпадать, иначе дробная часть присваивания временной задержки не будет учтена.
3) Генерация сброса
Логика сброса относительно проста. Обычно начальное значение присваивается 0, а затем после небольшой задержки сброс устанавливается в 1.
В большинстве моделирований здесь используется сброс с активным низким уровнем.
4) Часть стимулов
То, какие входные сигналы должна генерировать часть формирования стимулов, проектируется в соответствии с потребностями тестируемого модуля.
В этом примере:
- (4.1) Инициализировать входные сигналы тестируемого модуля, чтобы предотвратить появление неизвестного значения X. Для генерации данных стимулов нам нужно читать из файла данных.
- В (4.2) для открытия файла используется задача. Если указанный файл существует, можно получить ненулевой сигнал дескриптора fp_rd. fp_rd задаёт начальный адрес данных файла.
- Операция в (4.3) состоит в ожидании окончания сброса, чтобы система находилась в безопасном и стабильном состоянии, пригодном для тестирования.
- В (4.4) начинается чтение данных и подача стимулов в цикле. Данные отправляются по спадающему фронту тактового сигнала для того, чтобы тестируемый модуль мог лучше зафиксировать данные по возрастающему фронту.
С помощью системной задачи $fread считанная 16-битная переменная данных подаётся в буфер read_temp через сигнал дескриптора fd_rd.
Снимок экрана первых нескольких элементов данных во входном файле данных выглядит следующим образом. Поскольку $fread может читать только двоичные файлы, первая строка входного файла соответствует ASCII-коду 330a. Поэтому, чтобы получить значение 3 в файле, следует взять данные из битов с 9 по 8 переменной read_temp.

Сигнал data_in_temp представляет собой результат последующего интегрирования входного сигнала данных. Позже модуль верификации будет использовать его как эталон, чтобы определить, нормально ли проходит моделирование и правильно ли спроектирован модуль.
- В (4.5) выбор остановки входных данных после задержки в 2 цикла по возрастающему фронту тактового сигнала сделан для того, чтобы тестируемый модуль мог нормально зафиксировать последний сигнал разрешения данных и правильно проинтегрировать данные.
Когда объём данных относительно невелик, можно использовать системную задачу $readmemh в Verilog для непосредственного построчного чтения шестнадцатеричных данных. Если сохранить данные и формат в файле data_in.dat без изменений, эту часть формирования стимулов можно описать так:
Пример
reg [7:0] data_in_temp ; //для самопроверки
целое число k1 ;
initial begin
din_en = 1'b0 ;
din = 'b0 ;
$readmemh("../tb/data_in.dat", data_mem);
wait (rstn) ;
# CYCLE_200MHz ;
//читать данные из файла
for(k1=0; k1<40; k1=k1+1) begin
@(negedge clk) ;
din = data_mem[k1] ;
data_in_temp = {data_in_temp[5:0], din} ;
din_en = 1'b1 ;
end
//остановить данные
@(posedge clk) ;
#2 din_en = 1'b0 ;
end
5) Инстанцирование модуля
Здесь объявленные в начале тестбенча сигнальные переменные используются для инстанцирования и подключения тестируемого модуля.
6) Самопроверка
Если проект относительно прост, вполне возможно определить корректность проекта по временным диаграммам входных и выходных сигналов, и эту часть можно полностью удалить. Если данных много, иногда визуальное наблюдение не позволяет эффективно судить о корректности проекта. В этом случае добавление модуля самопроверки значительно повысит эффективность моделирования.
В примере, когда разрешение вывода данных dout_en активно, мы сравниваем выходные данные dout с эталонными данными read_temp (сформированными в части стимулов) и помещаем результат сравнения в сигнал err_cnt. В конце мы можем интуитивно судить о корректности проекта, наблюдая, равен ли сигнал err_cnt 0.
Конечно, как показано в примере, мы также можем записать данные в соответствующий файл и использовать другие методы для сравнения.
7) Завершение моделирования
Если мы не добавим часть завершения моделирования, моделирование будет выполняться бесконечно, а слишком длинные временные диаграммы иногда неудобно анализировать. Verilog предоставляет системную задачу $finish для остановки моделирования.
Перед остановкой моделирования результаты самопроверки можно вывести в терминал с помощью системной задачи $display.
Параметры чтения/записи файлов
Формат системной задачи $fopen, используемой для открытия файла, следующий:
fd = $fopen("<name_of_file>", "mode")
Подобно языку C, значение параметра режима открытия "mode" следующее:
| r | Открыть текстовый файл только для чтения, разрешено только чтение данных. |
|---|---|
| w | Открыть текстовый файл только для записи, разрешена только запись данных. Если файл существует, исходное содержимое файла будет удалено. Если файл не существует, будет создан новый файл. |
| a | Открыть текстовый файл для добавления и записывать данные в конец файла. Если файл не существует, будет создан новый файл. |
| rb | Открыть бинарный файл только для чтения, разрешено только чтение данных. |
| wb | Открыть или создать бинарный файл только для записи, разрешена только запись данных. |
| ab | Открыть бинарный файл для добавления и записывать данные в конец файла. |
| r+ | Открыть текстовый файл для чтения и записи, разрешены и чтение, и запись. |
| w+ | Открыть или создать текстовый файл для чтения и записи, разрешены чтение и запись. Если файл существует, исходное содержимое файла будет удалено. Если файл не существует, будет создан новый файл. |
| a+ | Открыть текстовый файл для чтения и записи, разрешены чтение и запись. Если файл не существует, будет создан новый файл. Чтение файла начинается с начала файла, а запись возможна только в режиме добавления. |
| rb+ | Открыть бинарный текстовый файл для чтения и записи, функциональность аналогична "r+". |
| wb+ | Открыть или создать бинарный текстовый файл для чтения и записи, функциональность аналогична "w+". |
| ab+ | Открыть текстовый файл для чтения и записи, с функциональностью, аналогичной "a+". |
Скачать исходный код
Скачать
