さまざまなアプリケーションシナリオの制約に伴い、チップは実行時に異なるアプリケーションに応じて異なるクロックソースを切り替える必要があることがよくあります。例えば、低消費電力モードと高性能モードでは、それぞれ低周波数と高周波数のクロックが必要です。2つのクロックソースは、同源で同期している場合もあれば、無関係な場合もあります。選択ロジックを直接使用してクロックを切り替えると、分周クロック信号にグリッチが発生する可能性が高いため、クロック切り替えロジックも特別に処理する必要があります。
クロック切り替えの問題
選択ロジックを直接使用してクロックを切り替える回路図を以下に示します。


クロック切り替え方式
2つのクロックのレベルが逆のときに切り替えると、必ずグリッチが発生します。レベルが同じときは、グリッチが発生しなくても、切り替え後の最初のクロックの周期やデューティ比は理想的ではありません。したがって、グリッチの発生を避けるために、2つのクロックがともにローレベルのときにクロックを切り替える必要があります。
典型的なクロック切り替え回路を以下に示します。
この回路は、クロックの立ち下がりエッジでクロック選択信号 sel_clk1 を保持します。同時に、一方のクロック選択信号が他方のクロックに対してフィードバック制御を行い、同時に有効になるクロックが1つだけであることを保証します。最後に「OR演算」を使用して2つのクロックを合成し、クロック切り替えのプロセスを完了します。

上記の回路を使用してクロック切り替え(clk1->clk2)を実行した波形図を以下に示します。
図からわかるように、clk1 から clk2 に切り替えるときは、最初に clk1 をオフにし、次に clk2 をオンにします。クロック選択信号がクロックの立ち下がりエッジに同期されているため、切り替えプロセス中にグリッチは発生しません。

clk2 から clk1 への切り替えの波形図を以下に示します。

選択信号は非同期信号である可能性があることを考慮して、クロック選択信号の保持フリップフロップの前に2段のフリップフロップを追加して同期処理を行い、メタステーブル状態の伝播を低減する必要があります。構造図は以下のとおりです。このクロック切り替え回路は、より汎用的です。

クロック切り替え設計
汎用的で安全なクロック切り替えロジックの記述は次のとおりです。
例
input rstn ,
input clk1,
input clk2,
input sel_clk1 , // 1 clk1, 0 clk2
output clk_out
);
reg [2:0] sel_clk1_r ;
reg [1:0] sel_clk1_neg_r ;
reg [2:0] sel_clk2_r ;
reg [1:0] sel_clk2_neg_r ;
//3クロックサイクルの保持を使用して、もう一方のクロック制御信号とこのクロック制御信号の「AND」論理演算を同期する
always @(posedge clk1 or negedge rstn) begin
if (!rstn) begin
sel_clk1_r <= 3'b111 ; //デフォルト値に注意
end
else begin
//sel clk1, and not sel clk2
sel_clk1_r <= {sel_clk1_r[1:0], sel_clk1 & (!sel_clk2_neg_r[1])} ;
end
end
//立ち下がりエッジで、2クロックサイクルの保持を使用してクロック選択信号を保持する
always @(negedge clk1 or negedge rstn) begin
if (!rstn) begin
sel_clk1_neg_r <= 2'b11 ; //デフォルト値に注意
end
else begin
sel_clk1_neg_r <= {sel_clk1_neg_r[0], sel_clk1_r[2]} ;
end
end
//3クロックサイクルの保持を使用して、もう一方のクロック制御信号とこのクロック制御信号の「AND」論理演算を同期する
always @(posedge clk2 or negedge rstn) begin
if (!rstn) begin
sel_clk2_r <= 3'b0 ; //デフォルト値に注意
end
else begin
//sel clk2, and not sel clk1
sel_clk2_r <= {sel_clk2_r[1:0], !sel_clk1 & (!sel_clk1_neg_r[1])} ;
end
end
//立ち下がりエッジで、2クロックサイクルの保持を使用してクロック選択信号を保持する
always @(negedge clk2 or negedge rstn) begin
if (!rstn) begin
sel_clk2_neg_r <= 2'b0 ; //デフォルト値に注意
end
else begin
sel_clk2_neg_r <= {sel_clk2_neg_r[0], sel_clk2_r[2]} ;
end
end
//クロックの論理演算には、通常、特定のプロセスセルライブラリを使用します。
//ここでは Verilog に組み込まれている論理ゲートセルで代用します
wire clk1_gate, clk2_gate ;
and (clk1_gate, clk1, sel_clk1_neg_r[1]) ;
and (clk2_gate, clk2, sel_clk2_neg_r[1]) ;
or (clk_out, clk1_gate, clk2_gate) ;
endmodule
testbench の記述は以下のとおりで、主に非同期クロックの選択信号を生成します。
例
module test ;
reg clk_100mhz, clk_200mhz ;
reg rstn ;
reg sel ;
wire clk_out ;
always #(2.5) clk_200mhz = ~clk_200mhz ;
always @(posedge clk_200mhz)
clk_100mhz = #1 ~clk_100mhz ;
initial begin
clk_100mhz = 0 ;
clk_200mhz = 0 ;
rstn = 0 ;
sel = 1 ;
#11 rstn = 1 ;
#36.2 sel = ~sel ;
#119.7 sel = ~sel ;
end
clk_switch u_clk_switch(
.rstn (rstn),
.clk1 (clk_100mhz),
.clk2 (clk_200mhz),
.sel_clk1 (sel),
.clk_out (clk_out));
initial begin
forever begin
#100;
if ($time >= 10000) $finish ;
end
end
endmodule
シミュレーション結果は以下のとおりで、クロックを相互に切り替えてもグリッチは発生しませんが、遅延が存在することがわかります。

本章のソースコードダウンロード
Download