キーワード:initial, always

プロセス構造文には2種類あり、initial 文と always 文です。それらは動作レベルモデリングの2つの基本文です。

1つのモジュールには複数の initial 文と always 文を含めることができますが、2種類の文を入れ子にして使用することはできません。

これらの文はモジュール内で並列に実行され、モジュール内の前後の順序とは関係ありません。

ただし、initial 文または always 文の内部は順次実行されると理解できます(ノンブロッキング代入を除く)。

各 initial 文または always 文は独立した制御フローを生成し、実行時間はすべて時刻0から始まります。

initial 文

initial 文は時刻0から実行を開始し、1回だけ実行されます。複数の initial ブロックは互いに独立しています。

initial ブロック内に複数の文が含まれる場合、キーワード begin と end を使用してブロック文を構成する必要があります。

initial ブロック内に文が1つだけの場合は、キーワード begin と end は使用しても使用しなくても構いません。

initial は理論上は合成不可能であり、主に初期化や信号検出などに使用されます。

前のセクションのコードを少し修正してシミュレーションを行います。コードは以下の通りです。

例

`timescale 1ns/1ns
 
module test ;
    reg  ai, bi ;
 
    initial begin
        ai         = 0 ;
        #25 ;      ai        = 1 ;
        #35 ;      ai        = 0 ;        //absolute 60ns
        #40 ;      ai        = 1 ;        //absolute 100ns
        #10 ;      ai        = 0 ;        //absolute 110ns
    end
 
    initial begin
        bi         = 1 ;
        #70 ;      bi        = 0 ;        //absolute 70ns
        #20 ;      bi        = 1 ;        //absolute 90ns
    end
 
    //at proper time stop the simulation
    initial begin
        forever begin
            #100;
            //$display("---gyc---%d", $time);
            if ($time >= 1000) begin
                $finish ;
            end
        end
   end
 
endmodule

シミュレーション結果は次のとおりです。

2つの initial プロセス文がそれぞれ信号 ai、bi に代入しても、互いに影響しないことがわかります。

信号 ai、bi の値は代入順に従って順に変化するため、initial 内部の文も順次実行されると見なすことができます。

always 文

initial 文とは逆に、always 文は繰り返し実行されます。always 文ブロックは時刻0からその中の動作文を実行し、最後の文を実行し終えると、再びブロック内の最初の文を実行し、このようにして繰り返します。

循環実行の特徴により、always 文は主にシミュレーションクロックの生成や信号動作の検出などに使用されます。

次に always を使用して100MHzのクロックソースを生成し、1010nsでシミュレーションを停止します。コードは以下の通りです。

コードは以下の通りです。

例

`timescale 1ns/1ns
 
module test ;
 
    parameter CLK_FREQ   = 100 ; //100MHz
    parameter CLK_CYCLE  = 1e9 / (CLK_FREQ * 1e6) ;   //switch to ns
 
    reg  clk ;
    initial      clk = 1'b0 ;      //clk is initialized to "0"
    always     # (CLK_CYCLE/2) clk = ~clk ;       //generating a real clock by reversing
 
    always begin
        #10;
        if ($time >= 1000) begin
            $finish ;
        end
    end
 
endmodule

シミュレーション結果は次のとおりです。

クロック周期が目的の100MHzになっていることがわかります。また、シミュレーションは1010nsで停止します。

ソースコードのダウンロード

Download