シリアル FIR フィルタ設計
設計説明
設計パラメータは変更せず、並列 FIR フィルタのパラメータと一致させます。すなわち、入力周波数が 7.5 MHz と 250 KHz の正弦波混合信号は、FIR フィルタを通した後、高周波信号 7.5MHz が除去され、250KHz の信号のみが残ります。
输入频率: 7.5MHz 和 250KHz 采样频率: 50MHz 阻带: 1MHz-6MHz 阶数: 15 (N=15)
シリアル設計とは、16 クロック周期内で 16 個の遅延データに対して時分割で順に乗算・加算演算を行い、その後クロック駆動でフィルタ出力値を出力することです。FIR フィルタ係数の対称性を考慮すると、1 つのフィルタ出力値を計算する周期を 8 に減らすことができます。シリアル設計では各周期に乗算演算を 1 回だけ行うため、設計には乗算器が 1 つだけで済みます。このとき、データは 8 クロック周期ごとに 1 回有効に入力する必要がありますが、出力信号周波数の正確性を保証するために、動作クロックはサンプリング周波数の 8 倍、すなわち 400MHz である必要があります。この方法の利点は消費リソースが少ないことですが、動作周波数の要求が高く、データを継続的に出力できません。
シリアル設計
設計で使用する乗算器モジュールのコードは、以前のパイプライン方式設計の乗算器を参照してください。
高速シミュレーションを容易にするために、直接乗算記号を使用することもできます。*乗算演算を実行します。設計にマクロ定義 SAFE_DESIGN を追加して、どの乗算器を使用するかを選択します。
FIR フィルタ係数は matlab で生成できます。詳細は付録を参照してください。
例
>> Description : fir study with serial tech
>> V190403 : Fs:50Mhz, fstop:1-6Mhz, order:16, sys clk:400MHz
***********************************************************/
`define SAFE_DESIGN
module fir_serial_low(
input rstn,
input clk, // システム動作クロック、400MHz
input en , // 入力データ有効信号
input [11:0] xin, // 混合周波数の信号データを入力
output valid, // 出力データ有効信号
output [28:0] yout // 出力データ
);
//delay of input data enable
reg [11:0] en_r ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
en_r[11:0] <= 'b0 ;
end
else begin
en_r[11:0] <= {en_r[10:0], en} ;
end
end
//fir coeficient
wire [11:0] coe[7:0] ;
assign coe[0] = 12'd11 ;
assign coe[1] = 12'd31 ;
assign coe[2] = 12'd63 ;
assign coe[3] = 12'd104 ;
assign coe[4] = 12'd152 ;
assign coe[5] = 12'd198 ;
assign coe[6] = 12'd235 ;
assign coe[7] = 12'd255 ;
//(1) 入力データシフト部分
reg [2:0] cnt ;
integer i, j ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
cnt <= 3'b0 ;
end
else if (en || cnt != 0) begin
cnt <= cnt + 1'b1 ; //8周期カウント
end
end
reg [11:0] xin_reg[15:0];
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
for (i=0; i<16; i=i+1) begin
xin_reg[i] <= 12'b0;
end
end
else if (cnt == 3'd0 && en) begin //8周期ごとに有効データを1回読み込む
xin_reg[0] <= xin ;
for (j=0; j<15; j=j+1) begin
xin_reg[j+1] <= xin_reg[j] ; // データシフト
end
end
end
//(2) 係数が対称なので、16個のシフトレジスタデータの先頭と末尾を加算
reg [11:0] add_a, add_b ;
reg [11:0] coe_s ;
wire [12:0] add_s ;
wire [2:0] xin_index = cnt>=1 ? cnt-1 : 3'd7 ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
add_a <= 13'b0 ;
add_b <= 13'b0 ;
coe_s <= 12'b0 ;
end
else if (en_r[xin_index]) begin //from en_r[1]
add_a <= xin_reg[xin_index] ;
add_b <= xin_reg[15-xin_index] ;
coe_s <= coe[xin_index] ;
end
end
assign add_s = {add_a} + {add_b} ;
//(3) 乗算演算、乗算は1つのみ使用
reg [24:0] mout ;
`ifdef SAFE_DESIGN
wire en_mult ;
wire [3:0] index_mult = cnt>=2 ? cnt-1 : 4'd7 + cnt[0] ;
mult_man #(13, 12) u_mult_single //自作のパイプライン乗算器をインスタンス化
(.clk (clk),
.rstn (rstn),
.data_rdy (en_r[index_mult]), //データのタイミング対応に注意
.mult1 (add_s),
.mult2 (coe_s),
.res_rdy (en_mult),
.res (mout)
);
`else
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
mout <= 25'b0 ;
end
else if (|en_r[8:1]) begin
mout <= coe_s * add_s ; //直接乗算
end
end
wire en_mult = en_r[2];
`endif
//(4) 累積加算、8組の25bitデータ -> 1組の29bitデータ
reg [28:0] sum ;
reg valid_r ;
//mult output en counter
reg [4:0] cnt_acc_r ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
cnt_acc_r <= 'b0 ;
end
else if (cnt_acc_r == 5'd7) begin //8周期を計時
cnt_acc_r <= 'b0 ;
end
else if (en_mult || cnt_acc_r != 0) begin //enが有効な限り、計時を停止しない
cnt_acc_r <= cnt_acc_r + 1'b1 ;
end
end
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
sum <= 29'd0 ;
valid_r <= 1'b0 ;
end
else if (cnt_acc_r == 5'd7) begin //8番目の累加周期でフィルタ値を出力
sum <= sum + mout;
valid_r <= 1'b1 ;
end
else if (en_mult && cnt_acc_r == 0) begin //初期化
sum <= mout ;
valid_r <= 1'b0 ;
end
else if (cnt_acc_r != 0) begin //acculating between cycles
sum <= sum + mout ;
valid_r <= 1'b0 ;
end
end
//出力信号の変化があまり頻繁にならないように、クロックで有効な出力データをラッチする
reg [28:0] yout_r ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
yout_r <= 'b0 ;
end
else if (valid_r) begin
yout_r <= sum ;
end
end
assign yout = yout_r ;
//(5) 出力データ有効遅延、すなわちフィルタデータの先頭15個のフィルタ値を破棄
reg [4:0] cnt_valid ;
always @(posedge clk or negedge rstn) begin
if (!rstn) begin
cnt_valid <= 'b0 ;
end
else if (valid_r && cnt_valid != 5'd16) begin
cnt_valid <= cnt_valid + 1'b1 ;
end
end
assign valid = (cnt_valid == 5'd16) & valid_r ;
endmodule
testbench
testbench は以下のように記述します。主な機能は、250KHz と 7.5MHz の正弦波混合信号データを途切れることなく連続して入力することです。入力する混合信号データも matlab で生成できます。詳細は付録を参照してください。
ここで、動作周波数は 400MHz ですが、入力データと入力データ有効信号はどちらも 50MHz の周波数で入力する必要があります。
例
//input
reg clk ;
reg rst_n ;
reg en ;
reg [11:0] xin ;
//output
wire [28:0] yout ;
wire valid ;
parameter SIMU_CYCLE = 64'd1000 ;
parameter SIN_DATA_NUM = 200 ;
//=====================================
// 8*50MHz clk generating
localparam TCLK_HALF = (10_000 >>3);
initial begin
clk = 1'b0 ;
forever begin
# TCLK_HALF clk = ~clk ;
end
end
//============================
// reset and finish
initial begin
rst_n = 1'b0 ;
# 30 rst_n = 1'b1 ;
# (TCLK_HALF * 2 * 8 * SIMU_CYCLE) ;
$finish ;
end
//=======================================
// read cos data into register
reg [11:0] stimulus [0: SIN_DATA_NUM-1] ;
integer i ;
initial begin
$readmemh("../tb/cosx0p25m7p5m12bit.txt", stimulus) ;
en = 0 ;
i = 0 ;
xin = 0 ;
# 200 ;
forever begin
repeat(7) @(negedge clk) ; //7周期空けて、8周期目にデータを与える
en = 1 ;
xin = stimulus[i] ;
@(negedge clk) ;
en = 0 ; //入力データ有効信号は1周期だけ持続すればよい
if (i == SIN_DATA_NUM-1) i = 0 ;
else i = i + 1 ;
end
end
fir_serial_low u_fir_serial (
.clk (clk),
.rstn (rst_n),
.en (en),
.xin (xin),
.valid (valid),
.yout (yout));
endmodule
シミュレーション結果
下図のシミュレーション結果からわかるように、FIR フィルタを通過した後の信号は低周波信号(250KHz)のみであり、高周波信号(7.5MHz)は除去されています。波形をより美しくするために、16個以降のフィルタデータを有効出力として使用します。

波形を局所的に拡大すると下図のようになります。このとき、入力データ有効信号 en と出力データ有効信号 valid は周期(50MHz)が同じパルス信号であり、持続的に有効ではありません。ただし、動作クロックは 400MHz なので、出力も 50MHz サンプリング周波数における 250KHz 周波数の正弦波信号として現れます。

付録:matlab 使用(『並列 FIR フィルタ設計』一致)
FIR フィルタ係数の生成
matlab を開き、コマンドウィンドウにコマンド「fdatool」を入力します。
続いて、以下のウィンドウが開くので、FIR フィルタパラメータに従って設定します。下図のとおりです。
ここで選択する FIR 実装方法は最小二乗法(Least-squares)です。実装方式が異なるとフィルタ効果も異なります。

File -> Export をクリックします。
フィルタパラメータを出力し、変数 coef に保存します。下図のとおりです。

このとき、coef 変数は浮動小数点型データのはずです。これに一定倍率の乗算で拡大を行い、その近似の固定小数点型データを設計中の FIR フィルタパラメータとします。ここでは拡大倍率を 2048 とし、結果は以下のとおりです。

入力する混合信号の生成
matlab を使用して混合入力信号を生成する参考コードは以下のとおりです。
信号は符号なし固定小数点型データで、ビット幅は 12bit であり、ファイルに保存されます。cosx0p25m7p5m12bit.txt 。
例
%=======================================================
% generating a cos wave data with txt hex format
%=======================================================
fc = 0.25e6 ; %中心周波数
fn = 7.5e6 ; %クラッタ周波数
Fs = 50e6 ; %サンプリング周波数
T = 1/fc ; %信号周期
Num = Fs * T ; %周期内の信号サンプリング点数
t = (0:Num-1)/Fs ; %離散時間
cosx = cos(2*pi*fc*t) ; %中心周波数正弦波信号
cosn = cos(2*pi*fn*t) ; %クラッタ信号
cosy = mapminmax(cosx + cosn) ; %振幅を(-1,1)の間に拡大
cosy_dig = floor((2^11-1) * cosy + 2^11) ; %振幅を拡大0~4095
fid = fopen('cosx0p25m7p5m12bit.txt', 'wt') ; %データファイルを書き込む
fprintf(fid, '%x\n', cosy_dig) ;
fclose(fid) ;
%時間領域波形
figure(1);
subplot(121);plot(t,cosx);hold on ;
plot(t,cosn) ;
subplot(122);plot(t,cosy_dig) ;
%周波数領域波形
fft_cosy = fftshift(fft(cosy, Num)) ;
f_axis = (-Num/2 : Num/2 - 1) * (Fs/Num) ;
figure(5) ;
plot(f_axis, abs(fft_cosy)) ;
ソースコードダウンロード
Download