キーワード: 順序ブロック、並列ブロック、ネストブロック、名前付きブロック、disable

Verilog ステートメントブロックは、2つ以上のステートメントを構文構造上1つのステートメントと同等にまとめる仕組みを提供します。主に順序ブロックと並列ブロックの2種類があります。

順序ブロック

順序ブロックはキーワード begin と end で表します。

順序ブロック内のステートメントは1つずつ実行されます。もちろん、非ブロッキング代入は除きます。

順序ブロック内の各ステートメントの遅延は、常にその前のステートメントが実行された時刻に関連します。

この節の前のシミュレーションでは、initial ブロック内のブロッキング代入は、すべて順序ブロックの例です。

並列ブロック

並列ブロックはキーワード fork と join で表します。

並列ブロック内のステートメントは、ブロッキング形式の代入であっても並列に実行されます。

並列ブロック内の各ステートメントの遅延は、ブロックの実行開始時刻に関連します。

順序ブロックと並列ブロックの違いは明らかですが、以下でシミュレーションを用いて説明します。

シミュレーションコードは次のとおりです:

例

`timescale 1ns/1ns
 
module test ;
    reg [3:0]   ai_sequen, bi_sequen ;
    reg [3:0]   ai_paral,  bi_paral ;
    reg [3:0]   ai_nonblk, bi_nonblk ;
 
 //============================================================//
    //(1)Sequence block
    initial begin
        #5 ai_sequen         = 4'd5 ;    //at 5ns
        #5 bi_sequen         = 4'd8 ;    //at 10ns
    end
    //(2)fork block
    initial fork
        #5 ai_paral          = 4'd5 ;    //at 5ns
        #5 bi_paral          = 4'd8 ;    //at 5ns
    join
    //(3)non-block block
    initial fork
        #5 ai_nonblk         <= 4'd5 ;    //at 5ns
        #5 bi_nonblk         <= 4'd8 ;    //at 5ns
    join
 
endmodule

シミュレーション結果は次のとおりです:

図のように、順序ブロックは順番に実行され、10ns の時点で信号 bi_sequen がようやく 8 に代入されます。

一方、並列ブロックでは、ai_paral と bi_paral の代入は同時に実行されるため、どちらも 5ns の時点で代入されます。

また、非ブロッキング代入も、並列ブロックと同等の代入効果を得られます。

ネストブロック

順序ブロックと並列ブロックは、ネストして使用することもできます。

シミュレーションコードは次のとおりです:

例

`timescale      1ns/1ns
 
module test ;
 
    reg [3:0]   ai_sequen2, bi_sequen2 ;
    reg [3:0]   ai_paral2,  bi_paral2 ;
    initial begin
        ai_sequen2         = 4'd5 ;    //at 0ns
        fork
            #10 ai_paral2          = 4'd5 ;    //at 10ns
            #15 bi_paral2          = 4'd8 ;    //at 15ns
        join
        #20 bi_sequen2      = 4'd8 ;    //at 35ns
    end
 
endmodule

シミュレーション結果は次のとおりです:

並列ブロック内のステートメントは並列に実行されるため、信号 ai_paral2 と信号 bi_paral2 はそれぞれ 10ns、15ns の時点で代入されます。並列ブロック内の最長実行時間は 15ns なので、順序ブロック内の信号 bi_sequen2 は 35ns の時点で代入されます。

名前付きブロック

ブロックステートメント構造に名前を付けることができます。

名前付きブロック内ではローカル変数を宣言でき、階層名を参照する方法で変数にアクセスできます。

シミュレーションコードは次のとおりです:

例

`timescale 1ns/1ns
 
module test;
 
    initial begin: サンプル   //名前付きブロック名は サンプル。セミコロンは省略できません
        integer    i ;       //この変数は test.サンプル.i を介して他のモジュールから使用できます
        i = 0 ;
        forever begin
            #10 i = i + 10 ;      
        end
    end
 
    reg stop_flag ;
    initial stop_flag = 1'b0 ;
    always begin : detect_stop
        if ( test.サンプル.i == 100) begin //i が10回累加されると、すなわち100nsでシミュレーションが停止します
            $display("Now you can stop the simulation!!!");
            stop_flag = 1'b1 ;
        end
        #10 ;
    end
 
endmodule

シミュレーション結果は次のとおりです:

名前付きブロックは無効化することもでき、キーワード disable で表します。

disable は名前付きブロックの実行を終了でき、ループからの脱出やエラー処理などに使用できます。

C 言語の break に似ていますが、break は現在のループのみを抜け出せるのに対し、disable はデザイン内の任意の名前付きブロックを無効化できます。

シミュレーションコードは次のとおりです:

例

`timescale 1ns/1ns
 
module test;
 
    initial begin: サンプル_d //名前付きブロック名は サンプル_d
        integer    i_d ;
        i_d = 0 ;
        while(i_d<=100) begin: サンプル_d2
            # 10 ;
            if (i_d >= 50) begin       //5回加算したら加算を停止
                disable サンプル_d3.clk_gen ;//外部ブロック clk_gen を停止
                disable サンプル_d2 ;       //現在のブロック サンプル_d2 を停止
            end
            i_d = i_d + 10 ;
        end
    end
 
    reg clk ;
    initial begin: サンプル_d3
        while (1) begin: clk_gen  //クロック生成モジュール
            clk=1 ;      #10 ;
            clk=0 ;      #10 ;
        end
    end
 
endmodule

シミュレーション結果は次のとおりです:

図からわかるように、信号 i_d は 50 まで加算されるとそれ以上加算されず、以降 clk クロックも生成されません。

このように、disable は現在の while ブロックから抜け出します。

注意すべき点として、disable を always または forever ブロック内で使用した場合、現在の回だけを抜け出し、次のステートメントは引き続き always または forever 内で実行されます。always ブロックと forever ブロックは常に実行されるため、この場合の disable は C 言語の continue 機能に似ています。

ソースコードのダウンロード

Download