Schlüsselwörter: initial, always
Es gibt 2 Arten von prozeduralen Strukturanweisungen: initial- und always-Anweisungen. Sie sind die 2 grundlegenden Anweisungen der Modellierung auf Verhaltensebene.
Ein Modul kann mehrere initial- und always-Anweisungen enthalten, aber diese 2 Arten von Anweisungen können nicht verschachtelt werden.
Diese Anweisungen werden innerhalb des Moduls parallel ausgeführt, unabhängig von ihrer Reihenfolge im Modul.
Innerhalb einer initial- oder always-Anweisung kann die Ausführung jedoch als sequentiell verstanden werden (außer bei nicht blockierenden Zuweisungen).
Jede initial- oder always-Anweisung erzeugt einen unabhängigen Kontrollfluss, und die Ausführungszeit beginnt bei Zeit 0.
initial-Anweisung
Die initial-Anweisung beginnt zum Zeitpunkt 0 mit der Ausführung und wird nur einmal ausgeführt. Mehrere initial-Blöcke sind unabhängig voneinander.
Wenn ein initial-Block mehrere Anweisungen enthält, müssen die Schlüsselwörter begin und end verwendet werden, um eine Blockanweisung zu bilden.
Wenn ein initial-Block nur eine Anweisung enthält, können die Schlüsselwörter begin und end verwendet werden oder auch nicht.
Die initial-Anweisung ist theoretisch nicht synthetisierbar und wird hauptsächlich für Initialisierung, Signalerkennung usw. verwendet.
Ändern Sie den Code aus dem vorherigen Abschnitt geringfügig und führen Sie eine Simulation aus. Der Code lautet wie folgt.
Beispiel
module test ;
reg ai, bi ;
initial begin
ai = 0 ;
#25 ; ai = 1 ;
#35 ; ai = 0 ; //absolut 60ns
#40 ; ai = 1 ; //absolut 100ns
#10 ; ai = 0 ; //absolut 110ns
end
initial begin
bi = 1 ;
#70 ; bi = 0 ; //absolut 70ns
#20 ; bi = 1 ; //absolut 90ns
end
//zum richtigen Zeitpunkt die Simulation stoppen
initial begin
forever begin
#100;
//$display("---gyc---%d", $time);
if ($time >= 1000) begin
$finish ;
end
end
end
endmodule
Die Simulationsergebnisse sind wie folgt:
Es ist zu erkennen, dass sich die 2 initial-Prozessanweisungen, wenn sie den Signalen ai bzw. bi Werte zuweisen, nicht gegenseitig beeinflussen.
Die Werte der Signale ai und bi ändern sich sequenziell entsprechend der Zuweisungsreihenfolge, daher können die Anweisungen innerhalb von initial auch als sequenzielle Ausführung betrachtet werden.

always-Anweisung
Anders als die initial-Anweisung wird die always-Anweisung wiederholt ausgeführt. Der always-Anweisungsblock beginnt ab Zeit 0 mit der Ausführung seiner Verhaltensanweisungen; nach der Ausführung der letzten Anweisung führt er die erste Anweisung im Block erneut aus und wiederholt diesen Zyklus.
Aufgrund ihrer zyklischen Ausführung wird die always-Anweisung häufig zur Erzeugung von Simulationstaktsignalen, zur Erkennung von Signalverhalten usw. verwendet.
Nachfolgend wird die always-Anweisung verwendet, um eine 100MHz-Taktquelle zu erzeugen, und die Simulation wird bei 1010ns angehalten. Der Code lautet wie folgt.
Der Code lautet wie folgt:
Beispiel
module test ;
parameter CLK_FREQ = 100 ; //100MHz
parameter CLK_CYCLE = 1e9 / (CLK_FREQ * 1e6) ; //Wechsel zu ns
reg clk ;
initial clk = 1'b0 ; //clk wird auf "0" initialisiert
always # (CLK_CYCLE/2) clk = ~clk ; //Erzeugen eines echten Takts durch Invertieren
always begin
#10;
if ($time >= 1000) begin
$finish ;
end
end
endmodule
Die Simulationsergebnisse sind wie folgt:
Es ist zu erkennen, dass die Taktperiode den gewünschten 100MHz entspricht. Außerdem wird die Simulation bei 1010ns angehalten.

Quellcode-Download
Herunterladen