キーワード:遅延制御、イベントトリガ、エッジトリガ、レベルトリガ

Verilog は2大分類のタイミング制御方法を提供しています:遅延制御とイベント制御です。イベント制御は主にエッジトリガイベント制御とレベルセンシティブイベント制御に分けられます。

遅延制御

遅延に基づくタイミング制御は式内に現れ、ステートメントの実行開始から実行完了までの時間間隔を指定します。

遅延は数値、識別子、または式にすることができます。

式内での位置の違いにより、遅延制御は通常遅延とインライン遅延に分けられます。

通常遅延

通常遅延に遭遇した場合、そのステートメントは一定時間待機してから、計算結果をターゲット信号に代入します。

形式は:#delay procedural_statement、例:

reg  value_test ;
reg  value_general ;
#10  value_general    = value_test ;

この遅延方式のもう1つの書き方は、シャープ記号を直接#独立した遅延実行ステートメントにすることです。例:

#10 ;
value_ single         = value_test ;

インライン遅延

インライン遅延に遭遇した場合、そのステートメントはまず計算結果を保存し、一定時間待機してからターゲット信号に代入します。

インライン遅延制御は代入記号の後に追加されます。例:

reg  value_test ;
reg  value_embed ;
value_embed        = #10 value_test ;

注意すべき点は、この2つの遅延制御方式の効果は異なるということです。

遅延ステートメントの代入記号の右辺が定数の場合、2つの遅延制御はどちらも同じ遅延代入効果を達成できます。

遅延ステートメントの代入記号の右辺が変数の場合、2つの遅延制御は異なる遅延代入効果を生じる可能性があります。

例えば、以下のシミュレーションコード:

例

`timescale 1ns/1ns
 
module test ;
    reg  value_test ;
    reg  value_general, value_embed, value_single ;
 
    //signal source
    initial begin
        value_test        = 0 ;
        #25 ;      value_test        = 1 ;
        #35 ;      value_test        = 0 ;        //absolute 60ns
        #40 ;      value_test        = 1 ;        //absolute 100ns
        #10 ;      value_test        = 0 ;        //absolute 110ns
    end
 
    //(1)general delay control
    initial begin
        value_general     = 1;
        #10 value_general  = value_test ; //10ns, value_test=0
        #45 value_general  = value_test ; //55ns, value_test=1
        #30 value_general  = value_test ; //85ns, value_test=0
        #20 value_general  = value_test ; //105ns, value_test=1
    end
 
    //(2)embedded delay control
    initial begin
        value_embed       = 1;
        value_embed  = #10 value_test ; //0ns, value_test=0
        value_embed  = #45 value_test ; //10ns, value_test=0
        value_embed  = #30 value_test ; //55ns, value_test=1
        value_embed  = #20 value_test ; //85ns, value_test=0
    end
 
    //(3)single delay control
    initial begin
        value_single      = 1;
        #10 ;
        value_single = value_test ; //10ns, value_test=0
        #45 ;
        value_single = value_test ; //55ns, value_test=1
        #30 ;
        value_single = value_test ; //85ns, value_test=0
        #20 ;
        value_single = value_test ; //105ns, value_test=1
    end
 
    always begin
        #10;
        if ($time >= 150) begin
            $finish ;
        end
    end
 
endmodule

シミュレーション結果は以下のとおりです。図からわかるように:

  • (1)通常遅延の2つの表現方法の実行結果はどちらも一致します。
  • (2)通常遅延代入方式:遅延ステートメントに遭遇した後、まず一定時間遅延し、その時点のオペランドをターゲット信号に代入します。「慣性遅延」の特性はなく、比較的狭いパルスを見逃すことはありません。
  • (3)インライン遅延代入方式:遅延ステートメントに遭遇した後、まず式の右辺の結果を計算し、次に一定時間遅延してからターゲット信号に代入します。

以下、インライン遅延の代入プロセスを分析します。

value_embed  = #10 value_test ; //0ns, value_test=0

0ns のとき、この遅延ステートメントを実行します。

まず 0 を信号 value_embed に代入し、10ns 遅延して出力は 0 になります。

value_embed  = #45 value_test ; //10ns, value_test=0

10ns のとき、この遅延ステートメントを実行します。

このとき value_test はまだ 0 なので、value_embed の値は変わりません。

つまり、55ns までは value_embed の値は依然として 0 を維持します。

value_embed  = #30 value_test ; //55ns, value_test=1

同様に、55ns のとき、value_test の値は 1 であり、それを value_embed に代入し、30ns 遅延して出力します。

したがって、85ns のとき、value_embed の出力は 1 です。

value_embed  = #20 value_test ; //85ns, value_test=0

同様に、105ns のとき、value_embed の出力は 0 です。

エッジトリガイベント制御

Verilog では、イベントとは、ある reg または wire 型の変数に値の変化が発生したことを指します。

イベントトリガに基づくタイミング制御は、主に以下のいくつかに分類されます。

一般イベント制御

イベント制御は記号@で表します。

ステートメントが実行される条件は、信号の値が特定の変化を起こすことです。

キーワード posedge は信号のエッジが正方向へ遷移することを指し、negedge は信号のエッジが負方向へ遷移することを指します。遷移方向が指定されていない場合は、2つの場合のエッジ変化のどちらでも関連イベントがトリガされます。例:

例

//信号clkが変化するだけでq<=dを実行、両エッジDフリップフロップモデル
always @(clk) q <= d ;                
//信号clkの立ち上がりエッジの時点でq<=dを実行、正エッジDフリップフロップモデル
always @(posedge clk) q <= d ;  
//信号clkの立ち下がりエッジの時点でq<=dを実行、負エッジDフリップフロップモデル
always @(negedge clk) q <= d ;
//dの値を即座に計算し、clkの立ち上がりエッジの時点でqに代入する。この書き方は推奨されない
q = @(posedge clk) d ;      

名前付きイベント制御

ユーザーは event(イベント)型の変数を宣言し、その変数をトリガして、イベントが発生したかどうかを認識できます。名前付きイベントはキーワード event で宣言され、トリガ信号は->で表します。例:

例

event     start_receiving ;
always @( posedge clk_samp) begin
        -> start_receiving ;       //サンプリングクロックの立ち上がりエッジをタイミングトリガ時点とする
end
 
always @(start_receiving) begin
    data_buf = {data_if[0], data_if[1]} ; //トリガ時点で、多次元データを統合する
end

センシティビティリスト

Verilog では、「or」式でこの状況を記述し、キーワードorを用いて複数のイベントまたは信号を接続します。これらのイベントまたは信号で構成されるリストは「センシティビティリスト」と呼ばれます。もちろん、or はカンマ,に置き換えることもできます。例:

例

//ローアクティブリセット端子付きDフリップフロップモデル
always @(posedge clk or negedge rstn)    begin      
//always @(posedge clk , negedge rstn)    begin      
//カンマを使用して複数のイベントトリガを列挙することもできます
    if(! rstn)begin
        q <= 1'b ;      
    end
    else begin
        q <= d ;
    end
end

組み合わせ論理の入力変数が多い場合、センシティビティリストの記述は非常に煩雑になります。この場合、より簡潔な書き方は、@* 或 @(*)ステートメントブロック内のすべての入力変数の変化にセンシティブであることを示します。例:

例

always @(*) begin
//always @(a, b, c, d, e, f, g, h, i, j, k, l, m) begin
//2つの書き方は等価
    assign s = a? b+c : d ? e+f : g ? h+i : j ? k+l : m ;
end

レベルセンシティブイベント制御

これまでに説明したイベント制御は、すべて信号値の変化またはイベントのトリガを待つ必要があり、@+センシティビティリストという方式で表されます。

Verilog は、レベルをセンシティブ信号として使用してタイミングを制御することもサポートしています。つまり、後続のステートメントの実行は、ある条件が真になるのを待つ必要があります。Verilog では、キーワード wait を使用してこのレベルセンシティブな状況を表します。例:

例

initial begin
    wait (start_enable) ;      //start 信号を待つ
    forever begin
        //start信号が有効になった後、clk_sampの立ち上がりエッジでデータを統合する
        @(posedge clk_samp)  ;
        data_buf = {data_if[0], data_if[1]} ;      
    end
end

ソースコードのダウンロード

Download