Mots-clés : initial, always

Il existe 2 types d'instructions de structure procédurale : les instructions initial et always. Ce sont les 2 instructions de base de la modélisation au niveau comportemental.

Un module peut contenir plusieurs instructions initial et always, mais ces 2 types d'instructions ne peuvent pas être imbriquées.

Ces instructions sont exécutées en parallèle au sein du module, indépendamment de leur ordre dans le module.

Cependant, à l'intérieur d'une instruction initial ou always, l'exécution peut être comprise comme séquentielle (sauf pour les affectations non bloquantes).

Chaque instruction initial ou always génère un flux de contrôle indépendant, et le temps d'exécution commence à partir du temps 0.

Instruction initial

L'instruction initial commence son exécution au temps 0 et ne s'exécute qu'une seule fois. Plusieurs blocs initial sont indépendants les uns des autres.

Si un bloc initial contient plusieurs instructions, les mots-clés begin et end doivent être utilisés pour former une instruction de bloc.

Si un bloc initial ne contient qu'une seule instruction, les mots-clés begin et end peuvent être utilisés ou non.

L'instruction initial n'est théoriquement pas synthétisable et est principalement utilisée pour l'initialisation, la détection de signal, etc.

Modifiez légèrement le code de la section précédente et lancez une simulation. Le code est le suivant.

Exemple

`timescale 1ns/1ns
 
module test ;
    reg  ai, bi ;
 
    initial begin
        ai         = 0 ;
        #25 ;      ai        = 1 ;
        #35 ;      ai        = 0 ;        //absolu 60ns
        #40 ;      ai        = 1 ;        //absolu 100ns
        #10 ;      ai        = 0 ;        //absolu 110ns
    end
 
    initial begin
        bi         = 1 ;
        #70 ;      bi        = 0 ;        //absolu 70ns
        #20 ;      bi        = 1 ;        //absolu 90ns
    end
 
    //au moment opportun, arrêter la simulation
    initial begin
        forever begin
            #100;
            //$display("---gyc---%d", $time);
            if ($time >= 1000) begin
                $finish ;
            end
        end
   end
 
endmodule

Les résultats de simulation sont les suivants :

On peut voir que lorsque les 2 instructions de processus initial attribuent respectivement des valeurs aux signaux ai et bi, elles ne s'affectent pas mutuellement.

Les valeurs des signaux ai et bi changent séquentiellement selon l'ordre d'affectation, de sorte que les instructions à l'intérieur de initial peuvent également être considérées comme une exécution séquentielle.

Instruction always

Contrairement à l'instruction initial, l'instruction always est exécutée de manière répétée. Le bloc d'instructions always commence l'exécution de ses instructions comportementales à partir du temps 0 ; après avoir exécuté la dernière instruction, il exécute à nouveau la première instruction du bloc, répétant ce cycle.

En raison de sa caractéristique d'exécution cyclique, l'instruction always est souvent utilisée pour générer des horloges de simulation, détecter le comportement des signaux, etc.

Ci-dessous, l'instruction always est utilisée pour générer une source d'horloge de 100MHz, et la simulation est arrêtée à 1010ns. Le code est le suivant.

Le code est le suivant :

Exemple

`timescale 1ns/1ns
 
module test ;
 
    parameter CLK_FREQ   = 100 ; //100MHz
    parameter CLK_CYCLE  = 1e9 / (CLK_FREQ * 1e6) ;   //passer en ns
 
    reg  clk ;
    initial      clk = 1'b0 ;      //clk est initialisé à "0"
    always     # (CLK_CYCLE/2) clk = ~clk ;       //génération d'une horloge réelle par inversion
 
    always begin
        #10;
        if ($time >= 1000) begin
            $finish ;
        end
    end
 
endmodule

Les résultats de simulation sont les suivants :

On peut voir que la période d'horloge correspond aux 100MHz souhaités. De plus, la simulation s'arrête à 1010ns.

Téléchargement du code source

Téléchargement