キーワード:ブロッキング代入、ノンブロッキング代入、並列

手続き代入は initial または always ステートメントブロック内での代入であり、代入対象はレジスタ、整数、実数などの型です。

これらの変数は代入された後、再び新しい値が代入されるまで、その値は保持されます。

連続代入は常にアクティブな状態にあり、いずれかのオペランドが変化すると式の結果に影響します。手続き代入は文が実行されたときだけ作用します。これが連続代入と手続き代入の違いです。

Verilog の手続き代入には2種類の文があります:ブロッキング代入とノンブロッキング代入です。

ブロッキング代入

ブロッキング代入は順次実行に属します。つまり、次の文が実行される前に、現在の文が必ず実行完了します。

ブロッキング代入文は等号を=代入演算子として使用します。

前述のシミュレーションでは、initial内の代入文はすべてブロッキング代入を使用しています。

ノンブロッキング代入

ノンブロッキング代入は並列実行文に属します。つまり、次の文の実行と現在の文の実行が同時に行われ、同じステートメントブロック内の後続の文の実行をブロックしません。

ノンブロッキング代入文は小なりイコール記号を<=代入演算子として使用します。

次のコードを使用して、ブロッキング代入とノンブロッキング代入のシミュレーションを行い、2種類の手続き代入の違いを説明します。

例

`timescale 1ns/1ns
 
module test ;
    reg [3:0]   ai, bi ;
    reg [3:0]   ai2, bi2 ;
    reg [3:0]   value_blk ;
    reg [3:0]   value_non ;
    reg [3:0]   value_non2 ;
 
    initial begin
        ai            = 4'd1 ;   //(1)
        bi            = 4'd2 ;   //(2)
        ai2           = 4'd7 ;   //(3)
        bi2           = 4'd8 ;   //(4)
        #20 ;                    //(5)
 
        //non-block-assigment with block-assignment
        ai            = 4'd3 ;     //(6)
        bi            = 4'd4 ;     //(7)
        value_blk     = ai + bi ;  //(8)
        value_non     <= ai + bi ; //(9)
 
        //non-block-assigment itself
        ai2           <= 4'd5 ;           //(10)
        bi2           <= 4'd6 ;           //(11)
        value_non2    <= ai2 + bi2 ;      //(12)
    end
 
   //stop the simulation
    always begin
        #10 ;
        if ($time >= 1000) $finish ;
    end
 
endmodule

シミュレーション結果は次のとおりです。

文(1)〜(8)はすべてブロッキング代入であり、順次実行されます。

20nsより前では、信号 ai、bi の値が変化します。手続き代入の特徴により、value_blk = ai + bi はまだ実行されていないため、20nsより前の value_blk の値は X(不定状態)です。

20nsより後では、信号 ai、bi の値が再び変化します。value_blk = ai + bi が実行されると、信号 value_blk は信号 ai、bi の新しい値を使用して計算結果 7 を得ます。

文(9)〜(12)はすべてノンブロッキング代入であり、並列実行されます。

まず、(9)~(12)はすべて並列実行ですが、実行順序は(8)より後です。したがって、信号 value_non = ai + bi の計算でも信号 ai、bi の新しい値が使用され、結果は7になります。

次に、(10)~(12)は並列実行であるため、value_non2 = ai2 + bi2 の計算時には、信号 ai2、bi2 の最新のノンブロッキング代入結果は考慮されません。つまり、value_non2 の計算時には信号 ai2、bi2 の古い値が使用され、結果は 4'hF になります。

ノンブロッキング代入を使用して競合ハザードを回避する

上記のシミュレーションコードは、読者がブロッキング代入とノンブロッキング代入の違いをよりよく理解するためのものです。実際のVerilogコード設計では、1つの手続き構造内でブロッキング代入とノンブロッキング代入を混在させないように注意してください。2つの代入方法を混用すると、タイミングを制御しにくくなり、予期しない結果が得られやすくなります。

多くの場合、回路を設計するときは、always順序論理ブロックではノンブロッキング代入を多用し、always組み合わせ論理ブロックではブロッキング代入を多用します。回路をシミュレーションするときは、initialブロックでは一般的にブロッキング代入を多用します。

下に示すように、クロックの立ち上がりエッジで2つのレジスタ値を交換する機能を実現するために、2つのalwaysブロックでブロッキング代入を使用します。

2つのalwaysブロック内の文は同時に実行されますが、a=b と b=a の実行順序は判定できないため、競合状態を引き起こします。

しかし、どちらが先に実行されるかにかかわらず(コンパイラなどに関係します)、タイミング問題を考慮しない場合、それらの実行順序には必ず前後があり、最終的に a と b の値は常に等しくなります。2つのレジスタ値を交換する効果は得られません。

例

always @(posedge clk) begin
    a = b ;
end
 
always @(posedge clk) begin
    b = a;
end

しかし、alwaysブロックでノンブロッキング代入を使用すれば、上記の競合ハザードを回避できます。

下に示すように、2つのalwaysブロック内の文は並列実行され、代入操作の右辺のオペランドは前のクロックサイクルの古い値を使用します。このとき、a<=b と b<=a は互いに干渉せずに実行でき、レジスタ値を交換する目的を達成できます。

例

always @(posedge clk) begin
    a <= b ;
end
 
always @(posedge clk) begin
    b <= a;
end

もちろん、次のコードを使用してもレジスタ値を交換する機能を実現できますが、alwaysブロックで直接ノンブロッキング代入を使用するほうが明らかに簡単で直感的です。

例

always @(posedge clk) begin
    temp    = a ;
    a       = b ;
    b       = temp ;
end

ソースコードのダウンロード

Download