キーワード:assign、全加算器

連続代入文は Verilog データフローモデリングの基本文であり、wire 型変数への代入に使用されます。

形式は以下のとおりです

assign     LHS_target = RHS_expression  ;

LHS(left hand side)は代入操作の左側を指し、RHS(right hand side)は代入操作の右側を指します。

assign はキーワードであり、宣言済みの wire 変数への連続代入文はすべて assign で始まります。例:

wire      Cout, A, B ;
assign    Cout  = A & B ;     //实现计算A与B的功能

説明が必要な点:

  • LHS_target はスカラーまたは wire 型ベクトルでなければならず、レジスタ型であってはなりません。
  • RHS_expression の型に制限はなく、スカラー、wire 型またはレジスタ型ベクトル、また関数呼び出しでも構いません。
  • RHS_expression 式のオペランドにイベント(値の変化)が発生すると、RHS_expression は直ちに再計算され、同時に LHS_target に代入されます。

Verilog には、wire 型への代入の別の簡単な方法も用意されています。wire 型変数を宣言するときに同時に代入する方法です。wire 型変数は一度しか代入できないため、この連続代入方式も一度だけしか使用できません。例えば、以下の代入方法と上記の代入例の代入方法は、効果がすべて同じです。

wire      A, B ;
wire      Cout = A & B ;

全加算器

以下ではデータフロー記述方式を用いて、1bit 全加算器を設計します。

Ai、Bi、Ci をそれぞれ被加数、加数、隣接する下位からの桁上げ(キャリー)とし、So、Co をそれぞれ本位の和と隣接する上位への桁上げとします。

真理値表は以下のとおりです:

Input  Output 
CiAiBiSoCo
00000
00110
01010
01101
10010
10101
11001
11111

全加算器の式は以下のとおりです:

So = Ai ⊕ Bi ⊕ Ci ;
Co = AiBi + Ci(Ai+Bi)

RTL コード(full_adder1.v)は以下のとおりです:

例

module full_adder1(
    input    Ai, Bi, Ci,
    output   So, Co);
 
    assign So = Ai ^ Bi ^ Ci ;
    assign Co = (Ai & Bi) | (Ci & (Ai | Bi));
endmodule

もちろん、より加算器に近いコード記述は以下のようになります:

例

module full_adder1(
    input    Ai, Bi, Ci
    output   So, Co);
 
    assign {Co, So} = Ai + Bi + Ci ;
endmodule

testbench(test.sv)の参考は以下のとおりです:

例

`timescale 1ns/1ns
 
module test ;
    reg Ai, Bi, Ci ;
    wire So, Co ;
 
    initial begin
        {Ai, Bi, Ci}      = 3'b0;
        forever begin
            #10 ;
            {Ai, Bi, Ci}      = {Ai, Bi, Ci} + 1'b1;
        end
    end
 
    full_adder1  u_adder(
        .Ai      (Ai),
        .Bi      (Bi),
        .Ci      (Ci),
        .So      (So),
        .Co      (Co));
 
    initial begin
        forever begin
            #100;
            //$display("---gyc---%d", $time);
            if ($time >= 1000) begin
            $finish ;
            end
        end
    end
 
 endmodule

シミュレーション結果は以下のとおりです:

ソースコードのダウンロード

Download