Schlüsselwörter: module, port, bidirektionaler Port, PAD

Die strukturelle Modellierung hat 3 Arten von Beschreibungsanweisungen: Gate-Instanziierungsanweisungen (Gate-Ebene), UDP-Instanziierungsanweisungen (User Defined Primitive) und Modulinstanziierungsanweisungen. Dieser Abschnitt behandelt hauptsächlich die am weitesten verbreiteten Instanziierungsanweisungen auf Modulebene.

Modul

Ein Modul ist die Definitionsform einer Grundeinheit in Verilog und die Schnittstelle zur Interaktion mit der Außenwelt.

Das Modulformat ist wie folgt definiert:

module module_name 
#(parameter_list)
(port_list) ;
              Declarations_and_Statements ;
endmodule

Eine Moduldefinition muss mit dem Schlüsselwort `module` beginnen und mit dem Schlüsselwort `endmodule` enden.

Der Modulname, die Portsignale, die Portdeklarationen und optionale Parameterdeklarationen usw. erscheinen vor den im Design verwendeten Verilog-Anweisungen (Declarations_and_Statements in der Abbildung).

Innerhalb eines Moduls gibt es 5 optionale Teile: Variablendeklarationen, Datenflussanweisungen, Anweisungen auf Verhaltensebene, Instanziierungen von Modulen niedrigerer Ebene sowie Tasks und Funktionen, wie in der folgenden Abbildung dargestellt. Die Reihenfolge und Position dieser 5 Teile sind beliebig. Alle Variablen sollten jedoch vor ihrer Verwendung deklariert werden. Der genaue Ort der Variablendeklarationen ist nicht vorgeschrieben, aber sie müssen vor der Verwendung platziert werden.

Der größte Teil des Simulationscodes weiter oben verwendet Moduldeklarationen; Sie können selbst darauf verweisen. Wir werden hier keine konkreten Beispiele geben. Wenn unten Ports eingeführt werden, führen wir detaillierte Simulationen durch.

Port

Ein Port ist die Schnittstelle, über die ein Modul mit der Außenwelt interagiert. Für die externe Umgebung ist das Innere eines Moduls unsichtbar, und Aufrufe des Moduls können nur über Portverbindungen erfolgen.

Portliste

Die Moduldefinition enthält eine optionale Portliste, in der in der Moduldeklaration im Allgemeinen Signalvariablen ohne Typ und ohne Bitbreite aufgeführt werden. Nachfolgend sehen Sie eine Portliste für ein PAD-Modell:

module pad(
    DIN, OEN, PULL,
    DOUT, PAD);

Wenn ein Modul keine Interaktion mit der externen Umgebung hat, muss es keine Portliste deklarieren. Beispielsweise hat in unseren früheren Simulationen das Testmodul in der Datei test.sv keine spezifischen Ports deklariert.

module test ;  //直接分号结束
    ......     //数据流或行为级描述
endmodule

Portdeklaration

(1) Nachdem die Portsignale in der Portliste aufgeführt wurden, können sie im Modulkörper deklariert werden.

Je nach Portrichtung gibt es 3 Porttypen: input, output und bidirektionaler Port (inout).

Die Typen input und inout können nicht als Datentyp reg deklariert werden, da der Typ reg zum Speichern von Werten verwendet wird, während input-Ports nur Änderungen der mit ihnen verbundenen externen Signale widerspiegeln können und die Werte dieser Signale nicht speichern können.

output kann als Datentyp wire oder reg deklariert werden.

Die Portdeklaration des pad-Moduls im obigen Beispiel kann im Modulkörper wie folgt ausgedrückt werden:

Beispiel

// Porttyp-Deklaration
input        DIN, OEN ;
input [1:0]  PULL ;  //(00,01 - Pull deaktiviert, 11 - Pull-up, 10 - Pull-down)
inout        PAD ;   //Pad-Wert
output       DOUT ;  //Pad laden, wenn Pad als Eingang konfiguriert ist

// Port-Datentypdeklaration
wire         DIN, OEN ;
wire  [1:0]  PULL ;
wire         PAD ;
reg          DOUT ;

(2) In Verilog werden Ports implizit als Variablen vom Typ wire deklariert. Das heißt, wenn ein Port das wire-Attribut hat, muss der Porttyp nicht erneut als wire deklariert werden. Wenn ein Port jedoch das reg-Attribut hat, kann die reg-Deklaration nicht weggelassen werden.

Die Portdeklaration im obigen Beispiel kann wie folgt vereinfacht werden:

Beispiel

// Porttyp-Deklaration
input        DIN, OEN ;
input [1:0]  PULL ;    
inout        PAD ;    
output       DOUT ;    
reg          DOUT ;

(3) Natürlich kann die Deklaration des Signals DOUT in einer einzigen Anweisung zusammengefasst werden:

output reg      DOUT ;

(4) Es gibt außerdem eine prägnantere und häufig verwendete Methode, Ports zu deklarieren, nämlich die Ports und ihre Typen in der Moduldeklaration aufzulisten. Ports vom Reg-Typ müssen entweder in der Moduldeklaration oder im Modulkörper deklariert werden. Zum Beispiel sind die folgenden beiden Schreibweisen äquivalent.

Beispiel

module pad(
    input        DIN, OEN ,
    input [1:0]  PULL ,
    inout        PAD ,
    output reg   DOUT
    );
 
module pad(
    input        DIN, OEN ,
    input [1:0]  PULL ,
    inout        PAD ,
    output       DOUT
    );
 
    reg        DOUT ;

inout-Port-Simulation

Simulieren Sie ein Pad-Modell, das den inout-Porttyp enthält. Der vollständige Code des Pad-Modells lautet wie folgt:

Beispiel

module pad(
    //DIN, Pad-Treiber, wenn Pad als Ausgang konfiguriert ist
    //OEN, Pad-Richtung (1-Eingang, o-Ausgang)
    input        DIN, OEN ,
    //Pull-Funktion (00,01-dispull, 10-pullup, 11-pulldown)
    input [1:0]  PULL ,
    inout        PAD ,
    //Pad-Last, wenn Pad als Eingang konfiguriert ist
    output reg   DOUT
    );
 
    //Eingabe:(kein Einfluss auf externe Pad-Eingangslogik), Ausgabe: DIN->PAD
    assign       PAD = OEN? 'bz : DIN ;
 
    //Eingabe:(PAD->DOUT)
    always @(*) begin
        if (OEN == 1) begin //Eingabe
            DOUT   = PAD ;
        end
        else begin
            DOUT   = 'bz ;
        end
    end
 
    //Tri-State-Gatter in Verilog verwenden, um Pull-up/Down-Funktion zu realisieren
    bufif1  puller(PAD, PULL[0], PULL[1]);
 
endmodule

Der Testbench-Code ist wie folgt:

Beispiel

`timescale 1ns/1ns
 
module test ;
    reg          DIN, OEN ;
    reg [1:0]    PULL ;
    wire         PAD ;
    wire         DOUT ;
 
    reg          PAD_REG ;
    assign       PAD = OEN ? PAD_REG : 1'bz ; //
 
    initial begin
        PAD_REG   = 1'bz ;        //Pad zunächst ohne Treiber
        OEN       = 1'b1 ;        //Eingangssimulation
        #0 ;      PULL      = 2'b10 ;   //Pull-down
        #20 ;     PULL      = 2'b11 ;   //Pull-up
        #20 ;     PULL      = 2'b00 ;   //Pull deaktivieren
        #20 ;     PAD_REG   = 1'b0 ;
        #20 ;     PAD_REG   = 1'b1 ;
 
        #30 ;     OEN       = 1'b0 ;    //Ausgangssimulation
                  DIN       = 1'bz ;
        #15 ;     DIN       = 1'b0 ;
        #15 ;     DIN       = 1'b1 ;
    end
 
    pad u_pad(
        .DIN     (DIN) ,
        .OEN     (OEN) ,
        .PULL    (PULL) ,
        .PAD     (PAD) ,
        .DOUT    (DOUT)
    );
 
    initial begin
        forever begin
            #100;
            if ($time >= 1000)  $finish ;
        end
    end
 
endmodule // test

Die Simulationsergebnisse sind wie folgt:

Die Analyse der Simulationsergebnisse ist wie folgt:

Wenn die PAD-Richtung Eingang ist und kein Treiber vorhanden ist, lässt sich die Pull-Funktion am PAD-Wert erkennen.

In den ersten 60ns ist die treibende Seite PAD_REG von PAD z, was als kein Treiben angesehen werden kann. Daher ist am Anfang PULL=2, Pull-down, der PAD-Wert ist 0; bei 20ns ist PULL=3, Pull-up, der PAD-Wert ist 1;

Bei 40ns ist PULL=0, keine Pull-Funktion, und der PAD-Wert am Eingang ist z.

Nach 60ns~100ns beginnt die treibende Seite PAD_REG von PAD normal zu treiben. Zu diesem Zeitpunkt ist es äquivalent dazu, dass PAD direkt mit PAD_REG verbunden ist, sodass der PAD-Wert weiterhin mit seinem Treiberwert übereinstimmt.

In der obigen Analyse ist die PAD-Richtung immer Eingang, und alle Ausgangsanschlüsse DOUT stimmen weiterhin mit dem PAD-Wert überein.

Wenn die PAD-Richtung Ausgang ist, d. h. bei 120ns OEN=0, stimmt der PAD-Wert weiterhin mit dem Wert des Eingangsanschlusses DIN überein.

Quellcode-Download

Herunterladen