Palabras clave: asignación bloqueante, asignación no bloqueante, paralelo

La asignación procedural es aquella que se realiza dentro de bloques de sentencias initial o always; el objeto de la asignación puede ser de tipos como registros, enteros, reales, etc.

Después de ser asignadas, estas variables mantienen su valor hasta que se les asigna un nuevo valor.

La asignación continua está siempre activa; cualquier cambio en un operando afecta el resultado de la expresión. La asignación procedural solo tiene efecto cuando se ejecuta la sentencia. Esta es la diferencia entre la asignación continua y la asignación procedural.

La asignación procedural en Verilog incluye dos tipos de sentencias: asignación bloqueante y asignación no bloqueante.

Asignación bloqueante

La asignación bloqueante pertenece a la ejecución secuencial; es decir, antes de que se ejecute la siguiente sentencia, la sentencia actual debe haberse completado.

La sentencia de asignación bloqueante utiliza el signo igual=como operador de asignación.

En las simulaciones anteriores, las sentencias de asignación dentro de initial utilizaban asignación bloqueante.

Asignación no bloqueante

La asignación no bloqueante pertenece a la ejecución paralela; es decir, la ejecución de la siguiente sentencia y la de la sentencia actual ocurren simultáneamente, y no bloquea la ejecución de las sentencias posteriores dentro del mismo bloque de sentencias.

La sentencia de asignación no bloqueante utiliza el signo menor o igual<=como operador de asignación.

Utilizando el siguiente código, se simulan las asignaciones bloqueante y no bloqueante para explicar la diferencia entre los dos tipos de asignación procedural.

Ejemplo

`timescale 1ns/1ns
 
module test ;
    reg [3:0]   ai, bi ;
    reg [3:0]   ai2, bi2 ;
    reg [3:0]   value_blk ;
    reg [3:0]   value_non ;
    reg [3:0]   value_non2 ;
 
    initial begin
        ai            = 4'd1 ;   //(1)
        bi            = 4'd2 ;   //(2)
        ai2           = 4'd7 ;   //(3)
        bi2           = 4'd8 ;   //(4)
        #20 ;                    //(5)
 
        //non-block-assigment with block-assignment
        ai            = 4'd3 ;     //(6)
        bi            = 4'd4 ;     //(7)
        value_blk     = ai + bi ;  //(8)
        value_non     <= ai + bi ; //(9)
 
        //non-block-assigment itself
        ai2           <= 4'd5 ;           //(10)
        bi2           <= 4'd6 ;           //(11)
        value_non2    <= ai2 + bi2 ;      //(12)
    end
 
   //stop the simulation
    always begin
        #10 ;
        if ($time >= 1000) $finish ;
    end
 
endmodule

El resultado de la simulación es el siguiente:

Las sentencias (1)-(8) son asignaciones bloqueantes y se ejecutan en orden.

Antes de 20ns, los valores de las señales ai y bi cambian. Debido a las características de la asignación procedural, value_blk = ai + bi no se ha ejecutado, por lo que antes de 20ns, el valor de value_blk es X (estado indeterminado).

Después de 20ns, los valores de las señales ai y bi cambian nuevamente. Al ejecutarse value_blk = ai + bi, la señal value_blk utiliza los nuevos valores de las señales ai y bi para obtener el resultado de cálculo 7.

Las sentencias (9)-(12) son asignaciones no bloqueantes y se ejecutan en paralelo.

Primero, aunque (9)-(12) se ejecutan de forma concurrente, su orden de ejecución está después de (8), por lo que el cálculo de value_non = ai + bi también utiliza los nuevos valores de las señales ai y bi, y el resultado es 7.

Segundo, (10)-(12) se ejecutan de forma concurrente, por lo que al calcular value_non2 = ai2 + bi2 no se tienen en cuenta los últimos resultados de asignación no bloqueante de las señales ai2 y bi2. Es decir, el cálculo de value_non2 utiliza los valores antiguos de las señales ai2 y bi2, y el resultado es 4'hF.

Uso de asignación no bloqueante para evitar condiciones de carrera

El código de simulación anterior tiene como único propósito que el lector comprenda mejor la diferencia entre la asignación bloqueante y la no bloqueante. Al diseñar código Verilog real, recuerde no mezclar asignaciones bloqueantes y no bloqueantes dentro de una misma estructura procedural. Cuando se mezclan los dos tipos de asignación, el temporizado es difícil de controlar y es fácil obtener resultados inesperados.

En la mayoría de los casos, al diseñar circuitos, se utiliza preferentemente la asignación no bloqueante en los bloques lógicos secuenciales always, y la asignación bloqueante en los bloques lógicos combinacionales always; al simular circuitos, generalmente se utiliza la asignación bloqueante en los bloques initial.

Como se muestra a continuación, para implementar la función de intercambiar los valores de dos registros en el flanco ascendente del reloj, se utiliza la asignación bloqueante en dos bloques always.

Debido a que las sentencias en los dos bloques always se ejecutan simultáneamente, no se puede determinar el orden de ejecución entre a=b y b=a, lo que crea una condición de carrera.

Pero sin importar cuál se ejecute primero (depende del compilador, etc.), sin considerar problemas de timing, siempre hay un orden en su ejecución, y al final los valores de a y b siempre son iguales. No se logra el efecto de intercambiar los valores de los dos registros.

Ejemplo

always @(posedge clk) begin
    a = b ;
end
 
always @(posedge clk) begin
    b = a;
end

Sin embargo, si se utiliza la asignación no bloqueante en los bloques always, se puede evitar la condición de carrera mencionada anteriormente.

Como se muestra a continuación, las sentencias en los dos bloques always se ejecutan en paralelo; el operando del lado derecho de la operación de asignación utiliza los valores antiguos del ciclo de reloj anterior. De este modo, a<=b y b<=a pueden ejecutarse sin interferirse mutuamente, logrando el propósito de intercambiar los valores de los registros.

Ejemplo

always @(posedge clk) begin
    a <= b ;
end
 
always @(posedge clk) begin
    b <= a;
end

Por supuesto, el siguiente código también puede implementar la función de intercambiar valores de registros, pero claramente no es tan simple e intuitivo como usar directamente la asignación no bloqueante en el bloque always.

Ejemplo

always @(posedge clk) begin
    temp    = a ;
    a       = b ;
    b       = temp ;
end

Descarga del código fuente

Download