キーワード: setup hold recovery removal width period
パス遅延を指定する目的は、シミュレーションのタイミングを実際のデジタル回路のタイミングにより近づけることである。タイミング制約を用いてデジタル設計のタイミングシミュレーションを行い、設計にタイミング制約の違反(violation)があるかどうかを検査して修正することも、デジタル設計において不可欠なプロセスである。
Verilog はタイミングチェックのためのシステムタスクをいくつか提供している。これらのシステムタスクは specify ブロック内でのみ呼び出すことができる。以下では、タイミングチェックに使用される6つの一般的なシステムタスク、$setup, $hold, $recovery, $removal, $width と $period を紹介する。
$setup, $hold
システムタスク $setup は設計中の素子のセットアップタイム制約条件をチェックするために使用され、$hold はホールドタイム制約条件をチェックするために使用される。その使用形式は以下のとおり:
$setup(data_event, ref_event, setup_limit);
- data_event: チェック対象の信号。制約に違反しているかどうかを判定する。
- ref_event: チェックに使用する参照信号。通常はクロック信号のエッジ。
- setup_limit: 設定された最小セットアップタイム
もしT( ref_event - data_event) < setup_limit、その場合は存在するviolationというレポートが出力されます。
$hold(ref_event, data_event, hold_limit);
- data_event: チェック対象の信号。制約に違反しているかどうかを判定する。
- ref_event: チェックに使用する参照信号。通常はクロック信号のエッジ。
- hold_limit: 設定された最小ホールドタイム
もしT( data_event - ref_event ) < hold_limit、その場合は存在するviolationというレポートが出力されます。
注意:$setup と $hold の入力ポートの位置は異なります。
Verilog はセットアップタイムとホールドタイムを同時にチェックするシステムタスクを提供しています:
$setuphold (ref_event, data_event, setup_limit, hold_limit);
以下では、ある数に15を掛ける操作を行い、$setup と $hold の使い方を説明します。
Verilog では、変数に定数を掛ける場合、一般的にシフト加算の方法で行います。例えば、変数 num に15を掛ける操作は次のように表せます:
num x 15 = (num << 3) + (num << 2) + (num << 1) + num
この操作には3つの加算器が必要です。次に加算器をモデル化し、パス遅延を指定します。
全加算器の機能説明は参照できます『Verilog チュートリアル』の3.1節の内容。
例
module full_adder1(
input Ai, Bi, Ci,
output So, Co);
assign So = Ai ^ Bi ^ Ci ;
assign Co = (Ai & Bi) | (Ci & (Ai | Bi));
specify
(Ai, Bi, Ci *> So) = 1.1 ;
(Ai, Bi *> Co) = 1.3 ;
(Ci => Co) = 1.2 ;
endspecify
endmodule
// 8ビット幅の加算器インスタンス
module full_adder8(
input [7:0] a , //adder1
input [7:0] b , //adder2
input c , //input carry bit
output [7:0] so , //adding result
output co //output carry bit
);
wire [7:0] co_temp ;
full_adder1 u_adder0(
.Ai (a[0]),
.Bi (b[0]),
.Ci (c==1'b1 ? 1'b1 : 1'b0),
.So (so[0]),
.Co (co_temp[0]));
genvar i ;
generate
for(i=1; i<=7; i=i+1) begin: adder_gen
full_adder1 u_adder(
.Ai (a[i]),
.Bi (b[i]),
.Ci (co_temp[i-1]),
.So (so[i]),
.Co (co_temp[i]));
end
endgenerate
assign co = co_temp[7] ;
endmodule
8ビット幅のフリップフロップの記述は以下のとおりです。フリップフロップにパス遅延を指定し、セットアップタイムとホールドタイムのタイミングチェックを追加します。
セットアップタイムは2ns、ホールドタイムは3nsに設定します。
例
input [7:0] d ,
input clk ,
output reg [7:0] q);
always @(posedge clk)
q <= d ;
specify
$setup(d, posedge clk, 2);
$hold(posedge clk, d, 3);
(d,clk *> q) = 0.3 ;
endspecify
endmodule
testbench 内で15を掛ける操作を実行し、1周期内に次の段のレジスタへ出力します。
例
module test ;
reg [3:0] a ;
reg [3:0] b ;
wire [3:0] so ;
wire co ;
parameter CYCLE_10NS = 10ns;
reg clk ;
initial begin
clk = 0 ;
# 111 ;
forever begin
#(CYCLE_10NS/2) clk = ~clk ;
end
end
// 15を掛ける必要のある数
reg [7:0] num = 0 ;
always @(posedge clk) begin
num[3:0] <= num[3:0] + 1 ;
end
// num * 8 + num * 4
wire [7:0] adder1 ;
full_adder8 u1_adder8(
.a (num<<2),
.b (num<<3),
.c (1'b0),
.so (adder1),
.co ());
//num * 2 + num
wire [7:0] adder2 ;
full_adder8 u2_adder8(
.a (num<<1),
.b (num),
.c (1'b0),
.so (adder2),
.co ());
//num x 15
wire [7:0] adder3 ;
full_adder8 u3_adder8(
.a (adder1),
.b (adder2),
.c (1'b0),
.so (adder3),
.co ());
//store the result
wire [7:0] res_mul15 ;
D8 data_store(
.d (adder3),
.clk (clk),
.q (res_mul15));
initial begin
forever begin
#100;
if ($time >= 1000) $finish ;
end
end
endmodule // test
シミュレーションレポートには setup/hold violation を含む出力情報が表示されました。一部のスクリーンショットは以下のとおりです。

violation が発生した時間の波形を切り取ったものを以下に示します。

分析は以下のとおりです:
- (1) セットアップタイムとホールドタイムの両方に violation が発生しました。シミュレーションでは変数 num に15を掛けた後、1クロック周期遅延した出力結果は正しいですが、実際の回路では非常に危険です。
- (2) 波形中の信号のセットアップタイムは 166-164.4 = 1.6 ns で、設定した 2ns より小さいため、violation が報告されます。
- (3) 波形中の信号のホールドタイムは 168.2-166 = 2.2 ns で、設定した 3ns より小さいため、violation が報告されます。
- (4) 図中の赤い部分は信号 d が変化する中間過程です。信号の各ビットの遅延が異なるため、中間に複数の異なる結果が現れる可能性があります。
タイミング最適化
ホールドタイムのタイミング最適化は、RTL レベルの記述では一般的に制御が難しく、これはバックエンド設計エンジニアの作業範囲に属するため、ここでは議論しません。
今回は主に、セットアップタイムが制約条件を満たさない場合の最適化問題について簡単に検討します。前節『3.3 セットアップタイムとホールドタイム』から、セットアップタイムの制約式は次のとおりです:
Tcq + Tcomb + Tsu <= Tclk + Tskew (1)
- Tcq: レジスタのクロック端子から Q 端子までの遅延;
- Tcomb: data path 内の組み合わせ論理遅延;
- Tsu: セットアップタイム;
- Tclk: クロック周期;
- Tskew: クロックスキュー。
この不等式を最適化するには、以下のいくつかの側面から検討できます:
- (1) タイミング特性の良いプロセス部品を選ぶこと。その Tcq と Tsu の値は小さいほど良い;
- (2) 組み合わせ論理を最適化し、組み合わせ論理遅延 Tcomb をできるだけ小さくする;
- (3) 動作クロック周波数を下げ、動作クロック周期 Tclk を大きくする;
- (4) クロックスキュー Tskew を増やす。ただし、クロックスキューが大きすぎると、ホールドタイムが満たされない、機能論理エラーなどの他の問題を引き起こす可能性があります。
RTL レベルでタイミング最適化を行う場合、方法(2)(3)のみを検討できます。
例えば、上記のシミュレーションの動作クロック周期を 10ns から 20ns に変更すると、setup violation は発生しません。
あるいは、ロジックを調整し、1周期内で3回の加算演算を完了するのを、2周期に分散して完了するように変更し、中間に1段のレジスタを追加してバッファリングすることで、タイミング上の負担を軽減します。同時に、変数 num の変化周期も元の2倍の長さにする必要があります。
testbench は次のように変更します:
例
`define LOGIC_BUF
module test ;
parameter CYCLE_10NS = 10ns;
reg clk ;
initial begin
clk = 0 ;
# 111 ;
forever begin
#(CYCLE_10NS/2) clk = ~clk ;
end
end
reg slow_flag = 0 ;
always @(posedge clk) begin
`ifdef LOGIC_BUF
slow_flag <= ~slow_flag ;
`else
slow_flag <= 1'b1 ;
`endif
end
reg [7:0] num = 0 ;
always @(posedge clk) begin
if(slow_flag)
num[3:0] <= num[3:0] + 1 ;
end
wire [7:0] adder1 ;
full_adder8 u1_adder8(
.a (num<<2),
.b (num<<3),
.c (1'b0),
.so (adder1),
.co ());
wire [7:0] adder2 ;
full_adder8 u2_adder8(
.a (num<<1),
.b (num),
.c (1'b0),
.so (adder2),
.co ());
//====== for better time=========
//adding buffer
wire [7:0] adder1_r, adder2_r ;
D8 adder1_buf(
.d (adder1),
.clk (clk),
.q (adder1_r));
D8 adder2_buf(
.d (adder2),
.clk (clk),
.q (adder2_r));
`ifdef LOGIC_BUF
wire [7:0] adder1_t = adder1_r ;
wire [7:0] adder2_t = adder2_r ;
`else
wire [7:0] adder1_t = adder1 ;
wire [7:0] adder2_t = adder2 ;
`endif
wire [7:0] adder3 ;
full_adder8 u3_adder8(
.a (adder1_t),
.b (adder2_t),
.c (1'b0),
.so (adder3),
.co ());
wire [7:0] res_mul15 ;
D8 data_store(
.d (adder3),
.clk (clk),
.q (res_mul15));
initial begin
forever begin
#100;
if ($time >= 1000) $finish ;
end
end
endmodule // test
このとき、シミュレーションレポートには violation はなくなり、シミュレーションのスクリーンショットは以下のとおりです。
図からわかるように、信号が早めに到着して一定に保たれる時間は 8.6 ns に達し、セットアップタイムのタイミング要件を完全に満たしています。
この方法の根本的な原理は、信号が複数回変化するタイミングを複数の周期に分散させ、タイミング制約の要件を満たすことです。さらに、パイプライン設計や並列設計などでもタイミングを最適化できます。

$recovery, $removal
セットアップタイムとホールドタイムの概念は、いずれも同期回路の設計において現れます。
非同期リセットのフリップフロップの場合、非同期リセット信号も recovery time(リカバリタイム)と removal time(リムーバルタイム)を満たす必要があります。これにより、リセットとリセット解除が効果的に行われ、メタステーブル状態の発生を防ぐことができます。
リセット解除時、リセット信号はクロックの有効エッジが来る前に、ある程度早く非リセット状態に戻る必要があります。この時間が recovery time です。同期クロックにおけるフリップフロップの setup time に似ています。
リセット時、リセット信号はクロックの有効エッジが来た後も、一定時間その状態を維持する必要があります。この時間が removal time です。同期クロックにおけるフリップフロップの hold time に似ています。
recovery と removal time の模式図を以下に示します。

システムタスク $recovery と $removal は、それぞれ recovery と removal time のチェックに使用されます。使用方法は以下のとおりです:
$recovery (ref_event, data_event, recovery_limit) ;
- ref_event: チェックに使用する参照信号。通常はクリアまたはリセット信号のエッジ;
- data_event: チェック対象の信号。通常はクロック信号のエッジ。
- recovery_limit: 設定された最小 recovery time。
ref_event (reset) < data_event (clock) かつ T(data_event - ref_event) < recovery_limit の場合、すなわちリセット信号がクロック信号の到来前に recovery time を満たさない場合、レポートに violation が出力されます。
$removal (ref_event, data_event, removal_limit) ;
- ref_event: チェックに使用する参照信号。通常はクリアまたはリセット信号のエッジ;
- data_event: チェック対象の信号。通常はクロック信号のエッジ。
- removal_limit: 設定された最小 removal time。
ref_event (reset) > data_event (clock) かつ T(ref_event - data_event) > removal_limit の場合、すなわちリセット信号がクロック信号の到来後に removal time を満たさない場合、レポートに violation が出力されます。
Verilog は removal と recovery を同時にチェックするシステムタスクを提供しています:
$recrem (ref_event, data_event, recovery_limit, removal_limit);
$width, $period
一部のデジタル設計、例えばフラッシュメモリでは、パルス幅や周期のチェックも必要です。そのために Verilog はそれぞれシステムタスク $width と $period を提供しています。使用方法は次のとおりです:
$width(ref_event, time_limit) ;
- ref_event:エッジトリガイベント
- time_limit:パルスの最小幅
$width は、エッジトリガイベント ref_event から次の逆方向の遷移エッジまでの時間をチェックするために使用され、パルス幅のチェックによく使われます。逆方向の2つのエッジ間の時間が time_limit より小さい場合、違反 (violation) が報告されます。
$period(ref_event, time_limit) ;
$period は、エッジトリガイベント ref_event から次の同じ方向の遷移エッジまでの時間をチェックするために使用され、クロック周期のチェックによく使われます。同じ方向の2つのエッジ間の時間が time_limit より小さい場合、レポートに violation が出力されます。

信号 CLK の幅と周期をチェックする specify ブロックの記述は次のとおりです:
例
$width(posedge CLK, 10);
$period(posedge CLK, 20);
endspecify
本章のソースコードダウンロード
Download