キーワード: specify, パス遅延

パス遅延はキーワード specify と endspecify で記述し、キーワードの間に specify ブロック文を構成します。

specify はモジュール内で独立した部分であり、他のステートメントブロック(initial, always など)の中に置くことはできません。

specify ブロック文には主に以下の機能があります:

  • すべてのパスにおけるピン間の遅延を指定する;
  • specparam 定数を定義する;
  • 回路にタイミングチェックを設定する。

並列接続

各パスにはソースピンとデスティネーションピンがあり、これらのパスの遅延を specify 文で順に記述することを並列接続と呼びます。

並列接続の使用形式は以下の通りです:

(<source_io> => <destination_io>) = <delay_value> ;

パス遅延を持つ4入力AND論理モジュールのモデルを以下に示します:

例

module and4(
   output       out,
   input        a, b, c, d);

   specify
      (a => out) = 2.5 ;
      (b => out) = 2.5 ;
      (c => out) = 3.5 ;
      (d => out) = 3.5 ;
   endspecify

   wire         an1, an2 ;
   and          (an1, a, b);
   and          (an2, c, d);
   and          (out, an1, an2);
endmodule

キーワード specparam を使用して specify ブロック内で遅延値の定数を定義し、それをパス遅延に代入することができます。

specparam で定義した定数は specify ブロック内でのみ使用できます。

例

   specify
      specparam ab_2_out = 2.5 ;
      specparam cd_2_out = 3.5 ;
     
      (a => out) = ab_2_out ;
      (b => out) = ab_2_out ;
      (c => out) = cd_2_out ;
      (d => out) = cd_2_out ;
   endspecify

並列接続では、ソースピンとデスティネーションピンは1対1で対応します。並列接続は複数ビット幅の信号間のパス遅延記述もサポートしますが、ビット幅は一致している必要があります。

例

module paral_conn(
    input [3:0]         d,
    output [3:0]        q);

   specify
      (d => q) = 3 ;
   endspecify

   assign q = d & 0101 ;
endmodule

ここで、specify ブロック文は展開して記述することもでき、2つの表現方法は等価です。

例

   specify
      (d[0] => q[0]) = 3 ;
      (d[1] => q[1]) = 3 ;
      (d[2] => q[2]) = 3 ;
      (d[3] => q[3]) = 3 ;
   endspecify

全接続

全接続では、ソースピンの各ビットがターゲットピンの各ビットに接続されます。

ソースピンとデスティネーションピンの接続は組み合わせ的に網羅され、ビット幅の対応は要求されません。

全接続の使用形式は以下の通りです:

(<multiple_source_io> *> <multiple_destination_io>) = <delay_value> ;

例えば4入力のAND論理モジュールは次のように記述できます:

例

module and4(
   output       out,
   input        a, b, c, d);

   specify
      (a,b *> out) = 2.5 ;
      (c,d *> out) = 3.5 ;
   endspecify

   wire         an1, an2 ;
   and          (an1, a, b);
   and          (an2, c, d);
   and          (out, an1, an2);
endmodule

エッジセンシティブパス

エッジセンシティブパスは、入力から出力への遅延のタイミングモデリングに使用され、エッジ識別子でトリガ条件を指定します。指定されていない場合、あらゆる変化がソースピンからデスティネーションピンへの遅延値の変化をトリガします。

使用例は以下の通りです:

例

    //clk の立ち上がりエッジで、clk から out へのパスの立ち上がり遅延は 1、立ち下がり遅延は 2
    //in から out へのデータパスは非反転、すなわち out = in
    (posedge clk => (out +: in)) = (1,2);
   
    //clk の立ち下がりエッジで、clk から out へのパスの立ち上がり遅延は 1、立ち下がり遅延は 2
    //in から out へのデータパスは反転、すなわち out = ~in
    (negedge clk => (out -: in)) = (1,2);
   
    //clk が任意に変化するとき、clk から out へのパスの立ち上がり遅延は 1、立ち下がり遅延は 2
    //in から out へのデータパスは予測不能で、非反転、反転、または不変
    (negedge clk => (out : in)) = (1,2);

条件パス

Verilog では、モデル内で信号値に応じて、パス遅延に条件付きで異なる値を代入することもできます。

条件内のオペランドはスカラでもベクタでもよく、条件式には任意の演算子を含めることもできます。

注意すべき点は、if 文を使用して条件パス内のすべての入力状態を完全に宣言する必要があることです。宣言されていないパスは分布遅延を使用し、分布遅延も宣言されていない場合はゼロ遅延が使用されます。パス遅延と分布遅延が同時に宣言されている場合は、最大の遅延がパス遅延として選択されます。

ただし、specify 内の if 文では else 構造を使用できません。条件がデフォルトの場合のパス遅延を記述するには ifnone を使用できます。

例

   specify
      if (a)    (a => out) = 2.5 ;
      if (~a)   (a => out) = 1.5 ;

      if (b & c)        (b => out) = 2.5 ;
      if (!(b & c))     (b => out) = 1.5 ;

      if ({c, d} == 2'b01)
                (c,d *> out) = 3.5 ;
      ifnone    (c,d *> out) = 3 ;
   endspecify

ゲート遅延パス

ゲート遅延(立ち上がり遅延、立ち下がり遅延、オフ遅延)の値も、パス遅延の方法で記述できます。

定義できる遅延パスの数は 1 個、2 個、3 個、6 個、12 個で、その他の数の遅延値はすべてエラーです。

以下に、ゲート遅延モデルにおけるパス遅延の表現方法を例を挙げて説明します。

例

   //1 個のパラメータ: 立ち上がり、立ち下がり、オフ遅延は1つの遅延パラメータのみを使用
   specify
      specparam t_delay = 1.5 ;
      (clk => q) = t_delay ;
   endspecify

   //2 個のパラメータ: 立ち上がり遅延(0->1, z->1, 0->z)= 1.5
   // 立ち下がり遅延(1->0, z->0, 1->z)= 2
   specify
      specparam t_rise = 1.5, t_fall = 2 ;
      (clk => q) = (t_rise, t_fall) ;
   endspecify
 
   //3 個のパラメータ: 立ち上がり遅延(0->1, z->1)= 1.5
   // 立ち下がり遅延(1->0, z->0)= 2
   // オフ遅延(1->z, 0->z)= 1.8
   specify
      specparam t_rise = 1.5, t_fall = 2, t_turnoff = 1.8 ;
      (clk => q) = (t_rise, t_fall, t_turnoff);
   endspecify

   //6 個のパラメータ: それぞれ 0->1, 1->0, 0->z, z->1, 1->z, z->0 に対応
   specify
      specparam t_01 = 1.5, t_10 = 2,   t_0z = 1.8 ;
      specparam t_z1 = 2,   t_1z = 2.2, t_z0 = 2.1 ;
      (clk => q) = (t_01, t_10, t_0z, t_z1, t_1z, t_z0) ;
   endspecify

   //12 個のパラメータ: それぞれ 0->1, 1->0, 0->z, z->1, 1->z, z->0 に対応
   //                 0->x, x->1, 1->x, x->0, x->z, z->x
   specify
      specparam t_01 = 1.5, t_10 = 2,   t_0z = 1.8 ;
      specparam t_z1 = 2,   t_1z = 2.2, t_z0 = 2.1 ;
      specparam t_0x = 1.1, t_x1 = 1.2, t_1x = 2.1 ;
      specparam t_x0 = 2,   t_xz = 2  , t_zx = 2.1 ;

      (clk => q) = (t_01, t_10, t_0z, t_z1, t_1z, t_z0,
                    t_0x, t_x1, t_1x, t_x0, t_xz, t_zx) ;
   endspecify

ゲートパス遅延モデルでは、最大値、最小値、標準値を指定することもできます。

例

   //立ち上がり、立ち下がり、オフ遅延の遅延値: min: typical: max
   specify
      specparam t_rise    = 1:1.5:1.8;
      specparam t_fall    = 1:1.8:2 ;
      specparam t_turnoff = 1.1:1.2:1.3 ;
      (clk => q) = (t_rise, t_fall, t_turnoff);
   endspecify

X伝播遅延

x 変換時間の遅延が指定されていない場合(ゲートパス遅延で12個の遅延パラメータが与えられていない場合)、次のように規定されます:

  • x から既知状態への変換の遅延時間は、必要となる可能性のある最大遅延時間;
  • 既知状態から x への変換の遅延時間は、必要となる可能性のある最小遅延時間。

例えば、ゲートパス遅延で6個の遅延パラメータが与えられている場合、x 伝播遅延時間は次の表のように定義されます:

x 変換遅延値
0->xmin(t_01, t_0z)
1->xmin(t_10, t_1z)
z->xmin(t_z1, t_z0)
  
x->0max(t_10, t_z0)
x->1max(t_01, t_z1)
x->zmax(t_1z, t_0z)

本章のソースコードダウンロード

Download