順序論理 UDP と組み合わせ論理 UDP は、定義形式と動作機能において異なります。主な違いは以下のとおりです。

  • 1. 順序論理 UDP の出力端子は reg 型として宣言する必要があります。
  • 2. 順序論理 UDP は initial 文で初期化できます。
  • 3. 状態表の形式も少し異なります:
    ...    :  <current_state>  :  <next_state>  ;
  • 4. 順序論理 UDP の状態表の各行は、入力部分、現在状態、出力状態の 3 つの部分から構成され、コロン「:」で区切られます。
  • 5. current_state は出力レジスタの現在値であり、next_state は出力レジスタの新しい値です。next_state は入力と current_state によって決定されます。
  • 6. 状態表の入力項目は、レベルでも、変化エッジの形式でもかまいません。

順序論理を表す UDP は主に2種類に分けられます:レベルトリガ UDP とエッジトリガ UDP です。

レベルトリガ UDP

レベルトリガ UDP の出力は、入力レベルの状態変化に応じて変化します。

クリア端子付き D ラッチの機能は次のように記述されます。

  • クリア端子が1のとき、出力端子は常に0です。
  • クリア端子が0、イネーブル制御端子が1のとき、ラッチは透過状態になり、出力端子は入力端子と等しくなります。
  • クリア端子が0、イネーブル制御端子が0のとき、ラッチは保持状態になり、出力端子は変化しません。

その真理値表は次のとおりです(q は現在状態、q+ は次の状態を表します):

実際、UDP を作成するプロセスは、別の形式で真理値表を作成するプロセスと理解できます。

クリア端子付き D ラッチの UDP は次のように記述できます。

primitive d_latch(q, clear, en, d);
   output       q ;
   reg          q ;
   input        d, en, clear ;

   initial
     q = 0 ;

   table
    //clear     en      d       :q      :q+ ;
      1         ?       ?       :?      :0 ;    //clear
      0         0       ?       :?      :- ;    //"-" means stable

      0         1       0       :?      :0 ;    //q = d
      0         1       1       :?      :1 ;
   endtable
endprimitive

もちろん、ポート信号を列挙するときにその型を宣言し、初期値を代入することもできます。

primitive d_latch2(
   output reg   q = 0,
   input        clear, en, d);
   ......
endprimitive

エッジトリガ UDP

エッジトリガ UDP の出力は、入力の変化エッジおよび/または入力レベルの状態変化に応じて変化します。

非同期リセット端子(RST)を持ち、クロックの立ち下がりエッジで信号を取り込む D フリップフロップの「真理値表」を直接示します。

この「真理値表」には、UDP コードを書きやすくするために、立ち上がりと立ち下がりの概念が追加されていることがわかります。

この D フリップフロップの順序論理 UDP は次のように記述されます。

primitive D_TRI(
            output reg  Q = 0,
            input       RST, CP, D);
   table
    //RST       CP      D       :Q      :Q+ ;
      //(1) クリア
      1         ?       ?       :?      :0 ;  //RST=1 のときクリア
      (??)      ?       ?       :?      :- ;  //RST のエッジ変化は無視
      //(2) クロック立ち下がりエッジで取り込み
      0         (10)    0       :?      :0 ;  //クロック立ち下がりエッジで信号を取り込む
      0         (10)    1       :?      :1 ;
      //possible negedge
      0         (1x)    ?       :?      :- ;  //クロック立ち下がりエッジ時の保持の可能性
      0         (x0)    ?       :?      :- ;
      //(3) クロック立ち上がりエッジで保持
      0         (0?)    ?       :?      :- ;  //クロック立ち上がりエッジ時に保持
      //possible posedge
      0         (x1)    ?       :?      :- ;  //クロック立ち上がりエッジ時の保持の可能性
      //(4) クロックエッジ以外の変化時、データが変化しても出力は保持されます
      0         ?       (??)    :?      :- ;  
   endtable
endprimitive // D_TRI

このフリップフロップを簡単にシミュレーションするための testbench は次のように記述されます。

例

`timescale 1ns/1ps
module test ;
   reg  D, CP = 0 ;
   reg  RST ;
   wire Q ;
   always #5 CP = ~CP ;
   //data driver
   initial begin
      D = 0 ;
      #12 D = 1 ;
      #10 D = 0 ;
      #14  D = 1 ;
      #3  D = 0 ;
      #18  D = 0 ;
   end
   //reset driver
   initial begin
      RST = 0 ;
      #3        RST = 1 ;
      #2        RST = 0 ;
      #22       RST = 1 ;
      #1        RST = 0 ;
   end
   D_TRI u_d_trigger(Q, RST, CP, D);
   initial begin
      forever begin
         #100;
         //$display("---gyc---%d", $time);
         if ($time >= 1000) begin
            $finish ;
         end
      end
   end
endmodule // test

シミュレーション結果は次のとおりです。

図からわかるように、cap1 の時点で Q 端子はリセットされてクリアされます。cap2 の時点、つまりクロック立ち下がりエッジでは、出力端子は D 端子の入力 1 を取り込みます。cap3 の時点で、Q 端子は再びクリアされます。設計どおりです。

注意すべき点は次のとおりです:

状態表の各行において、複数の入力部分がある場合、変化エッジは最大1つのみです。例えば、以下の状態表の記述は誤りです。

   table
      ......
      (10)     (10)    1       :?      :1 ;
   endtable

レベルトリガの状態表の入力項目は、エッジトリガの状態表の入力項目よりも優先度が高くなります。両方が同時に出現した場合、出力端子の状態はレベルトリガの状態表によって決定されます。

例えば上記の D フリップフロップでは、RST はレベルトリガ、CP はエッジトリガとみなせます。RST の立ち上がりエッジと CP の立ち下がりエッジが同時に到来すると、出力端子は 0 になります。下図の cap 時点のとおりです。もちろん、実際のタイミングではクロックとリセットのエッジが同時に到来するのは避けるべきです。

エッジトリガ UDP では、すべての入力信号について、エッジ変化時の出力信号の変化を指定する必要があります。指定しないと、その信号の変化エッジで出力端子が X になる可能性があります。

例えば、RST のエッジ変化の記述が欠けている場合:

    //(??)    ?       ?       :?      :- ; //忽略 RST 边沿变化

その場合、RST の立ち下がりエッジで出力は x になります。

さらに、クロック安定時、D 端子データ変化時の記述が欠けている場合:

    //(4) 非时钟沿变化时,即便数据有跳变,输出仍然保持
    //0         ?       (??)    :?      :- ;

その場合、D 端子のデータ変化エッジでも出力が x になります。


UDP 状態表記号の略語

UDP 状態表のレベルと変化エッジの略語記号および説明を以下の表に示します。

略号意味説明
?0, 1, x入力のみに使用可能
b1, 1入力のみに使用可能
-元の値を保持出力のみに使用可能
(ab)信号が a から b に変化入力端のエッジ指示に使用
r(01)信号の立ち上がりエッジ
f(10)信号の立ち下がりエッジ
p(01), (0x) または (x1)信号の立ち上がりエッジの可能性がある
n(10), (1x) または (x0)信号の立ち下がりエッジの可能性がある
*(??)信号の任意のエッジ変化

UDP 設計ガイド

デジタル設計において module と primitive のどちらを使用するかは、設計要件や複雑さなどの観点から総合的に検討する必要があります。以下にいくつかの指針となるアドバイスを示します。

  • UDP は機能的なモデリングのみが可能で、回路のタイミングや製造プロセス(CMOS、TTL など)をモデル化することはできません。UDP を使用する主な目的は、真理値表に似た簡潔な形式でデジタル設計をモデル化することです。一方、module は回路タイミングを含み、製造プロセスを指定できます。
  • UDP は出力ポートが1つのデジタル設計のみを実現できます。出力ポートが2つ以上の場合は、module のみを使用できます。
  • UDP はメモリ内のルックアップテーブルを使用して実装されます。入力ポートが多い場合、入力ポートの組み合わせは指数関数的に増加します。UDP の入力ポート数もシミュレータの制限を受けます。したがって、入力ポートが多い場合は UDP を使用すべきではありません。
  • UDP を使用する場合は、必ず略号を使用して UDP 状態表をできるだけ完全に記述してください。入力の組み合わせを漏らすと、出力端が X 状態になる可能性があり、設計エラーを引き起こします。

この章のソースコードダウンロード

Download