Palabras clave: setup hold recovery removal width period
Especificar el retardo de ruta tiene como objetivo hacer que la temporización de la simulación se acerque más a la del circuito digital real. Utilizar restricciones de temporización para simular temporalmente diseños digitales, verificar si el diseño tiene violaciones de las restricciones y corregirlas es también un proceso indispensable en el diseño digital.
Verilog proporciona algunas tareas de sistema para la verificación de tiempos. Estas tareas de sistema solo se pueden invocar dentro de bloques specify. A continuación se presentan 6 tareas de sistema de uso común para la verificación de tiempos: $setup, $hold, $recovery, $removal, $width y $period.
$setup, $hold
La tarea de sistema $setup se utiliza para comprobar la restricción del tiempo de establecimiento de los componentes del diseño, y $hold para comprobar la restricción del tiempo de mantenimiento. Su formato de uso es el siguiente:
$setup(data_event, ref_event, setup_limit);
- data_event: la señal verificada, para determinar si viola la restricción
- ref_event: la señal de referencia utilizada para la verificación, generalmente el flanco de la señal de reloj
- setup_limit: el tiempo de establecimiento mínimo configurado
SiT( ref_event - data_event) < setup_limit, se imprimiráviolationun informe de violación.
$hold(ref_event, data_event, hold_limit);
- data_event: la señal verificada, para determinar si viola la restricción
- ref_event: la señal de referencia utilizada para la verificación, generalmente el flanco de la señal de reloj
- hold_limit: el tiempo de mantenimiento mínimo configurado
SiT( data_event - ref_event ) < hold_limit, se imprimiráviolationun informe de violación.
Nota:Las posiciones de los puertos de entrada de $setup y $hold son diferentes.
Verilog proporciona tareas de sistema para comprobar simultáneamente el tiempo de establecimiento y el tiempo de mantenimiento:
$setuphold (ref_event, data_event, setup_limit, hold_limit);
A continuación se realiza una operación de multiplicar un número por 15 para ilustrar el uso de $setup y $hold.
En Verilog, multiplicar una variable por una constante generalmente se realiza mediante el método de desplazamiento y suma. Por ejemplo, la operación de multiplicar la variable num por 15 se puede expresar como:
num x 15 = (num << 3) + (num << 2) + (num << 1) + num
Esta operación requiere 3 sumadores. A continuación se modela el sumador y se especifica el retardo de ruta.
La descripción funcional del sumador completo se puede consultar enel contenido de la sección 3.1 del «Tutorial de Verilog»。
Ejemplo
module full_adder1(
input Ai, Bi, Ci,
output So, Co);
assign So = Ai ^ Bi ^ Ci ;
assign Co = (Ai & Bi) | (Ci & (Ai | Bi));
specify
(Ai, Bi, Ci *> So) = 1.1 ;
(Ai, Bi *> Co) = 1.3 ;
(Ci => Co) = 1.2 ;
endspecify
endmodule
// instanciación del sumador de 8 bits de ancho
module full_adder8(
input [7:0] a , //adder1
input [7:0] b , //adder2
input c , //input carry bit
output [7:0] so , //adding result
output co //output carry bit
);
wire [7:0] co_temp ;
full_adder1 u_adder0(
.Ai (a[0]),
.Bi (b[0]),
.Ci (c==1'b1 ? 1'b1 : 1'b0),
.So (so[0]),
.Co (co_temp[0]));
genvar i ;
generate
for(i=1; i<=7; i=i+1) begin: adder_gen
full_adder1 u_adder(
.Ai (a[i]),
.Bi (b[i]),
.Ci (co_temp[i-1]),
.So (so[i]),
.Co (co_temp[i]));
end
endgenerate
assign co = co_temp[7] ;
endmodule
El flip-flop de 8 bits de ancho se describe a continuación. En el flip-flop se especifica el retardo de ruta y se añaden las comprobaciones de tiempo de establecimiento y tiempo de mantenimiento.
El tiempo de establecimiento se establece en 2 ns, y el tiempo de mantenimiento en 3 ns.
Ejemplo
input [7:0] d ,
input clk ,
output reg [7:0] q);
always @(posedge clk)
q <= d ;
specify
$setup(d, posedge clk, 2);
$hold(posedge clk, d, 3);
(d,clk *> q) = 0.3 ;
endspecify
endmodule
En el testbench se realiza la operación de multiplicar por 15 y se entrega a la siguiente etapa de registros dentro de un ciclo.
Ejemplo
module test ;
reg [3:0] a ;
reg [3:0] b ;
wire [3:0] so ;
wire co ;
parameter CYCLE_10NS = 10ns;
reg clk ;
initial begin
clk = 0 ;
# 111 ;
forever begin
#(CYCLE_10NS/2) clk = ~clk ;
end
end
// el número que se va a multiplicar por 15
reg [7:0] num = 0 ;
always @(posedge clk) begin
num[3:0] <= num[3:0] + 1 ;
end
// num * 8 + num * 4
wire [7:0] adder1 ;
full_adder8 u1_adder8(
.a (num<<2),
.b (num<<3),
.c (1'b0),
.so (adder1),
.co ());
//num * 2 + num
wire [7:0] adder2 ;
full_adder8 u2_adder8(
.a (num<<1),
.b (num),
.c (1'b0),
.so (adder2),
.co ());
//num x 15
wire [7:0] adder3 ;
full_adder8 u3_adder8(
.a (adder1),
.b (adder2),
.c (1'b0),
.so (adder3),
.co ());
//store the result
wire [7:0] res_mul15 ;
D8 data_store(
.d (adder3),
.clk (clk),
.q (res_mul15));
initial begin
forever begin
#100;
if ($time >= 1000) $finish ;
end
end
endmodule // test
En el informe de simulación aparecen mensajes impresos con setup/hold violation, como se muestra parcialmente en la siguiente captura.

La forma de onda en el momento en que aparece la violation se captura como se muestra a continuación.

El análisis es el siguiente:
- (1) Tanto el tiempo de establecimiento como el tiempo de mantenimiento presentan violation. Aunque en la simulación el resultado de salida después de retrasar un ciclo de reloj para la variable num multiplicada por 15 es correcto, el circuito real es muy peligroso.
- (2) En la forma de onda, el tiempo de establecimiento de la señal es 166-164.4 = 1.6 ns, menor que los 2 ns configurados, por lo que se reporta violation.
- (3) En la forma de onda, el tiempo de mantenimiento de la señal es 168.2-166 = 2.2 ns, menor que los 3 ns configurados, por lo que se reporta violation.
- (4) La parte roja en la figura es el proceso intermedio de cambio de la señal d. Debido a que los retardos de cada bit de la señal son diferentes, pueden aparecer múltiples resultados diferentes en el medio.
Optimización de tiempos
La optimización de tiempos del tiempo de mantenimiento generalmente no es fácil de controlar a nivel de descripción RTL; esto pertenece al ámbito de trabajo de los ingenieros de diseño de backend, por lo que no se discute aquí.
Esta vez se aborda principalmente el problema de optimización cuando el tiempo de establecimiento no cumple con la restricción. De la sección anterior «3.3 Tiempo de establecimiento y tiempo de mantenimiento», se sabe que la expresión de restricción del tiempo de establecimiento es:
Tcq + Tcomb + Tsu <= Tclk + Tskew (1)
- Tcq: retardo del extremo de reloj del registro al extremo Q;
- Tcomb: retardo de la lógica combinatoria en el data path;
- Tsu: tiempo de establecimiento;
- Tclk: período de reloj;
- Tskew: desplazamiento de reloj.
La optimización de esta desigualdad puede considerarse desde los siguientes aspectos:
- (1) Elegir componentes de proceso con mejores características de temporización; cuanto menores sean sus valores de Tcq y Tsu, mejor;
- (2) Optimizar la lógica combinatoria para que el retardo de la lógica combinatoria Tcomb sea lo menor posible;
- (3) Reducir la frecuencia del reloj de trabajo y aumentar el período de reloj Tclk;
- (4) Aumentar el desplazamiento de reloj Tskew, pero un desplazamiento de reloj excesivo puede causar otros problemas, como que el tiempo de mantenimiento no se cumpla, errores de lógica funcional, etc.
Al realizar la optimización de tiempos a nivel RTL, solo se pueden considerar los métodos (2) y (3).
Por ejemplo, si se cambia el período del reloj de trabajo en la simulación anterior de 10 ns a 20 ns, no aparecerá una setup violation.
O bien, ajustar la lógica: las 3 operaciones de suma que se completan en un ciclo se cambian para que se realicen en dos ciclos, añadiendo una etapa de registros intermedia como búfer, para reducir la presión sobre la temporización. Al mismo tiempo, el período de cambio de la variable num también debe duplicarse.
El testbench se modifica como sigue:
Ejemplo
`define LOGIC_BUF
module test ;
parameter CYCLE_10NS = 10ns;
reg clk ;
initial begin
clk = 0 ;
# 111 ;
forever begin
#(CYCLE_10NS/2) clk = ~clk ;
end
end
reg slow_flag = 0 ;
always @(posedge clk) begin
`ifdef LOGIC_BUF
slow_flag <= ~slow_flag ;
`else
slow_flag <= 1'b1 ;
`endif
end
reg [7:0] num = 0 ;
always @(posedge clk) begin
if(slow_flag)
num[3:0] <= num[3:0] + 1 ;
end
wire [7:0] adder1 ;
full_adder8 u1_adder8(
.a (num<<2),
.b (num<<3),
.c (1'b0),
.so (adder1),
.co ());
wire [7:0] adder2 ;
full_adder8 u2_adder8(
.a (num<<1),
.b (num),
.c (1'b0),
.so (adder2),
.co ());
//====== for better time=========
//adding buffer
wire [7:0] adder1_r, adder2_r ;
D8 adder1_buf(
.d (adder1),
.clk (clk),
.q (adder1_r));
D8 adder2_buf(
.d (adder2),
.clk (clk),
.q (adder2_r));
`ifdef LOGIC_BUF
wire [7:0] adder1_t = adder1_r ;
wire [7:0] adder2_t = adder2_r ;
`else
wire [7:0] adder1_t = adder1 ;
wire [7:0] adder2_t = adder2 ;
`endif
wire [7:0] adder3 ;
full_adder8 u3_adder8(
.a (adder1_t),
.b (adder2_t),
.c (1'b0),
.so (adder3),
.co ());
wire [7:0] res_mul15 ;
D8 data_store(
.d (adder3),
.clk (clk),
.q (res_mul15));
initial begin
forever begin
#100;
if ($time >= 1000) $finish ;
end
end
endmodule // test
En este momento, el informe de simulación ya no contiene violation. La captura de la simulación es la siguiente.
Como se puede ver en la figura, el tiempo en que la señal llega antes y se mantiene estable puede alcanzar los 8.6 ns, cumpliendo completamente con los requisitos de temporización del tiempo de establecimiento.
El principio fundamental de este método es distribuir la temporización de los múltiples cambios de la señal en varios ciclos para cumplir con los requisitos de las restricciones de temporización. Además, el diseño de pipeline, el diseño paralelo, etc., también pueden optimizar la temporización.

$recovery, $removal
Los conceptos de tiempo de establecimiento y tiempo de mantenimiento aparecen en el diseño de circuitos síncronos.
Para los flip-flops con reset asíncrono, la señal de reset asíncrona también debe cumplir con el recovery time (tiempo de recuperación) y el removal time (tiempo de eliminación) para poder resetear y liberar el reset de manera efectiva y evitar estados metaestables.
Al liberar el reset, la señal de reset debe recuperar el estado no activo un tiempo antes de que llegue el flanco activo del reloj; este tiempo es el recovery time. Es similar al setup time del flip-flop bajo un reloj síncrono.
Al activar el reset, la señal de reset debe permanecer estable durante un tiempo después de que llegue el flanco activo del reloj; este tiempo es el removal time. Es similar al hold time del flip-flop bajo un reloj síncrono.
El diagrama esquemático del recovery y el removal time se muestra a continuación.

Las tareas de sistema $recovery y $removal se utilizan para la comprobación del recovery y del removal time respectivamente. Su uso es el siguiente:
$recovery (ref_event, data_event, recovery_limit) ;
- ref_event: la señal de referencia utilizada para la verificación, generalmente el flanco de la señal de clear o reset;
- data_event: la señal verificada, generalmente el flanco de la señal de reloj.
- recovery_limit: el recovery time mínimo configurado.
Cuando ref_event (reset) < data_event (clock) y T(data_event - ref_event) < recovery_limit, es decir, si la señal de reset no cumple con el recovery time antes de la llegada de la señal de reloj, se imprimirá una violation en el informe.
$removal (ref_event, data_event, removal_limit) ;
- ref_event: la señal de referencia utilizada para la verificación, generalmente el flanco de la señal de clear o reset;
- data_event: la señal verificada, generalmente el flanco de la señal de reloj.
- removal_limit: el removal time mínimo configurado.
Cuando ref_event (reset) > data_event (clock) y T(ref_event - data_event) > removal_limit, es decir, si la señal de reset no cumple con el removal time después de la llegada de la señal de reloj, se imprimirá una violation en el informe.
Verilog proporciona tareas de sistema para comprobar simultáneamente el removal y el recovery:
$recrem (ref_event, data_event, recovery_limit, removal_limit);
$width, $period
Algunos diseños digitales, como la memoria flash, también requieren verificar el ancho de pulso o el período. Para ello, Verilog proporciona las tareas de sistema $width y $period respectivamente. Su uso es el siguiente:
$width(ref_event, time_limit) ;
- ref_event: evento de disparo por flanco
- time_limit: ancho mínimo del pulso
$width se utiliza para comprobar el tiempo entre el evento de disparo por flanco ref_event y el siguiente flanco de transición opuesto. Se usa comúnmente para verificar el ancho de pulso. Si el tiempo entre dos flancos de transición opuestos es menor que time_limit, se reportará una violación.
$period(ref_event, time_limit) ;
$period se utiliza para comprobar el tiempo entre el evento de disparo por flanco ref_event y el siguiente flanco de transición en la misma dirección. Se usa comúnmente para verificar el período de reloj. Si el tiempo entre dos flancos de transición en la misma dirección es menor que time_limit, se imprimirá una violación en el informe.

El bloque specify para verificar el ancho y el período de la señal CLK se describe a continuación:
Ejemplo
$width(posedge CLK, 10);
$period(posedge CLK, 20);
endspecify
Descargar el código fuente de este capítulo
Download